[oe] [meta-oe][PATCH] dibbler: add initial recipe, dibbler 1.0.1

[Khem Raj]

On Thu, Dec 15, 2016 at 8:04 AM, Andre McCurdy <armccurdy at gmail.com> wrote:
> Dibbler is a portable DHCPv6 implementation.
>
>   http://klub.com.pl/dhcpv6/
>
> Signed-off-by: Andre McCurdy <armccurdy at gmail.com>
> ---
>  .../recipes-connectivity/dibbler/dibbler_1.0.1.bb  | 40 ++++++++++++++++++++++
>  1 file changed, 40 insertions(+)
>  create mode 100644 meta-oe/recipes-connectivity/dibbler/dibbler_1.0.1.bb
>
> diff --git a/meta-oe/recipes-connectivity/dibbler/dibbler_1.0.1.bb b/meta-oe/recipes-connectivity/dibbler/dibbler_1.0.1.bb
> new file mode 100644
> index 0000000..41bb78f
> --- /dev/null
> +++ b/meta-oe/recipes-connectivity/dibbler/dibbler_1.0.1.bb
> @@ -0,0 +1,40 @@
> +SUMMARY = "A portable DHCPv6 implementation"
> +DESCRIPTION = "Dibbler is a portable DHCPv6 implementation. It supports stateful \
> +(i.e. IPv6 address granting and IPv6 prefix delegation) as well as stateless (i.e. \
> +option granting) autoconfiguration for IPv6."
> +HOMEPAGE = "http://klub.com.pl/dhcpv6"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=7236695bb6d4461c105d685a8b61c4e3 \
> +                    file://bison++/COPYING;md5=8ca43cbc842c2336e835926c2166c28b"
> +
> +DEPENDS = "flex-native bison-native"
> +
> +SRC_URI = "http://klub.com.pl/dhcpv6/dibbler/dibbler-${PV}.tar.gz"

its also on sourceforge. perhaps better to use that for SRC_URI
https://sourceforge.net/projects/dibbler/

> +
> +SRC_URI[md5sum] = "93357bea3ec35b0c1d11242055361409"
> +SRC_URI[sha256sum] = "27869877e060c039cbc24a5f6a9dd69006bf67de0ffdf29a645a80aef6e476a1"
> +
> +inherit autotools
> +
> +PACKAGECONFIG ?= "auth bind-reuse dns-update dst-addr-filter link-state"
> +
> +PACKAGECONFIG[auth] = "--enable-auth,--disable-auth"
> +PACKAGECONFIG[bind-reuse] = "--enable-bind-reuse,--disable-bind-reuse"
> +PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
> +PACKAGECONFIG[dns-update] = "--enable-dns-update,--disable-dns-update"
> +PACKAGECONFIG[dst-addr-filter] = "--enable-dst-addr-filter,--disable-dst-addr-filter"
> +PACKAGECONFIG[link-state] = "--enable-link-state,--disable-link-state"
> +PACKAGECONFIG[remote-autoconf] = "--enable-remote-autoconf,--disable-remote-autoconf"
> +PACKAGECONFIG[resolvconf] = "--enable-resolvconf,--disable-resolvconf"
> +
> +EXTRA_OECONF += " \
> +    --disable-efence \
> +    --with-gtest=no \
> +"
> +
> +PACKAGES =+ "${PN}-client ${PN}-relay ${PN}-requestor ${PN}-server"
> +
> +FILES_${PN}-client = "${sbindir}/${PN}-client"
> +FILES_${PN}-relay = "${sbindir}/${PN}-relay"
> +FILES_${PN}-requestor = "${sbindir}/${PN}-requestor"
> +FILES_${PN}-server = "${sbindir}/${PN}-server"
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel