[oe] [PATCH v2] [meta-oe] opencv: Add OpenCV 3.0
Martin Jansa
martin.jansa at gmail.com
Fri Jul 3 15:27:35 UTC 2015
On Tue, Jun 09, 2015 at 04:13:09PM +0200, Ricardo Ribalda Delgado wrote:
> -Support for new PACKAGECONFIGS
> -Merge with opencv-samples
>
> Since it is not backward compatible with 2.x and cannot be installed in
> parallel it has a DEFAULT_PREFERENCE of -1.
>
> Signed-off-by: Ricardo Ribalda Delgado <ricardo.ribalda at gmail.com>
> ---
> meta-oe/recipes-support/opencv/opencv_3.0.bb | 127 +++++++++++++++++++++++++++
> 1 file changed, 127 insertions(+)
> create mode 100644 meta-oe/recipes-support/opencv/opencv_3.0.bb
>
> diff --git a/meta-oe/recipes-support/opencv/opencv_3.0.bb b/meta-oe/recipes-support/opencv/opencv_3.0.bb
> new file mode 100644
> index 000000000000..60a96af1fe68
> --- /dev/null
> +++ b/meta-oe/recipes-support/opencv/opencv_3.0.bb
> @@ -0,0 +1,127 @@
> +SUMMARY = "Opencv : The Open Computer Vision Library"
> +HOMEPAGE = "http://opencv.willowgarage.com/wiki/"
> +SECTION = "libs"
> +
> +LICENSE = "BSD"
> +LIC_FILES_CHKSUM = "file://include/opencv2/opencv.hpp;endline=41;md5=6d690d8488a6fca7a2c192932466bb14"
> +
> +ARM_INSTRUCTION_SET = "arm"
> +
> +DEPENDS = "python-numpy libtool swig swig-native python bzip2 zlib glib-2.0 oracle-jse-jdk ant"
meta-oe doesn't depend on meta-java layer, so this cannot be added here
ERROR: Nothing PROVIDES 'oracle-jse-jdk' (but
/home/jenkins/oe/world/shr-core/meta-openembedded/meta-oe/recipes-support/opencv/opencv_3.0.bb
DEPENDS on or otherwise requires it)
ERROR: Nothing PROVIDES 'ant' (but
/home/jenkins/oe/world/shr-core/meta-openembedded/meta-oe/recipes-support/opencv/opencv_3.0.bb
DEPENDS on or otherwise requires it). Close matches:
Is it possible to disable java part with PACKAGECONFIG?
> +
> +DEFAULT_PREFERENCE = "-1"
> +
> +SRCREV_opencv = "424c2bddb39dae97dc4639a24eaa0e0c8fbb8e69"
> +SRCREV_contrib = "844c30e8b2f2f4b34b96a169fafe9beea3c45e87"
> +SRCREV_FORMAT = "opencv"
> +SRC_URI = "git://github.com/Itseez/opencv.git;nobranch=1;name=opencv \
> + git://github.com/Itseez/opencv_contrib.git;nobranch=1;destsuffix=contrib;name=contrib"
Don't use nobranch=1 when it's not needed:
OE @ ~/projects/opencv $ git branch -a --contains 424c2bddb39dae97dc4639a24eaa0e0c8fbb8e69
* master
remotes/origin/HEAD -> origin/master
remotes/origin/master
OE @ ~/projects/opencv $ cd ../opencv_contrib/
OE @ ~/projects/opencv_contrib $ git branch -a --contains 844c30e8b2f2f4b34b96a169fafe9beea3c45e87
* master
remotes/origin/HEAD -> origin/master
remotes/origin/master
> +
> +PV = "3.0+git${SRCPV}"
> +
> +S = "${WORKDIR}/git"
> +
> +EXTRA_OECMAKE = "-DPYTHON2_NUMPY_INCLUDE_DIRS:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include \
> + -DOPENCV_EXTRA_MODULES_PATH=${WORKDIR}/contrib/modules \
> + -DWITH_1394=OFF \
> + -DCMAKE_SKIP_RPATH=ON \
> + ${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \
> + ${@base_conditional("libdir", "/usr/lib64", "-DLIB_SUFFIX=64", "", d)} \
> + ${@base_conditional("libdir", "/usr/lib32", "-DLIB_SUFFIX=32", "", d)} \
> +"
> +
> +PACKAGECONFIG ??= "eigen jpeg libav png tiff v4l tbb samples\
> + ${@bb.utils.contains("DISTRO_FEATURES", "x11", "gtk", "", d)}"
> +PACKAGECONFIG[eigen] = "-DWITH_EIGEN=ON,-DWITH_EIGEN=OFF,libeigen,"
> +PACKAGECONFIG[gtk] = "-DWITH_GTK=ON,-DWITH_GTK=OFF,gtk+3,"
> +PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON,-DWITH_JPEG=OFF,jpeg,"
> +PACKAGECONFIG[libav] = "-DWITH_FFMPEG=ON,-DWITH_FFMPEG=OFF,libav,"
> +PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng,"
> +PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff,"
> +PACKAGECONFIG[v4l] = "-DWITH_V4L=ON,-DWITH_V4L=OFF,v4l-utils,"
> +PACKAGECONFIG[jasper] = "-DWITH_JASPER=ON,-DWITH_JASPER=OFF,jasper,"
> +PACKAGECONFIG[amdblas] = "-DWITH_OPENCLAMDBLAS=ON,-DWITH_OPENCLAMDBLAS=OFF,libclamdblas,"
> +PACKAGECONFIG[amdfft] = "-DWITH_OPENCLAMDFFT=ON,-DWITH_OPENCLAMDFFT=OFF,libclamdfft,"
> +PACKAGECONFIG[opencl] = "-DWITH_OPENCL=ON,-DWITH_OPENCL=OFF,opencl-headers,"
> +PACKAGECONFIG[gstreamer] = "-DWITH_GSTREAMER=ON,-DWITH_GSTREAMER=OFF,gstreamer1.0 gstreamer1.0-plugins-base,"
> +PACKAGECONFIG[oracle-java-amd64] = "-DJAVA_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_INCLUDE_PATH2=${JAVA_HOME}/include/linux -DJAVA_AWT_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_AWT_LIBRARY=${JAVA_HOME}/lib/amd64/libjawt.so -DJAVA_JVM_LIBRARY=${JAVA_HOME}/lib/amd64/server/libjvm.so,,oracle-jse-jdk ant,"
> +PACKAGECONFIG[samples] = "-DBUILD_EXAMPLES=ON -DINSTALL_PYTHON_EXAMPLES=ON,-DBUILD_EXAMPLES=OFF,,"
> +PACKAGECONFIG[tbb] = "-DWITH_TBB=ON,-DWITH_TBB=OFF,tbb,"
> +
> +inherit distutils-base pkgconfig cmake
> +
> +export BUILD_SYS
> +export HOST_SYS
> +export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}"
> +export PYTHON="${STAGING_BINDIR_NATIVE}/python"
> +export JAVA_HOME="${STAGING_DIR_TARGET}/usr/share/java/"
> +export ANT_DIR="${STAGING_DIR_TARGET}/usr/share/ant/"
> +
> +TARGET_CC_ARCH += "-I${S}/include "
> +
> +PACKAGES += "${PN}-java-dbg ${PN}-java ${PN}-samples-dbg ${PN}-samples ${PN}-apps python-opencv"
> +
> +python populate_packages_prepend () {
> + cv_libdir = d.expand('${libdir}')
> + cv_libdir_dbg = d.expand('${libdir}/.debug')
> + do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True)
> + do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
> + do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
> + do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True)
> +
> + pn = d.getVar('PN', 1)
> + metapkg = pn + '-dev'
> + d.setVar('ALLOW_EMPTY_' + metapkg, "1")
> + blacklist = [ metapkg ]
> + metapkg_rdepends = [ ]
> + packages = d.getVar('PACKAGES', 1).split()
> + for pkg in packages[1:]:
> + if not pkg in blacklist and not pkg in metapkg_rdepends and pkg.endswith('-dev'):
> + metapkg_rdepends.append(pkg)
> + d.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rdepends))
> +
> + blacklist = [ metapkg ]
> + metapkg_rdepends = [ ]
> + for pkg in packages[1:]:
> + if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.endswith('-dbg') and not pkg.endswith('-doc') :
> + metapkg_rdepends.append(pkg)
> + bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
> +
> +}
> +
> +PACKAGES_DYNAMIC += "^libopencv-.*"
> +
> +FILES_${PN} = ""
> +FILES_${PN}-apps = "${bindir}/* ${datadir}/OpenCV"
> +FILES_${PN}-dbg += "${libdir}/.debug"
> +FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig"
> +FILES_${PN}-doc = "${datadir}/OpenCV/doc"
> +FILES_${PN}-java = "${datadir}/OpenCV/java"
> +FILES_${PN}-java-dbg = "${datadir}/OpenCV/java/.debug/"
> +FILES_${PN}-samples = "${datadir}/OpenCV/samples/"
> +FILES_${PN}-samples-dbg = "${datadir}/OpenCV/samples/bin/.debug"
> +
> +INSANE_SKIP_${PN}-apps = "staticdev"
> +INSANE_SKIP_${PN}-java = "libdir"
> +INSANE_SKIP_${PN}-java-dbg = "libdir"
> +
> +ALLOW_EMPTY_${PN} = "1"
> +
> +INSANE_SKIP_python-opencv = "True"
> +SUMMARY_python-opencv = "Python bindings to opencv"
> +FILES_python-opencv = "${PYTHON_SITEPACKAGES_DIR}/*"
> +RDEPENDS_python-opencv = "python-core python-numpy"
> +
> +do_install_append() {
> + cp ${S}/include/opencv/*.h ${D}${includedir}/opencv/
> + sed -i '/blobtrack/d' ${D}${includedir}/opencv/cvaux.h
> +
> + # Move Python files into correct library folder (for multilib build)
> + if [ "$libdir" != "/usr/lib" ]; then
> + mv ${D}/usr/lib/* ${D}/${libdir}/
> + rm -rf ${D}/usr/lib
> + fi
> +
> + install -d ${D}${datadir}/OpenCV/samples/bin/
> + cp -f bin/*-tutorial-* bin/*-example-* ${D}${datadir}/OpenCV/samples/bin/
> +}
> --
> 2.1.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150703/bc57a93e/attachment-0002.sig>
More information about the Openembedded-devel
mailing list