[oe] [meta-oe][PATCH] plymouth: Add recipe

[Andreas Müller]

Played around a bit with this and have two notes (which could be done
as follow up - depends on Martin's apply queue)

On Thu, Sep 3, 2015 at 9:39 AM, Khem Raj <raj.khem at gmail.com> wrote:
> Signed-off-by: Khem Raj <raj.khem at gmail.com>
> ---
>  meta-oe/recipes-core/plymouth/plymouth_0.9.2.bb | 61 +++++++++++++++++++++++++
>  1 file changed, 61 insertions(+)
>  create mode 100644 meta-oe/recipes-core/plymouth/plymouth_0.9.2.bb
>
> diff --git a/meta-oe/recipes-core/plymouth/plymouth_0.9.2.bb b/meta-oe/recipes-core/plymouth/plymouth_0.9.2.bb
> new file mode 100644
> index 0000000..b8c82ed
> --- /dev/null
> +++ b/meta-oe/recipes-core/plymouth/plymouth_0.9.2.bb
> @@ -0,0 +1,61 @@
> +SUMMARY = "Plymouth is a project from Fedora providing a flicker-free graphical boot process."
> +
> +DESCRIPTION = "Plymouth is an application that runs very early in the boot process \
> +               (even before the root filesystem is mounted!) that provides a \
> +              graphical boot animation while the boot process happens in the background."
> +
> +HOMEPAGE = "http://www.freedesktop.org/wiki/Software/Plymouth"
> +SECTION = "base"
> +
> +LICENSE = "GPLv2+"
> +
> +LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
> +
> +DEPENDS = "libcap libpng cairo dbus udev"
> +PROVIDES = "virtual/psplash"
> +RPROVIDES_${PN} = "virtual/psplash virtual/psplash-support"
> +
> +SRC_URI = "http://www.freedesktop.org/software/plymouth/releases/${BPN}-${PV}.tar.bz2"
> +SRC_URI[md5sum] = "ff420994deb7ea203df678df92e7ab7d"
> +SRC_URI[sha256sum] = "2f0ce82042cf9c7eadd2517a1f74c8a85fa8699781d9f294a06eade29fbed57f"
> +
> +EXTRA_OECONF += " --enable-shared --disable-static --disable-gtk \
^ --disable-gtk is set by PACKAGCONFIG
> +                 --with-logo=${LOGO} \
> +                  ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-systemd-integration --with-system-root-install', '', d)} \
> +                "
> +
> +PACKAGECONFIG[drm] = "--enable-drm,--disable-drm,libdrm"
> +PACKAGECONFIG[pango] = "--enable-pango,--disable-pango,pango"
> +PACKAGECONFIG[gtk] = "--enable-gtk,--disable-gtk,gtk+"
> +
> +PACKAGECONFIG ??= "pango"
> +
> +LOGO ??= "${datadir}/plymouth/bizcom.png"
> +
> +PACKAGECONFIG_append_x86 = " drm"
> +PACKAGECONFIG_append_x86-64 = " drm"
> +
> +inherit autotools pkgconfig systemd
> +
> +
> +do_install_append() {
> +       install -d ${D}${systemd_unitdir}/system
> +       install -m 644 ${B}/systemd-units/*.service ${D}${systemd_unitdir}/system
> +       install -m 644 ${B}/systemd-units/systemd-ask-password-plymouth.path ${D}${systemd_unitdir}/system
> +       # Remove /var/run from package as plymouth will populate it on startup
> +       rm -fr "${D}${localstatedir}/run"
> +}
> +
> +PACKAGES =+ "${PN}-initrd ${PN}-set-default-theme"
> +
> +FILES_${PN}-initrd = "${libdir}/plymouth/plymouth/*"
> +FILES_${PN}-set-default-theme = "${sbindir}/plymouth-set-default-theme"
> +
> +FILES_${PN} += "${systemd_unitdir}/system/*"
> +FILES_${PN}-dbg += "${libdir}/plymouth/renderers/.debug"
> +
> +
> +RDEPENDS_${PN}-initrd = "bash dracut"
> +RDEPENDS_${PN}-set-default-theme = "bash"
^ plymouth-set-default-theme can be called with '-R' |
'--rebuild-initrd' which makes use of plymouth's initrd-scripts. So I
would replace 'bash' by '${PN}-initrd' here
> +
> +SYSTEMD_SERVICE_${PN} = "plymouth-start.service"
> --
> 2.5.1


Andreas