[oe] [meta-multimedia][PATCH] updated mpd to current upstream stable

[Martin Jansa]

On Sun, Mar 16, 2014 at 03:48:58PM -0700, stephen.arnold42 wrote:
> ---
>  .../recipes-multimedia/musicpd/mpd_0.18.8.bb       | 59 ++++++++++++++++++++++

Can you please remove 0.18.4 in the same commit and resend with -M?

Thanks

>  1 file changed, 59 insertions(+)
>  create mode 100644 meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb
> 
> diff --git a/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb b/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb
> new file mode 100644
> index 0000000..b6882af
> --- /dev/null
> +++ b/meta-multimedia/recipes-multimedia/musicpd/mpd_0.18.8.bb
> @@ -0,0 +1,59 @@
> +SUMMARY = "Music Player Daemon"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
> +HOMEPAGE ="http://www.musicpd.org"
> +
> +DEPENDS = "alsa-lib libsamplerate0 libsndfile1 libvorbis libogg faad2 ffmpeg curl sqlite bzip2 pulseaudio"
> +
> +SRC_URI = " \
> +    http://www.musicpd.org/download/${PN}/stable/${P}.tar.xz \
> +    file://mpd.conf.in \
> +"
> +
> +SRC_URI[md5sum] = "7bbe1caf5abe404dc985ca4f44984b1f"
> +SRC_URI[sha256sum] = "5366378e548fb77996cc33b0e15165ddd84f1e496bdd04616bd593aecdc26450"
> +
> +inherit autotools useradd systemd
> +
> +EXTRA_OECONF = "enable_bzip2=yes"
> +EXTRA_OECONF += "${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
> +
> +PACKAGECONFIG[mad] = "--enable-mad,--disable-mad,libmad"
> +PACKAGECONFIG[id3tag] = "--enable-id3,--disable-id3,libid3tag"
> +PACKAGECONFIG[lame] = "--enable-lame-encoder,--disable-lame-encoder,lame"
> +
> +do_install_append() {
> +    install -d ${D}/${localstatedir}/lib/mpd/music
> +    chmod 775 ${D}/${localstatedir}/lib/mpd/music
> +    install -d ${D}/${localstatedir}/lib/mpd/playlists
> +    chown -R mpd ${D}/${localstatedir}/lib/mpd
> +    chown mpd:mpd ${D}/${localstatedir}/lib/mpd/music
> +
> +    install -d ${D}/${sysconfdir}
> +    install -m 644 ${WORKDIR}/mpd.conf.in ${D}/${sysconfdir}/mpd.conf
> +    sed -i \
> +        -e 's|%music_directory%|${localstatedir}/lib/mpd/music|' \
> +        -e 's|%playlist_directory%|${localstatedir}/lib/mpd/playlists|' \
> +        -e 's|%db_file%|${localstatedir}/lib/mpd/mpd.db|' \
> +        -e 's|%log_file%|${localstatedir}/log/mpd.log|' \
> +        -e 's|%state_file%|${localstatedir}/lib/mpd/state|' \
> +        ${D}/${sysconfdir}/mpd.conf
> +
> +    if [ -e ${D}/${systemd_unitdir}/system/mpd.service ] ; then
> +        sed -i \
> +            's|^ExecStart=.*|ExecStart=${bindir}/mpd --no-daemon|' \
> +            ${D}/${systemd_unitdir}/system/mpd.service
> +    fi
> +}
> +
> +RPROVIDES_${PN} += "${PN}-systemd"
> +RREPLACES_${PN} += "${PN}-systemd"
> +RCONFLICTS_${PN} += "${PN}-systemd"
> +SYSTEMD_SERVICE_${PN} = "mpd.service"
> +
> +USERADD_PACKAGES = "${PN}"
> +USERADD_PARAM_${PN} = " \
> +    --system --no-create-home \
> +    --home ${localstatedir}/lib/mpd \
> +    --groups audio \
> +    --user-group mpd"
> -- 
> 1.8.5.3
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 198 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20140317/a10a80f2/attachment-0002.sig>