[oe] [PATCH 3/3 v2][meta-multimedia] rygel: Add recipe

[Khem Raj]

> On Oct 8, 2015, at 1:10 AM, Manuel Bachmann <manuel.bachmann at iot.bzh> wrote:
> 
> Rygel is a UPnP Audio-Video media server, that allows to
> share media files to other devices. It can also become a
> MediaRenderer controlled by UPnP or DLNA Controllers.
> 
> Rygel makes use of the GStreamer library to recognize and
> index media files. UPnp clients will then be able to browse
> through them with the aid of metadata (artist, date...).
> 
> We do not propose to build without GStreamer support
> (because then if cannot parse any actual media file, and
> this is pointless), and for the same reason always include
> the GStreamer engine in the main package ; but allow
> separate packages for plugins.
> 
> (disable tracker plugin for now, because it pulls 3 layers
> and needs us to have a PREFERRED udev provider, which is a
> bit extreme for a first version)
> 
> Signed-off-by: Manuel Bachmann <manuel.bachmann at iot.bzh>
> Author: Manuel Bachmann <manuel.bachmann at iot.bzh>
> Author: Ross Burton <ross.burton at intel.com>
> ---
> .../recipes-connectivity/rygel/rygel_0.26.1.bb     | 59 ++++++++++++++++++++++
> 1 file changed, 59 insertions(+)
> create mode 100644 meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> 
> diff --git a/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb b/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> new file mode 100644
> index 0000000..3862b1e
> --- /dev/null
> +++ b/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> @@ -0,0 +1,59 @@
> +SUMMARY = "A UPnP AV media server and renderer"
> +DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \
> +allow you to easily share audio, video and pictures to other devices. \
> +Additionally, media player software may use Rygel to become a MediaRenderer \
> +that may be controlled remotely by a UPnP or DLNA Controller."
> +HOMEPAGE = "http://live.gnome.org/Rygel"
> +
> +LICENSE = "LGPLv2+"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
> +                    file://src/rygel/rygel-main.vala;endline=25;md5=a4cce4d389da1c1638fe68d07ae9d811"
> +
> +DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base ossp-uuid libgee libsoup-2.4 libmediaart-2.0"
> +RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback shared-mime-info"
> +
> +GNOME_COMPRESS_TYPE = “xz"

isn’t this default ?

> +SRC_URI[archive.md5sum] = "f182d54913a528bb5b4fb2f291aca0fc"
> +SRC_URI[archive.sha256sum] = "390740609e34399b886ddb9a8f7eca25055ad72048dfdd869edf02999b1e1d8f"
> +
> +inherit gnomebase
> +
> +EXTRA_OECONF = "--disable-introspection --disable-tracker-plugin --with-media-engine=gstreamer"
> +
> +PACKAGECONFIG ?= "external mpris mediathek ruih media-export gst-launch gtk+3"
> +PACKAGECONFIG[external] = "--enable-external-plugin,--disable-external-plugin"
> +PACKAGECONFIG[mpris] = "--enable-mpris-plugin,--disable-mpris-plugin"
> +PACKAGECONFIG[mediathek] = "--enable-mediathek-plugin,--disable-mediathek-plugin"
> +PACKAGECONFIG[ruih] = "--enable-ruih-plugin,--disable-ruih-plugin"
> +PACKAGECONFIG[media-export] = "--enable-media-export-plugin,--disable-media-export-plugin,sqlite3"
> +PACKAGECONFIG[gst-launch] = "--enable-gst-launch-plugin,--disable-gst-launch-plugin"
> +PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3"
> +
> +LIBV = "2.6"
> +
> +do_install_append() {
> +       # Remove .la files for loadable modules
> +       rm -f ${D}/${libdir}/rygel-${LIBV}/engines/*.la
> +       rm -f ${D}/${libdir}/rygel-${LIBV}/plugins/*.la
> +}
> +
> +FILES_${PN} += "${libdir}/rygel-${LIBV}/engines ${datadir}/dbus-1 ${datadir}/icons"
> +FILES_${PN}-dev += "${datadir}/vala”

did you miss to add vala in DEPENDS ?

> +FILES_${PN}-dbg += "${libdir}/rygel-${LIBV}/engines/.debug ${libdir}/rygel-${LIBV}/plugins/.debug"
> +
> +PACKAGES += "${PN}-meta"
> +ALLOW_EMPTY_${PN}-meta = "1"
> +
> +PACKAGES_DYNAMIC = "${PN}-plugin-*"
> +
> +python populate_packages_prepend () {
> +    rygel_libdir = d.expand('${libdir}/rygel-${LIBV}')
> +    postinst = d.getVar('plugin_postinst', True)
> +    pkgs = []
> +
> +    pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), 'librygel-(.*)\.so$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> +    pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), '(.*)\.plugin$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> +
> +    metapkg = d.getVar('PN', True) + '-meta'
> +    d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
> +}
> --
> 1.8.3.1
> 
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 204 bytes
Desc: Message signed with OpenPGP using GPGMail
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20151009/8846c0d8/attachment-0002.sig>