[oe] [PATCH][meta-oe] cpupower: add recipes

[Martin Jansa]

On Tue, Mar 29, 2016 at 03:28:56PM +0800, rongqing.li at windriver.com wrote:
> From: Roy Li <rongqing.li at windriver.com>
> 
> cpupower is tools to shows and sets processor power related values
> 
> Signed-off-by: Roy Li <rongqing.li at windriver.com>
> ---
>  meta-oe/recipes-kernel/cpupower/cpupower.bb | 41 +++++++++++++++++++++++++++++
>  1 file changed, 41 insertions(+)
>  create mode 100644 meta-oe/recipes-kernel/cpupower/cpupower.bb
> 
> diff --git a/meta-oe/recipes-kernel/cpupower/cpupower.bb b/meta-oe/recipes-kernel/cpupower/cpupower.bb
> new file mode 100644
> index 0000000..d53deac
> --- /dev/null
> +++ b/meta-oe/recipes-kernel/cpupower/cpupower.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "Shows and sets processor power related values"
> +DESCRIPTION = "cpupower is a collection of tools to examine and tune power \
> +saving related features of your processor."
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
> +DEPENDS = "pciutils"
> +
> +inherit kernelsrc kernel-arch
> +
> +do_configure[depends] += "virtual/kernel:do_shared_workdir"
> +do_populate_lic[depends] += "virtual/kernel:do_patch"
> +
> +PROVIDES = "virtual/cpupower"
> +
> +B = "${WORKDIR}/${BPN}-${PV}"
> +
> +EXTRA_OEMAKE = '\
> +    -C ${S}/tools/power/cpupower \
> +    O=${B} \
> +    CROSS=${TARGET_PREFIX} \
> +    ARCH=${ARCH} \
> +    CC="${CC}" \
> +    AR="${AR}" \
> +'
> +do_compile() {
> +	unset CFLAGS
> +	oe_runmake all

Use 4 spaces for indentation.

> +}
> +
> +do_install() {
> +	unset CFLAGS
> +	oe_runmake DESTDIR=${D} install
> +	chown root:root ${D}/${libdir}/*
> +}
> +
> +python do_package_prepend() {
> +    d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
> +}
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +RDEPENDS_${PN} = "bash"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20160412/9a2f6085/attachment-0002.sig>