[oe] [meta-oe][PATCH] wayland-fits: Add recipe

[Khem Raj]

On Sat, Sep 19, 2015 at 1:28 AM, Manuel Bachmann
<manuel.bachmann at iot.bzh> wrote:
> wayland-fits is a functional integration test suite
> for Wayland and Weston.
>
> Signed-off-by: Manuel Bachmann <manuel.bachmann at iot.bzh>
> ---
>  .../recipes-graphics/wayland/wayland-fits_git.bb   | 30 ++++++++++++++++++++++
>  1 file changed, 30 insertions(+)
>  create mode 100644 meta-oe/recipes-graphics/wayland/wayland-fits_git.bb
>
> diff --git a/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb b/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb
> new file mode 100644
> index 0000000..550e171
> --- /dev/null
> +++ b/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb
> @@ -0,0 +1,30 @@
> +SUMMARY = "Wayland-fits, the Wayland Functional Integration Test Suite"
> +DESCRIPTION = "Wayland-fits is a fully automated functional integration \
> +test suite. Its main purpose is to test the functionality and integration of \
> +client-side (i.e. toolkit) and server-side (compositor) implementations of \
> +the Wayland protocol."
> +HOMEPAGE = "https://github.com/01org/wayland-fits"
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=f8d34cadaf891753c0f00c6cd48f08f5 \
> +                    file://src/extensions/weston/weston-wfits.cpp;endline=21;md5=848c81e55cf3a30a9f6ed75f0dba7a97"
> +
> +SRC_URI = "git://github.com/01org/wayland-fits.git"
> +SRCREV = "f30dfa9fceb438d3687c5215093fffc21a7852fc"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit autotools pkgconfig
> +
> +DEPENDS = "libcheck boost wayland weston"
> +RDEPENDS_${PN} = "weston"

may be better to use += here

> +
> +EXTRA_OECONF = "--enable-shared --disable-static \
> +                --disable-efl-tests --disable-gtk-tests \
> +                --with-boost-libdir=${STAGING_LIBDIR}"

We do have EFL and GTK support in OE, would it make sense to turn it
into some sort of PACKAGECONFIG ?

> +
> +do_install_append() {
> +       rm -f ${D}/${libdir}/weston/*.la
> +}
> +
> +FILES_${PN} = "${bindir}/wfits ${libdir}/weston/*.so"
> +FILES_${PN}-dbg = "${bindir}/.debug ${libdir}/weston/.debug ${prefix}/src"

this could be += as well.

> --
> 1.8.3.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel