[oe] [meta-oe][PATCH] multipath-tools: add recipe for git version

[Khem Raj]

Hi Koen

On Mar 27, 2013, at 3:07 AM, Koen Kooi <koen at dominion.thruhere.net> wrote:

> Multipath-tools hasn't seen a release in 3 years, so grab latest git.
> 
> 'kpartx' is subpackaged since that's the tool most people want.
> 
> Signed-off-by: Koen Kooi <koen at dominion.thruhere.net>
> ---
> .../multipath-tools/multipath-tools_git.bb         | 34 ++++++++++++++++++++++
> 1 file changed, 34 insertions(+)
> create mode 100644 recipes-support/multipath-tools/multipath-tools_git.bb
> 
> diff --git a/recipes-support/multipath-tools/multipath-tools_git.bb b/recipes-support/multipath-tools/multipath-tools_git.bb
> new file mode 100644
> index 0000000..1b83f49
> --- /dev/null
> +++ b/recipes-support/multipath-tools/multipath-tools_git.bb
> @@ -0,0 +1,34 @@
> +DESCRIPTION = "The upstream project used to drive the Device Mapper multipathing driver."
> +
> +DEPENDS = "lvm2 libaio"

as I read it also depends on libreadline

> +
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=7be2873b6270e45abacc503abbe2aa3d"
> +
> +
> +SRC_URI = "git://git.opensvc.com/multipath-tools/.git;protocol=http"
> +SRCREV = "15fc23ffb2bd1bac6990eda3e23c3e8980e6cfa5"
> +
> +S = "${WORKDIR}/git"
> +
> +PV = "0.4.9+git"
> +

Is current release 0.4.9 ? I wonder if it will this be ok for upgrade path when a release happens 

> +EXTRA_OEMAKE = "MULTIPATH_VERSION=${PV} DESTDIR=${D} syslibdir=${base_libdir} libdir=${base_libdir}/multipath"
> +
> +do_compile() {
> +	oe_runmake
> +}
> +
> +do_install() {
> +	oe_runmake install
> +}
> +
> +FILES_${PN}-dbg += "${base_libdir}/multipath/.debug"
> +FILES_${PN} += "${base_libdir}/multipath \
> +                ${base_libdir}/systemd"
> +
> +PACKAGES =+ "kpartx"
> +FILES_kpartx = "${base_sbindir}/kpartx \
> +                ${base_libdir}/udev/kpartx_id"
> +
> +RDEPENDS_${PN} += "kpartx"
> -- 
> 1.8.1.4
> 
> 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-devel