[oe] [meta-oe][PATCH] Add smstools3 http://smstools3.kekekasvi.com to meta-oe recipes-connectivity.

[Martin Jansa]

subject should start with smstools3:

On Mon, Mar 16, 2015 at 06:48:17PM +0100, Kai Ulrich wrote:
> From: kulrich <ulrich.kai at gmail.com>
> 
> Signed-off-by: kulrich <ulrich.kai at gmail.com>
> ---
>  .../smstools3/sms_binpath_and_psops.patch          | 19 ++++++++++
>  .../smstools3/smstools3_3.1.15.bb                  | 44 ++++++++++++++++++++++
>  2 files changed, 63 insertions(+)
>  create mode 100644 meta-oe/recipes-connectivity/smstools3/smstools3/sms_binpath_and_psops.patch
>  create mode 100644 meta-oe/recipes-connectivity/smstools3/smstools3_3.1.15.bb
> 
> diff --git a/meta-oe/recipes-connectivity/smstools3/smstools3/sms_binpath_and_psops.patch b/meta-oe/recipes-connectivity/smstools3/smstools3/sms_binpath_and_psops.patch
> new file mode 100644
> index 0000000..ffcaa09
> --- /dev/null
> +++ b/meta-oe/recipes-connectivity/smstools3/smstools3/sms_binpath_and_psops.patch
> @@ -0,0 +1,19 @@
> +Index: smstools3/scripts/sms3
> +===================================================================
> +--- smstools3.orig/scripts/sms3	2010-05-04 11:21:44.000000000 +0200
> ++++ smstools3/scripts/sms3	2015-02-22 20:05:51.615074469 +0100
> +@@ -24,11 +24,11 @@
> + # Logfile can also be defined in here:
> + LOGFILE="/var/log/smsd.log"
> + 
> +-DAEMON=/usr/local/bin/smsd
> ++DAEMON=/usr/bin/smsd
> + # A program which turns power off for couple of seconds:
> +-RESETMODEMS=/usr/local/bin/smsd_resetmodems
> ++RESETMODEMS=/usr/bin/smsd_resetmodems
> + NAME=smsd
> +-PSOPT="-e"
> ++PSOPT=""
> + ECHO=echo
> + case `uname` in
> +   *BSD|Darwin)
> diff --git a/meta-oe/recipes-connectivity/smstools3/smstools3_3.1.15.bb b/meta-oe/recipes-connectivity/smstools3/smstools3_3.1.15.bb
> new file mode 100644
> index 0000000..55a2583
> --- /dev/null
> +++ b/meta-oe/recipes-connectivity/smstools3/smstools3_3.1.15.bb
> @@ -0,0 +1,44 @@
> +SUMMARY = "The SMS Server Tools 3 is a SMS Gateway software which can send and receive short messages through GSM modems and mobile phones."

SUMMARY should be short, split to SUMMARY and DESCRIPTION.

> +SECTION = "network"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=4d21efa1bb2a186360dde4035f860682"
> +HOMEPAGE = "http://smstools3.kekekasvi.com"
> +
> +SRC_URI = "http://smstools3.kekekasvi.com/packages/${PN}-${PV}.tar.gz \

${PN}-${PV} -> ${BP}

> +           file://sms_binpath_and_psops.patch"
> +
> +SRC_URI[md5sum] = "0241ef60e646fac1a06254a848e61ed7"
> +SRC_URI[sha256sum] = "ed00ffaeaa312a5b4f969f4e97a64603a866bbe16e393ea02f5bf05234814d59"
> +
> +
> +S = "${WORKDIR}/${PN}"
> +
> +RDEPENDS_${PN} = " bash "

drop unnecessary spaces around bash.

> +INITSCRIPT_NAME = "sms3"
> +INITSCRIPT_PARAMS = "defaults"
> +
> +inherit update-rc.d
> +
> +do_install () {
> +	
> +	install -d ${D}${bindir}	
> +	install -m 755 ${S}/src/smsd "${D}${bindir}/smsd"
> +	
> +	install -m 755 ${S}/scripts/sendsms "${D}${bindir}/sendsms"
> +	install -m 755 ${S}/scripts/sms2html "${D}${bindir}/sms2html"
> +	install -m 755 ${S}/scripts/sms2unicode "${D}${bindir}/sms2unicode" 
> +	install -m 755 ${S}/scripts/unicode2sms "${D}${bindir}/unicode2sms"
> +
> +	install -d ${D}${sysconfdir}	
> +	install -m 644 ${S}/examples/smsd.conf.easy "${D}${sysconfdir}/smsd.conf"
> +
> +	install -d "${D}${localstatedir}/spool"
> +	install -d "${D}${localstatedir}/spool/sms"
> +	install -d "${D}${localstatedir}/spool/sms/incoming"
> +	install -d "${D}${localstatedir}/spool/sms/outgoing"
> +	install -d "${D}${localstatedir}/spool/sms/checked"
> +
> +	install -d ${D}${sysconfdir}/init.d
> +	install -m 755 ${S}/scripts/sms3 "${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}"
> +
> +}
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150317/fd9974bf/attachment-0002.sig>