[oe] [PATCH 3/3][meta-multimedia] rygel: Add recipe

[Manuel Bachmann]

Rygel is a UPnP Audio-Video media server, that allows to
share media files to other devices. It can also become a
MediaRenderer controlled by UPnP or DLNA Controllers.

Rygel makes use of the GStreamer library to recognize and
index media files. UPnp clients will then be able to browse
through them with the aid of metadata (artist, date...).

(we do not propose to build without GStreamer support,
because then if cannot parse any actual media file, and
this is pointless)

Signed-off-by: Manuel Bachmann <manuel.bachmann at iot.bzh>
---
 meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb     | 32 ++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100644 meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb

diff --git a/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb b/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
new file mode 100644
index 0000000..e118901
--- /dev/null
+++ b/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
@@ -0,0 +1,32 @@
+SUMMARY = "A UPnP AV media server and renderer"
+DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \
+allow you to easily share audio, video and pictures to other devices. \
+Additionally, media player software may use Rygel to become a MediaRenderer \
+that may be controlled remotely by a UPnP or DLNA Controller."
+
+LICENSE = "LGPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
+                    file://src/rygel/rygel-main.vala;endline=25;md5=a4cce4d389da1c1638fe68d07ae9d811"
+
+DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base ossp-uuid libgee libsoup-2.4 libmediaart-2.0"
+RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback"
+
+GNOME_COMPRESS_TYPE = "xz"
+SRC_URI[archive.md5sum] = "f182d54913a528bb5b4fb2f291aca0fc"
+SRC_URI[archive.sha256sum] = "390740609e34399b886ddb9a8f7eca25055ad72048dfdd869edf02999b1e1d8f"
+
+inherit gnomebase
+
+EXTRA_OECONF = "--disable-introspection --disable-tracker-plugin --with-media-engine=gstreamer"
+
+PACKAGECONFIG ?= "gtk+3"
+PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3"
+
+do_install_append() {
+       rm -f ${D}/${libdir}/rygel-2.6/engines/*.la
+       rm -f ${D}/${libdir}/rygel-2.6/plugins/*.la
+       rm -rf ${D}/${datadir}/vala
+}
+
+FILES_${PN} += "${libdir}/rygel-2.6 ${datadir}/dbus-1 ${datadir}/icons"
+FILES_${PN}-dbg += "${libdir}/rygel-2.6/engines/.debug ${libdir}/rygel-2.6/plugins/.debug"
-- 
1.8.3.1