[oe] [PATCH 2/2][meta-multimedia] rygel: Update to 0.28.2
Martin Jansa
martin.jansa at gmail.com
Wed Jan 27 14:14:53 UTC 2016
On Fri, Jan 22, 2016 at 03:51:41PM +0100, Manuel Bachmann wrote:
> From: Manuel Bachmann <mbc at iot.bzh>
>
> Update to latest version. This mainly fixes file uploading,
> which did not work in previous version (see upstream commit
> "1d45866a3fd7ca47bdbea60156bd18b994710662" among others).
>
> Rygel will not keep running anymore when its "plugins"
> folder is absent or empty. Thus, to avoid disappointments,
> we now RRECOMMEND at least the "media-export" plugin.
Please resend with -M and libunistring dependency or PACKAGECONFIG.
rygel: rygel-plugin-media-export rdepends on libunistring, but it isn't a build dependency? [build-deps]
>
> Signed-off-by: Manuel Bachmann <mbc at iot.bzh>
> ---
> .../recipes-connectivity/rygel/rygel_0.26.1.bb | 58 -------------------
> .../recipes-connectivity/rygel/rygel_0.28.2.bb | 59 ++++++++++++++++++++
> 2 files changed, 59 insertions(+), 58 deletions(-)
> delete mode 100644 meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> create mode 100644 meta-multimedia/recipes-connectivity/rygel/rygel_0.28.2.bb
>
> diff --git a/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb b/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> deleted file mode 100644
> index af3f2be..0000000
> --- a/meta-multimedia/recipes-connectivity/rygel/rygel_0.26.1.bb
> +++ /dev/null
> @@ -1,58 +0,0 @@
> -SUMMARY = "A UPnP AV media server and renderer"
> -DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \
> -allow you to easily share audio, video and pictures to other devices. \
> -Additionally, media player software may use Rygel to become a MediaRenderer \
> -that may be controlled remotely by a UPnP or DLNA Controller."
> -HOMEPAGE = "http://live.gnome.org/Rygel"
> -
> -LICENSE = "LGPLv2+"
> -LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
> - file://src/rygel/rygel-main.vala;endline=25;md5=a4cce4d389da1c1638fe68d07ae9d811"
> -
> -DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base ossp-uuid libgee libsoup-2.4 libmediaart-2.0"
> -RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback shared-mime-info"
> -
> -GNOME_COMPRESS_TYPE = "xz"
> -SRC_URI[archive.md5sum] = "f182d54913a528bb5b4fb2f291aca0fc"
> -SRC_URI[archive.sha256sum] = "390740609e34399b886ddb9a8f7eca25055ad72048dfdd869edf02999b1e1d8f"
> -
> -inherit gnomebase vala
> -
> -EXTRA_OECONF = "--disable-introspection --disable-tracker-plugin --with-media-engine=gstreamer"
> -
> -PACKAGECONFIG ?= "external mpris mediathek ruih media-export gst-launch gtk+3"
> -PACKAGECONFIG[external] = "--enable-external-plugin,--disable-external-plugin"
> -PACKAGECONFIG[mpris] = "--enable-mpris-plugin,--disable-mpris-plugin"
> -PACKAGECONFIG[mediathek] = "--enable-mediathek-plugin,--disable-mediathek-plugin"
> -PACKAGECONFIG[ruih] = "--enable-ruih-plugin,--disable-ruih-plugin"
> -PACKAGECONFIG[media-export] = "--enable-media-export-plugin,--disable-media-export-plugin,sqlite3"
> -PACKAGECONFIG[gst-launch] = "--enable-gst-launch-plugin,--disable-gst-launch-plugin"
> -PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3"
> -
> -LIBV = "2.6"
> -
> -do_install_append() {
> - # Remove .la files for loadable modules
> - rm -f ${D}/${libdir}/rygel-${LIBV}/engines/*.la
> - rm -f ${D}/${libdir}/rygel-${LIBV}/plugins/*.la
> -}
> -
> -FILES_${PN} += "${libdir}/rygel-${LIBV}/engines ${datadir}/dbus-1 ${datadir}/icons"
> -FILES_${PN}-dbg += "${libdir}/rygel-${LIBV}/engines/.debug ${libdir}/rygel-${LIBV}/plugins/.debug"
> -
> -PACKAGES += "${PN}-meta"
> -ALLOW_EMPTY_${PN}-meta = "1"
> -
> -PACKAGES_DYNAMIC = "${PN}-plugin-*"
> -
> -python populate_packages_prepend () {
> - rygel_libdir = d.expand('${libdir}/rygel-${LIBV}')
> - postinst = d.getVar('plugin_postinst', True)
> - pkgs = []
> -
> - pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), 'librygel-(.*)\.so$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> - pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), '(.*)\.plugin$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> -
> - metapkg = d.getVar('PN', True) + '-meta'
> - d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
> -}
> diff --git a/meta-multimedia/recipes-connectivity/rygel/rygel_0.28.2.bb b/meta-multimedia/recipes-connectivity/rygel/rygel_0.28.2.bb
> new file mode 100644
> index 0000000..f1c47a0
> --- /dev/null
> +++ b/meta-multimedia/recipes-connectivity/rygel/rygel_0.28.2.bb
> @@ -0,0 +1,59 @@
> +SUMMARY = "A UPnP AV media server and renderer"
> +DESCRIPTION = "Rygel is a home media solution (UPnP AV MediaServer) that \
> +allow you to easily share audio, video and pictures to other devices. \
> +Additionally, media player software may use Rygel to become a MediaRenderer \
> +that may be controlled remotely by a UPnP or DLNA Controller."
> +HOMEPAGE = "http://live.gnome.org/Rygel"
> +
> +LICENSE = "LGPLv2+"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
> + file://src/rygel/rygel-main.vala;endline=27;md5=99324118da4c012d25edae2f779ae9b3"
> +
> +DEPENDS = "libxml2 glib-2.0 gssdp gupnp gupnp-av gupnp-dlna gstreamer1.0 gstreamer1.0-plugins-base ossp-uuid libgee libsoup-2.4 libmediaart-2.0"
> +RDEPENDS_${PN} = "gstreamer1.0-plugins-base-playback shared-mime-info"
> +RRECOMMENDS_${PN} = "rygel-plugin-media-export"
> +
> +GNOME_COMPRESS_TYPE = "xz"
> +SRC_URI[archive.md5sum] = "9fbe4fb53b6cfa2f3f3723b7649a2215"
> +SRC_URI[archive.sha256sum] = "9ea23df7186caac5f1aad3137edf6d507d339b9a469fc3133df4043fa66b61f5"
> +
> +inherit gnomebase vala
> +
> +EXTRA_OECONF = "--disable-introspection --disable-tracker-plugin --with-media-engine=gstreamer"
> +
> +PACKAGECONFIG ?= "external mpris mediathek ruih media-export gst-launch gtk+3"
> +PACKAGECONFIG[external] = "--enable-external-plugin,--disable-external-plugin"
> +PACKAGECONFIG[mpris] = "--enable-mpris-plugin,--disable-mpris-plugin"
> +PACKAGECONFIG[mediathek] = "--enable-mediathek-plugin,--disable-mediathek-plugin"
> +PACKAGECONFIG[ruih] = "--enable-ruih-plugin,--disable-ruih-plugin"
> +PACKAGECONFIG[media-export] = "--enable-media-export-plugin,--disable-media-export-plugin,sqlite3"
> +PACKAGECONFIG[gst-launch] = "--enable-gst-launch-plugin,--disable-gst-launch-plugin"
> +PACKAGECONFIG[gtk+3] = ",--without-ui,gtk+3"
> +
> +LIBV = "2.6"
> +
> +do_install_append() {
> + # Remove .la files for loadable modules
> + rm -f ${D}/${libdir}/rygel-${LIBV}/engines/*.la
> + rm -f ${D}/${libdir}/rygel-${LIBV}/plugins/*.la
> +}
> +
> +FILES_${PN} += "${libdir}/rygel-${LIBV}/engines ${datadir}/dbus-1 ${datadir}/icons"
> +FILES_${PN}-dbg += "${libdir}/rygel-${LIBV}/engines/.debug ${libdir}/rygel-${LIBV}/plugins/.debug"
> +
> +PACKAGES += "${PN}-meta"
> +ALLOW_EMPTY_${PN}-meta = "1"
> +
> +PACKAGES_DYNAMIC = "${PN}-plugin-*"
> +
> +python populate_packages_prepend () {
> + rygel_libdir = d.expand('${libdir}/rygel-${LIBV}')
> + postinst = d.getVar('plugin_postinst', True)
> + pkgs = []
> +
> + pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), 'librygel-(.*)\.so$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> + pkgs += do_split_packages(d, oe.path.join(rygel_libdir, "plugins"), '(.*)\.plugin$', d.expand('${PN}-plugin-%s'), 'Rygel plugin for %s', postinst=postinst, extra_depends=d.expand('${PN}'))
> +
> + metapkg = d.getVar('PN', True) + '-meta'
> + d.setVar('RDEPENDS_' + metapkg, ' '.join(pkgs))
> +}
> --
> 1.7.10.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
--
Martin 'JaMa' Jansa jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20160127/146db56c/attachment-0002.sig>
More information about the Openembedded-devel
mailing list