[oe] [PATCH] synergy: project has moved from synergy.googlecode.com

[Martin Jansa]

On Thu, Aug 20, 2015 at 01:19:02PM -0700, Rudolf J Streif wrote:
> The synergy project on synergy.googlecode.com is defunct. The
> sources cannot be downloaded from there anymore. The new project
> home is synergy-project.org, but sources can only be downloaded
> from ther with a login. The source code repo is on github.com/synergy.
> 
> New recipe to check out the code from GitHub. The code contains
> zip archives for gmock and gtest, which need to be extracted before
> do_configure.
> 
> Signed-off-by: Rudolf J Streif <rudolf.streif at gmail.com>
> ---
>  meta-oe/recipes-support/synergy/synergy_git.bb | 33 ++++++++++++++++++++++++++
>  1 file changed, 33 insertions(+)
>  create mode 100644 meta-oe/recipes-support/synergy/synergy_git.bb

Remove
meta-openembedded/meta-oe/recipes-support/synergy/synergy_1.3.8.bb
in the same commit.

> 
> diff --git a/meta-oe/recipes-support/synergy/synergy_git.bb b/meta-oe/recipes-support/synergy/synergy_git.bb
> new file mode 100644
> index 0000000..8650685
> --- /dev/null
> +++ b/meta-oe/recipes-support/synergy/synergy_git.bb
> @@ -0,0 +1,33 @@
> +SUMMARY = "Synergy - control multiple computers with one keyboard and mouse"
> +HOMEPAGE = "http://synergy-project.org"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=0f366945b209c5523e39889f636af00a"

Add comment in commit message explaining why license checksum is
different in this version.

> +LICENSE = "GPL-2.0"
> +SECTION = "x11/utils"
> +
> +DEPENDS = "libx11 libxtst libxinerama"

Why did you drop virtual from libx11?

DEPENDS = "virtual/libx11 libxtst libxinerama"


> +
> +SRC_URI = "git://github.com/synergy/synergy.git;protocol=http"
> +
> +# HEAD
> +SRCREV_pn-synergy ?= "${AUTOREV}"

NAK

> +
> +# Version 1.7.4-rc8
> +SRCREV_pn-synergy ?= "c734bab59ecb7703605e01438e6bff4338b5cb34"

Drop "_pn-synergy ?"

normal assignment is enough

Set PV "1.7.3+1.7.4-rc8+${SRCPV}"

> +
> +S = "${WORKDIR}/git"
> +
> +inherit cmake

What happened with distro_features_check from original recipe?

inherit cmake distro_features_check
# depends on virtual/libx11
REQUIRED_DISTRO_FEATURES = "x11"


> +
> +do_unpack_extra() {
> +    cd ${S}/ext
> +    for file in *.zip; do
> +        fname="${file##*/}"
> +        unzip $file -d ${fname%.*}
> +    done
> +}
> +addtask unpack_extra after do_unpack before do_patch
> +
> +do_install() {
> +    install -d ${D}/usr/bin
> +    install -m 0755 ${S}/bin/synergy* ${D}/usr/bin/
> +}
> -- 
> 2.1.0
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150820/1c4ee587/attachment-0002.sig>