[oe] [meta-oe][PATCH] openvpn: update and enable iproute2 support

[Ben Shelton]

From: Richard Tollerton <rich.tollerton at ni.com>

- Added .bb for version 2.3.4.
- The download URL was broken; it's changed to reflect where the website
  points to.
- Force use of iproute2, which is generally recommended when running
  OpenVPN as an unprivileged user. Ref:
  http://community.openvpn.net/openvpn/wiki/UnprivilegedUser
- Explicitly add libpam to DEPENDS if pam is enabled, and disable the
  auth-pam plugin if pam is not enabled.

Signed-off-by: Richard Tollerton <rich.tollerton at ni.com>
Signed-off-by: Ben Shelton <ben.shelton at ni.com>
---
 .../recipes-support/openvpn/openvpn_2.1.3.bb       | 27 -------------------
 .../recipes-support/openvpn/openvpn_2.3.4.bb       | 30 ++++++++++++++++++++++
 2 files changed, 30 insertions(+), 27 deletions(-)
 delete mode 100644 meta-networking/recipes-support/openvpn/openvpn_2.1.3.bb
 create mode 100644 meta-networking/recipes-support/openvpn/openvpn_2.3.4.bb

diff --git a/meta-networking/recipes-support/openvpn/openvpn_2.1.3.bb b/meta-networking/recipes-support/openvpn/openvpn_2.1.3.bb
deleted file mode 100644
index 9ef0fbf..0000000
--- a/meta-networking/recipes-support/openvpn/openvpn_2.1.3.bb
+++ /dev/null
@@ -1,27 +0,0 @@
-SUMMARY = "A full-featured SSL VPN solution via tun device"
-HOMEPAGE = "http://openvpn.sourceforge.net"
-SECTION = "console/network"
-LICENSE = "GPLv2"
-LIC_FILES_CHKSUM = "file://COPYING;md5=5aac200199fde47501876cba7263cb0c"
-DEPENDS = "lzo openssl"
-
-inherit autotools
-
-SRC_URI = "http://openvpn.net/release/openvpn-${PV}.tar.gz \
-           file://openvpn"
-
-SRC_URI[md5sum] = "7486d3e270ba4b033e311d3e022a0ad7"
-SRC_URI[sha256sum] = "5185181df2e6043bd667377bc92e36ea5a5bd7600af209654f109b6403ca5b36"
-
-CFLAGS += "-fno-inline"
-
-# I want openvpn to be able to read password from file (hrw)
-EXTRA_OECONF += "--enable-password-save"
-
-do_install_append() {
-    install -d ${D}/${sysconfdir}/init.d
-    install -d ${D}/${sysconfdir}/openvpn
-    install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
-}
-
-RRECOMMENDS_${PN} = "kernel-module-tun"
diff --git a/meta-networking/recipes-support/openvpn/openvpn_2.3.4.bb b/meta-networking/recipes-support/openvpn/openvpn_2.3.4.bb
new file mode 100644
index 0000000..282befe
--- /dev/null
+++ b/meta-networking/recipes-support/openvpn/openvpn_2.3.4.bb
@@ -0,0 +1,30 @@
+SUMMARY = "A full-featured SSL VPN solution via tun device."
+HOMEPAGE = "http://openvpn.sourceforge.net"
+SECTION = "console/network"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5aac200199fde47501876cba7263cb0c"
+DEPENDS = "lzo openssl iproute2 ${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
+
+inherit autotools
+
+SRC_URI = "http://swupdate.openvpn.org/community/releases/openvpn-${PV}.tar.gz \
+           file://openvpn"
+
+SRC_URI[md5sum] = "04d47237907faabe9d046970ffe44b2e"
+SRC_URI[sha256sum] = "af506d5f48568fa8d2f2435cb3fad35f9a9a8f263999ea6df3ba296960cec85a"
+
+CFLAGS += "-fno-inline"
+
+# I want openvpn to be able to read password from file (hrw)
+EXTRA_OECONF += "--enable-password-save --enable-iproute2"
+EXTRA_OECONF += "${@base_contains('DISTRO_FEATURES', 'pam', '', '--disable-plugin-auth-pam', d)}"
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/init.d
+    install -d ${D}/${sysconfdir}/openvpn
+    install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
+}
+
+RRECOMMENDS_${PN} = "kernel-module-tun"
+
+FILES_${PN}-dbg += "/usr/lib/openvpn/plugins/.debug"
-- 
2.0.2