[oe] [meta-oe][PATCH 3/3] dlm: add a new recipe

[Martin Jansa]

On Mon, Jan 05, 2015 at 03:19:54PM +0800, leimaohui wrote:
> From: leimh <leimaohui at cn.fujitsu.com>
> 
> The kernel dlm requires a user daemon to control membership.
> 
> Signed-off-by: leimh <leimaohui at cn.fujitsu.com>
> ---
>  meta-oe/recipes-extended/dlm/dlm_4.0.2.bb | 47 +++++++++++++++++++++++++++++++
>  1 file changed, 47 insertions(+)
>  create mode 100644 meta-oe/recipes-extended/dlm/dlm_4.0.2.bb
> 
> diff --git a/meta-oe/recipes-extended/dlm/dlm_4.0.2.bb b/meta-oe/recipes-extended/dlm/dlm_4.0.2.bb
> new file mode 100644
> index 0000000..b46c357
> --- /dev/null
> +++ b/meta-oe/recipes-extended/dlm/dlm_4.0.2.bb
> @@ -0,0 +1,47 @@
> +DESCRIPTION = "dlm control daemon and tool"
> +
> +SECTION = "utils"
> +HOMEPAGE = "https://fedorahosted.org/cluster/wiki/HomePage"
> +
> +SRC_URI = "https://git.fedorahosted.org/cgit/dlm.git/snapshot/dlm-${PV}.tar.xz"

dlm-${PV} -> ${BP} but more importantly is dlm.git/snapshots "stable"?
Doesn't it re-generated sometimes ?
> +
> +SRC_URI[md5sum] = "efc2ee6093aa6aa0a88aaad83e998a3f"
> +SRC_URI[sha256sum] = "b89bc557aaffbab0ac005398025f247718a5589cff6574d902eaffe2b20e683e"
> +
> +LICENSE = "LGPLv2+&GPLv2&GPLv2+"

Add spaces around &

> +LIC_FILES_CHKSUM = "file://README.license;md5=8f0bbcdd678df1bce9863492b6c8832d"
> +
> +DEPENDS = "corosync systemd"
> +
> +inherit pkgconfig systemd
> +
> +SYSTEMD_SERVICE_${PN} = "dlm.service"
> +SYSTEMD_AUTO_ENABLE = "enable"
> +
> +export EXTRA_OEMAKE = ""
> +
> +do_compile_prepend() {
> +    sed -i "s/libsystemd-daemon/libsystemd/g" ${S}/dlm_controld/Makefile
> +}
> +
> +do_compile () {
> +    oe_runmake 'CC=${CC}'
> +}
> +
> +do_install_append (){
> +	install -d ${D}${sysconfdir}/sysconfig/
> +	install -d ${D}${sysconfdir}/init.d/
> +	install -m 0644 ${S}/init/dlm.sysconfig ${D}${sysconfdir}/sysconfig/dlm
> +	install -m 0644 ${S}/init/dlm.init ${D}${sysconfdir}/init.d/dlm
> +
> +	# install systemd unit files
> +	if ${@base_contains('DISTRO_FEATURES','systemd','true','false',d)}; then
> +		install -d ${D}${systemd_unitdir}/system
> +		install -m 0644 ${S}/init/dlm.service ${D}${systemd_unitdir}/system
> +	fi
> +}

Use 4 spaces for indentation

> +
> +do_install() {
> +    oe_runmake install DESTDIR=${D} LIBDIR=${libdir}
> +}
> +
> -- 
> 1.8.4.2
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150105/b9aa7279/attachment-0002.sig>