[oe] [PATCH] ntimed: add recipe to meta-networking (git version)

[Khem Raj]

On Sat, May 30, 2015 at 5:31 PM, Christopher Larson <kergoth at gmail.com> wrote:
> Ntimed is an unreleased ntpd replacement being sponsored by the Linux
> Foundation. Currently it only includes a work-in-progress client, but for
> future use this recipe emits an ntimed-client package and an ntimed meta
> package which will pull in client and server.
>

should it have RCONFLICTS with ntp ?

> Signed-off-by: Christopher Larson <kergoth at gmail.com>
> ---
>  .../ntimed/ntimed/use-ldflags.patch                | 16 +++++++++
>  .../recipes-support/ntimed/ntimed_git.bb           | 41 ++++++++++++++++++++++
>  2 files changed, 57 insertions(+)
>  create mode 100644 meta-networking/recipes-support/ntimed/ntimed/use-ldflags.patch
>  create mode 100644 meta-networking/recipes-support/ntimed/ntimed_git.bb
>
> diff --git a/meta-networking/recipes-support/ntimed/ntimed/use-ldflags.patch b/meta-networking/recipes-support/ntimed/ntimed/use-ldflags.patch
> new file mode 100644
> index 0000000..87a7778
> --- /dev/null
> +++ b/meta-networking/recipes-support/ntimed/ntimed/use-ldflags.patch
> @@ -0,0 +1,16 @@
> +Obey LDFLAGS.
> +
> +Signed-off-by: Christopher Larson <kergoth at gmail.com>
> +Upstream-Status: Pending
> +
> +--- Ntimed.orig/configure      2015-05-30 11:57:59.927796993 -0700
> ++++ Ntimed/configure   2015-05-30 11:58:26.143948894 -0700
> +@@ -142,7 +142,7 @@
> +
> +       echo
> +       echo "ntimed-client:    ${l}"
> +-      echo "  \${CC} \${CFLAGS} -o ntimed-client ${l} -lm"
> ++      echo "  \${CC} \${CFLAGS} -o ntimed-client ${l} \${LDFLAGS} -lm"
> +       echo
> +       echo "clean:"
> +       echo "  rm -f ${l} ntimed-client"
> diff --git a/meta-networking/recipes-support/ntimed/ntimed_git.bb b/meta-networking/recipes-support/ntimed/ntimed_git.bb
> new file mode 100644
> index 0000000..0990541
> --- /dev/null
> +++ b/meta-networking/recipes-support/ntimed/ntimed_git.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "Network time synchronization software, NTPD replacement"
> +DESCRIPTION = "This is a preview/early-access/alpha/buzzword-of-the-times \
> +release of a new FOSS project written to gradually take over the world of \
> +networked timekeeping."
> +HOMEPAGE = "https://github.com/bsdphk/Ntimed"
> +SECTION = "console/network"
> +
> +LICENSE = "BSD-2-Clause"
> +LIC_FILES_CHKSUM = "file://main.c;startline=2;endline=24;md5=eda11d21005319bb76cbb6f911f0f66d"
> +
> +SRC_URI = "git://github.com/bsdphk/Ntimed \
> +           file://use-ldflags.patch"
> +
> +PV = "0.0+git${SRCPV}"
> +SRCREV = "db0abbb4c80f2ecef6bc5d9639bca5bea28532a2"
> +
> +S = "${WORKDIR}/git"
> +
> +EXTRA_OEMAKE = "\
> +    'CC=${CC}' \
> +    'CFLAGS=${CFLAGS}' \
> +    'LDFLAGS=${LDFLAGS}' \
> +"
> +
> +do_configure () {
> +    sh ./configure
> +}
> +
> +do_compile () {
> +    oe_runmake
> +}
> +
> +do_install () {
> +    install -D -m 0755 ntimed-client ${D}${sbindir}/ntimed-client
> +}
> +
> +ALLOW_EMPTY_${PN} = "1"
> +RDEPENDS_${PN} += "ntimed-client"
> +
> +PACKAGE_BEFORE_PN += "ntimed-client"
> +FILES_ntimed-client = "${sbindir}/ntimed-client"
> --
> 2.2.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel