[oe] [meta-oe][PATCH] v4l-utils: Update to 1.0.1

[Martin Jansa]

On Mon, May 05, 2014 at 11:50:05PM -0300, Otavio Salvador wrote:
> This updates to last stable release and, as a plus, fix an out of tree
> build failure.

file://openat.patch was removed but not the patch itself

> 
> Signed-off-by: Otavio Salvador <otavio at ossystems.com.br>
> ---
>  .../recipes-multimedia/v4l2apps/v4l-utils_0.8.8.bb | 39 ----------------------
>  .../recipes-multimedia/v4l2apps/v4l-utils_1.0.1.bb | 26 +++++++++++++++
>  2 files changed, 26 insertions(+), 39 deletions(-)
>  delete mode 100644 meta-oe/recipes-multimedia/v4l2apps/v4l-utils_0.8.8.bb
>  create mode 100644 meta-oe/recipes-multimedia/v4l2apps/v4l-utils_1.0.1.bb
> 
> diff --git a/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_0.8.8.bb b/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_0.8.8.bb
> deleted file mode 100644
> index 485a416..0000000
> --- a/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_0.8.8.bb
> +++ /dev/null
> @@ -1,39 +0,0 @@
> -SUMMARY = "v4l2 and IR applications"
> -LICENSE = "GPLv2 & LGPLv2.1"
> -LIC_FILES_CHKSUM = "file://COPYING;md5=48da9957849056017dc568bbc43d8975 \
> -                    file://COPYING.LIB;md5=d749e86a105281d7a44c2328acebc4b0"
> -
> -PR = "r2"
> -
> -DEPENDS = "jpeg virtual/libx11"
> -
> -inherit autotools gettext
> -
> -# libv4l was absorbed into this, let OE know that
> -PROVIDES = "libv4l"
> -
> -SRC_URI = "git://linuxtv.org/v4l-utils.git \
> -           file://openat.patch \
> -"
> -# 54f16ca8183dd8ae8bf4ccc07949795aff0301f5 -> v0.8.8 tag
> -SRCREV = "0298efdcd1153b8f719b9164548a3f0546f0cb7c"
> -
> -S = "${WORKDIR}/git"
> -
> -EXTRA_OECONF = "--disable-qv4l2 --enable-shared --with-udevdir=${base_libdir}/udev" 
> -
> -do_configure() {
> -    # autotools_do_configure fails with:
> -    # | configure.ac:139: error: required file 'build-aux/config.rpath' not found
> -    autoreconf -vfi 
> -    oe_runconf
> -}
> -
> -PACKAGES =+ "rc-keymaps libv4l libv4l-dbg libv4l-dev"
> -
> -FILES_rc-keymaps = "${sysconfdir}/rc* ${base_libdir}/udev/rc*"
> -FILES_${PN} = "${bindir} ${sbindir} ${base_libdir}/udev/rules.d/70-infrared.rules"
> -FILES_libv4l += "${libdir}/libv4l/* ${libdir}/*.so.*"
> -FILES_libv4l-dbg += "${libdir}/libv4l/.debug"
> -FILES_libv4l-dev += "${libdir}/*.so ${includedir}/lib* ${libdir}/pkgconfig/lib*"
> -
> diff --git a/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_1.0.1.bb b/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_1.0.1.bb
> new file mode 100644
> index 0000000..6c25c90
> --- /dev/null
> +++ b/meta-oe/recipes-multimedia/v4l2apps/v4l-utils_1.0.1.bb
> @@ -0,0 +1,26 @@
> +SUMMARY = "v4l2 and IR applications"
> +LICENSE = "GPLv2 & LGPLv2.1"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=48da9957849056017dc568bbc43d8975 \
> +                    file://COPYING.libv4l;md5=d749e86a105281d7a44c2328acebc4b0"
> +
> +DEPENDS = "jpeg virtual/libx11"
> +
> +inherit autotools gettext
> +
> +# libv4l was absorbed into this, let OE know that
> +PROVIDES = "libv4l"
> +
> +SRC_URI = "http://linuxtv.org/downloads/v4l-utils/v4l-utils-${PV}.tar.bz2"
> +SRC_URI[md5sum] = "b06ea8b15e27cff352b4536e835448bc"
> +SRC_URI[sha256sum] = "fc0132e82a18dfad9619be3abf50c206e2f449b1c14440cde36f25874fdce7df"
> +
> +EXTRA_OECONF = "--disable-qv4l2 --enable-shared --with-udevdir=${base_libdir}/udev"
> +
> +PACKAGES =+ "rc-keymaps libv4l libv4l-dbg libv4l-dev"
> +
> +FILES_rc-keymaps = "${sysconfdir}/rc* ${base_libdir}/udev/rc*"
> +FILES_${PN} = "${bindir} ${sbindir} ${base_libdir}/udev/rules.d/70-infrared.rules"
> +FILES_libv4l += "${libdir}/libv4l*${SOLIBS} ${libdir}/libv4l/*.so ${libdir}/libv4l/plugins/*.so \
> +                 ${libdir}/libv4l/*-decomp"
> +FILES_libv4l-dbg += "${libdir}/libv4l/.debug ${libdir}/libv4l/plugins/.debug"
> +FILES_libv4l-dev += "${libdir}/v4l*${SOLIBSDEV} ${libdir}/libv4l/*.la ${libdir}/libv4l/plugins/*.la"
> -- 
> 2.0.0.rc0
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 198 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20140506/53e80e91/attachment-0002.sig>