[oe] [PATCH v2][meta-oe] wayland-fits: Add recipe

[Manuel Bachmann]

wayland-fits is a functional integration test suite
for Wayland and Weston.

It optionally supports EFL and GTK+ tests.

Signed-off-by: Manuel Bachmann <manuel.bachmann at iot.bzh>
---
 .../recipes-graphics/wayland/wayland-fits_git.bb   |   33 ++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100755 meta-oe/recipes-graphics/wayland/wayland-fits_git.bb

diff --git a/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb b/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb
new file mode 100755
index 0000000..a0eefb5
--- /dev/null
+++ b/meta-oe/recipes-graphics/wayland/wayland-fits_git.bb
@@ -0,0 +1,33 @@
+SUMMARY = "Wayland-fits, the Wayland Functional Integration Test Suite"
+DESCRIPTION = "Wayland-fits is a fully automated functional integration \
+test suite. Its main purpose is to test the functionality and integration of \
+client-side (i.e. toolkit) and server-side (compositor) implementations of \
+the Wayland protocol."
+HOMEPAGE = "https://github.com/01org/wayland-fits"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=f8d34cadaf891753c0f00c6cd48f08f5 \
+                    file://src/extensions/weston/weston-wfits.cpp;endline=21;md5=848c81e55cf3a30a9f6ed75f0dba7a97"
+
+SRC_URI = "git://github.com/01org/wayland-fits.git"
+SRCREV = "f30dfa9fceb438d3687c5215093fffc21a7852fc"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig
+
+DEPENDS = "libcheck boost wayland weston"
+RDEPENDS_${PN} = "weston"
+
+EXTRA_OECONF += "--enable-shared --disable-static --with-boost-libdir=${STAGING_LIBDIR}"
+
+PACKAGECONFIG ?= "elementary gtk+3"
+
+PACKAGECONFIG[elementary] = "--enable-efl-tests,--disable-efl-tests,elementary"
+PACKAGECONFIG[gtk+3] = "--enable-gtk-tests,--disable-gtk-tests,gtk+3"
+
+do_install_append() {
+	rm -f ${D}/${libdir}/weston/*.la
+}
+
+FILES_${PN} += "${bindir}/wfits ${libdir}/weston/*.so"
+FILES_${PN}-dbg += "${bindir}/.debug ${libdir}/weston/.debug ${prefix}/src"
-- 
1.7.10.4