[oe] [meta-handheld][PATCH] mininit: update SRC_URI and move to v. 2.0.2

[Andrea Adami]

Signed-off-by: Andrea Adami <andrea.adami at gmail.com>
---
 recipes-bsp/mininit/mininit_2.0.2.bb | 36 ++++++++++++++++++++++++++++++++++++
 recipes-bsp/mininit/mininit_git.bb   | 36 ------------------------------------
 2 files changed, 36 insertions(+), 36 deletions(-)
 create mode 100644 recipes-bsp/mininit/mininit_2.0.2.bb
 delete mode 100644 recipes-bsp/mininit/mininit_git.bb

diff --git a/recipes-bsp/mininit/mininit_2.0.2.bb b/recipes-bsp/mininit/mininit_2.0.2.bb
new file mode 100644
index 0000000..862849d
--- /dev/null
+++ b/recipes-bsp/mininit/mininit_2.0.2.bb
@@ -0,0 +1,36 @@
+SUMMARY = "mininit for romfs/squashfs loop images"
+DESCRIPTION = "mininit is a linux-as-bootloader implementation based on losetup."
+HOMEPAGE = "https://github.com/OpenDingux/mininit"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://license.txt;md5=a00f7cbb0dca244e8ae6aaa792217ecf"
+
+SRC_URI = "https://github.com/OpenDingux/mininit/archive/v${PV}.tar.gz"
+SRC_URI[md5sum] = "13c6ad344c9f29e28267c37718926d83"
+SRC_URI[sha256sum] = "bdece10be16af57758e87d9be7d17a37deb7c42253966b7c06b334acea93992f"
+
+S = "${WORKDIR}/mininit-${PV}"
+
+LDFLAGS += '-static'
+
+do_compile () {
+        oe_runmake
+}
+do_install () {
+        install -d ${D}${bindir}/
+        install -m 0755 mininit-initramfs ${D}${bindir}/mininit
+        install -d ${D}/dev
+        install -d ${D}/boot
+        install -d ${D}/root
+        install -d ${D}/proc
+        install -d ${D}/sys
+}
+
+FILES_${PN} += " ${bindir}/mininit-initramfs /init /dev /boot /root /proc /sys"
+
+pkg_postinst_${PN} () {
+        ln -sf ${bindir}/mininit $D/init
+}
+
+BBCLASSEXTEND = "klibc"
+
+COMPATIBLE_MACHINE = "(akita|c7x0|collie|gcw0|h1940|h3600|hx4700|poodle|spitz|tosa)"
diff --git a/recipes-bsp/mininit/mininit_git.bb b/recipes-bsp/mininit/mininit_git.bb
deleted file mode 100644
index a0439ae..0000000
--- a/recipes-bsp/mininit/mininit_git.bb
+++ /dev/null
@@ -1,36 +0,0 @@
-SUMMARY = "mininit for romfs/squashfs loop images"
-DESCRIPTION = "mininit is a linux-as-bootloader implementation based on losetup."
-HOMEPAGE = "https://github.com/pcercuei/mininit"
-LICENSE = "PD"
-LIC_FILES_CHKSUM = "file://init.c;md5=305bd83abb9a5aac95d48b5efbc11d58"
-SRCREV = "51eaefcaea52a5dbc1addd21ba93154aa9c97d66"
-PV = "1.1.0"
-
-SRC_URI = "git://github.com/pcercuei/mininit.git"
-SRC_URI[md5sum] = "62509644735a4e599e3ed0229f283faa"
-SRC_URI[sha256sum] = "4d747b16c33ac64a7923a179947d5581b4e309b73a3c89824056e9c4f0749f18"
-
-S = "${WORKDIR}/git"
-
-do_compile () {
-        oe_runmake mininit
-}
-do_install () {
-        install -d ${D}${bindir}/
-        install -m 0755 mininit ${D}${bindir}/
-        install -d ${D}/dev
-        install -d ${D}/boot
-        install -d ${D}/root
-        install -d ${D}/proc
-        install -d ${D}/sys
-}
-
-FILES_${PN} += " ${bindir}/mininit /init /dev /boot /root /proc /sys"
-
-pkg_postinst_${PN} () {
-        ln -sf ${bindir}/mininit $D/init
-}
-
-BBCLASSEXTEND = "klibc"
-
-COMPATIBLE_MACHINE = "(akita|c7x0|collie|gcw0|h1940|h3600|hx4700|poodle|spitz|tosa)"
-- 
1.9.1