[oe] [meta-oe][PATCH] ne10: add recipe

[Martin Jansa]

On Wed, Feb 03, 2016 at 05:45:02PM +0100, Carlos Rafael Giani wrote:
> Add recipe for the Ne10 library ( http://projectne10.github.io/Ne10/ ).
> This library provides heavily ARM NEON optimized versions of functions
> that are commonly used.
> 
> Signed-off-by: Carlos Rafael Giani <dv at pseudoterminal.org>
> ---
>  meta-oe/recipes-support/ne10/ne10_1.2.1.bb | 38 ++++++++++++++++++++++++++++++
>  1 file changed, 38 insertions(+)
>  create mode 100644 meta-oe/recipes-support/ne10/ne10_1.2.1.bb
> 
> diff --git a/meta-oe/recipes-support/ne10/ne10_1.2.1.bb b/meta-oe/recipes-support/ne10/ne10_1.2.1.bb
> new file mode 100644
> index 0000000..a465e7d
> --- /dev/null
> +++ b/meta-oe/recipes-support/ne10/ne10_1.2.1.bb
> @@ -0,0 +1,38 @@
> +DESCRIPTION = "Library containing NEON-optimized implementations for a common set of functions"
> +HOMEPAGE = "http://projectne10.github.io/Ne10/"
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=463ac0a7d64edc2b787c4206635ca2b1"
> +SECTION = "libs"
> +
> +SRC_URI = "git://github.com/projectNe10/Ne10.git"
> +SRCREV = "v${PV}"

please set SRCREV to git hash, so that fetcher won't try to access
remote repo to translate tag name to SRCREV.

> +S = "${WORKDIR}/git"
> +
> +inherit cmake
> +
> +NE10_TARGET_ARCH = ""
> +EXTRA_OECMAKE = '-DGNULINUX_PLATFORM=ON -DNE10_BUILD_SHARED=ON -DNE10_LINUX_TARGET_ARCH="${NE10_TARGET_ARCH}"'
> +
> +COMPATIBLE_MACHINE_aarch64 = "(.*)"
> +COMPATIBLE_MACHINE_armv7a = "(.*)"
> +
> +python () {
> +    if any(t.startswith('armv7') for t in d.getVar('TUNE_FEATURES', True).split()):
> +        d.setVar('NE10_TARGET_ARCH', 'armv7')
> +        bb.note('Building Ne10 for armv7')
> +    elif any(t.startswith('aarch64') for t in d.getVar('TUNE_FEATURES', True).split()):
> +        d.setVar('NE10_TARGET_ARCH', 'aarch64')
> +        bb.note('Building Ne10 for aarch64')
> +    else:
> +        raise bb.parse.SkipPackage("Incompatible with archs other than armv7 and aarch64")
> +}
> +
> +do_install() {
> +        install -d ${D}${libdir}
> +        install -d ${D}${includedir}
> +        install -m 0644 ${S}/inc/NE10*.h ${D}${includedir}/
> +        install -m 0644 ${B}/modules/libNE10.a ${D}${libdir}/
> +        install -m 0755 ${B}/modules/libNE10.so.* ${D}${libdir}/
> +        cp -a ${B}/modules/libNE10.so ${D}${libdir}/

Use 4 spaces for indentation.

> +}
> -- 
> 2.5.0
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20160203/556e250e/attachment-0002.sig>