[oe] [meta-networking][PATCH v2] openwsman: add recipe

[Joe MacDonald]

Bian,

I just wanted to be sure you had noticed the discussion on the list
regarding this submission, it has what looks like a -lm issue in the
compile stage and consequently we'll need a v3, please.  You can see an
example of the failure here:

http://errors.yoctoproject.org/Errors/Search/Details/7107/1/10/3939

Thanks,
-J.

[[oe] [meta-networking][PATCH v2] openwsman: add recipe] On 15.01.06 (Tue 13:45) Bian Naimeng wrote:

> Opensource Implementation of WS-Management
> 
> Signed-off-by: Bian Naimeng <biannm at cn.fujitsu.com>
> ---
>  .../libssl-is-required-if-eventint-supported.patch | 17 +++++++
>  .../openwsman/openwsman/openwsmand.service         | 12 +++++
>  .../openwsman/openwsman_2.4.12.bb                  | 59 ++++++++++++++++++++++
>  3 files changed, 88 insertions(+)
>  create mode 100644 meta-networking/recipes-protocols/openwsman/openwsman/libssl-is-required-if-eventint-supported.patch
>  create mode 100644 meta-networking/recipes-protocols/openwsman/openwsman/openwsmand.service
>  create mode 100644 meta-networking/recipes-protocols/openwsman/openwsman_2.4.12.bb
> 
> diff --git a/meta-networking/recipes-protocols/openwsman/openwsman/libssl-is-required-if-eventint-supported.patch b/meta-networking/recipes-protocols/openwsman/openwsman/libssl-is-required-if-eventint-supported.patch
> new file mode 100644
> index 0000000..bd540e3
> --- /dev/null
> +++ b/meta-networking/recipes-protocols/openwsman/openwsman/libssl-is-required-if-eventint-supported.patch
> @@ -0,0 +1,17 @@
> +libssl is required by wsman_client_transport if ENABLE_EVENTING_SUPPORT enabled.
> +
> +Signed-off-by: Bian Naimeng <biannm at cn.fujitsu.com>
> +
> +diff -Nurp openwsman-2.4.12.orig/src/lib/CMakeLists.txt openwsman-2.4.12/src/lib/CMakeLists.txt
> +--- openwsman-2.4.12.orig/src/lib/CMakeLists.txt	2014-10-28 23:04:47.000000000 +0800
> ++++ openwsman-2.4.12/src/lib/CMakeLists.txt	2014-12-31 11:09:20.340428523 +0800
> +@@ -56,6 +56,9 @@ TARGET_LINK_LIBRARIES( ${WSMAN_CLIENT_TR
> + SET_TARGET_PROPERTIES( ${WSMAN_CLIENT_TRANSPORT_PKG} PROPERTIES VERSION 1.0.0 SOVERSION 1)
> + INSTALL(TARGETS ${WSMAN_CLIENT_TRANSPORT_PKG} DESTINATION ${LIB_INSTALL_DIR})
> + 
> ++IF( ENABLE_EVENTING_SUPPORT )
> ++TARGET_LINK_LIBRARIES( ${WSMAN_CLIENT_TRANSPORT_PKG} ${OPENSSL_LIBRARIES} )
> ++ENDIF( ENABLE_EVENTING_SUPPORT )
> + 
> + ############### wsman_client ###############
> + 
> diff --git a/meta-networking/recipes-protocols/openwsman/openwsman/openwsmand.service b/meta-networking/recipes-protocols/openwsman/openwsman/openwsmand.service
> new file mode 100644
> index 0000000..154f3cd
> --- /dev/null
> +++ b/meta-networking/recipes-protocols/openwsman/openwsman/openwsmand.service
> @@ -0,0 +1,12 @@
> +[Unit]
> +Description=Openwsman WS-Management Service
> +After=syslog.target
> +
> +[Service]
> +Type=forking
> +ExecStart=@SBINDIR@/openwsmand
> +ExecStartPre=@SYSCONFDIR@/openwsman/owsmangencert.sh
> +PIDFile=@LOCALSTATEDIR@/run/wsmand.pid
> +
> +[Install]
> +WantedBy=multi-user.target
> diff --git a/meta-networking/recipes-protocols/openwsman/openwsman_2.4.12.bb b/meta-networking/recipes-protocols/openwsman/openwsman_2.4.12.bb
> new file mode 100644
> index 0000000..f188b1d
> --- /dev/null
> +++ b/meta-networking/recipes-protocols/openwsman/openwsman_2.4.12.bb
> @@ -0,0 +1,59 @@
> +SUMMARY = "Opensource Implementation of WS-Management"
> +DESCRIPTION = "Openwsman is a project intended to provide an open-source \
> +implementation of the Web Services Management specipication \
> +(WS-Management) and to expose system management information on the \
> +Linux operating system using the WS-Management protocol. WS-Management \
> +is based on a suite of web services specifications and usage \
> +requirements that exposes a set of operations focused on and covers \
> +all system management aspects. \
> +Openwsman Server and service libraries"
> +HOMEPAGE = "http://www.openwsman.org/"
> +SECTION = "Applications/System"
> +
> +DEPENDS = "curl libxml2 openssl libpam"
> +
> +SRC_URI = "https://github.com/Openwsman/openwsman/archive/v2.4.12.tar.gz \
> +           file://libssl-is-required-if-eventint-supported.patch \
> +           file://openwsmand.service"
> +
> +SRC_URI[md5sum] = "4893a41c6fd89b33095c315c79638a75"
> +SRC_URI[sha256sum] = "6a4b75dfff1a51c7bc09fd1d44abbde55ae74906f3828797ce391883358120f4"
> +
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=d4f53d4c6cf73b9d43186ce3be6dd0ba"
> +
> +inherit systemd cmake pkgconfig pythonnative perlnative
> +
> +SYSTEMD_SERVICE_${PN} = "openwsmand.service"
> +SYSTEMD_AUTO_ENABLE = "disable"
> +
> +EXTRA_OECMAKE = "-DBUILD_BINDINGS=NO -DBUILD_LIBCIM=NO -DBUILD_PERL=YES \
> +                 -DCMAKE_INSTALL_PREFIX=${prefix} -DLIB=lib"
> +
> +do_configure_prepend() {
> +    export HOST_SYS=${HOST_SYS}
> +    export BUILD_SYS=${BUILD_SYS}
> +    export STAGING_INCDIR=${STAGING_INCDIR}
> +    export STAGING_LIBDIR=${STAGING_LIBDIR}
> +}
> +
> +do_install_append() {
> +    install -d ${D}/${sysconfdir}/init.d
> +    install -m 755 ${B}/etc/init/openwsmand.sh ${D}/${sysconfdir}/init.d/openwsmand
> +    ln -sf ${sysconfdir}/init.d/openwsmand ${D}/${sbindir}/rcopenwsmand
> +
> +    if ${@base_contains('DISTRO_FEATURES','systemd','true','false',d)}; then
> +        install -d ${D}/${systemd_unitdir}/system
> +        install -m 644 ${WORKDIR}/openwsmand.service ${D}/${systemd_unitdir}/system
> +
> +        sed -i -e 's, at SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/openwsmand.service
> +        sed -i -e 's, at SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/openwsmand.service
> +        sed -i -e 's, at LOCALSTATEDIR@,${localstatedir},g' ${D}${systemd_unitdir}/system/openwsmand.service
> +    fi
> +}
> +
> +FILES_${PN}-dbg += "${libdir}/openwsman/plugins/.debug/ \
> +                    ${libdir}/openwsman/authenticators/.debug/ \
> +                   "
> +
> +INSANE_SKIP_${PN} = "dev-so"
> -- 
> 1.9.1
> 
-- 
-Joe MacDonald.
:wq
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 490 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150109/d4333795/attachment-0002.sig>