[oe] [meta-oe][PATCH] ttf-pt-sans: add recipe

[Martin Jansa]

On Fri, Mar 18, 2016 at 02:59:04PM +0200, Ioan-Adrian Ratiu wrote:
> PT Sans is an open source licensed font released in 2010 by ParaType.
> The ParaTypeFFL-1.3 license file has been submitted to OE-core.
> 
> Signed-off-by: Ioan-Adrian Ratiu <adrian.ratiu at ni.com>
> ---
>  .../recipes-graphics/ttf-fonts/ttf-pt-sans_1.1.bb  | 44 ++++++++++++++++++++++
>  1 file changed, 44 insertions(+)
>  create mode 100644 meta-oe/recipes-graphics/ttf-fonts/ttf-pt-sans_1.1.bb
> 
> diff --git a/meta-oe/recipes-graphics/ttf-fonts/ttf-pt-sans_1.1.bb b/meta-oe/recipes-graphics/ttf-fonts/ttf-pt-sans_1.1.bb
> new file mode 100644
> index 0000000..b7f4548
> --- /dev/null
> +++ b/meta-oe/recipes-graphics/ttf-fonts/ttf-pt-sans_1.1.bb
> @@ -0,0 +1,44 @@
> +SUMMARY = "PT Sans Fonts"
> +DESCRIPTION = "The PT Sans TTF font set"
> +HOMEPAGE = "http://www.paratype.com/public/"
> +
> +SECTION = "x11/fonts"
> +
> +LICENSE = "ParaTypeFFL-1.3"
> +LIC_FILES_CHKSUM = "file://../PT%20Free%20Font%20License_eng.txt;md5=d720f3a281ed81c3f4cfc465e11b1d0d"
> +
> +inherit allarch fontcache

This cannot be allarch when it depends on TUNE_PKGARCH fontconfig, see
layer.conf and send v2.

> +RDEPENDS_${PN} = "fontconfig-utils"

This is already added by fontcache.bbclass.

> +
> +FONT_PACKAGES = "${PN}"

This is the default, why do you assign it here?

> +
> +# Downloading from fedora because upstream doesn't version its zip file
> +# and causes hash build failures
> +SRC_URI = "http://pkgs.fedoraproject.org/repo/pkgs/paratype-pt-sans-fonts/PTSans.zip/c3f5a0e20a75cf628387510a720924a7/PTSans.zip"
> +
> +SRC_URI[md5sum] = "c3f5a0e20a75cf628387510a720924a7"
> +SRC_URI[sha256sum] = "0164f824e03c32c99e8a225853ec168893a04a09ade132e93a674e85ae033b2e"
> +
> +do_install () {
> +	install -d ${D}${datadir}/fonts/X11/TTF/
> +	cd ..
> +	for i in *.ttf; do
> +		install -m 0644 $i ${D}${prefix}/share/fonts/X11/TTF/${i}
> +	done
> +}
> +
> +FILES_${PN} += "${datadir}"
> +
> +pkg_postinst_${PN} () {
> +        set -x
> +        for fontdir in `find $D/usr/lib/X11/fonts -type d`; do
> +                mkfontdir $fontdir
> +                mkfontscale $fontdir
> +        done
> +        for fontdir in `find $D/usr/share/fonts/X11 -type d`; do
> +                mkfontdir $fontdir
> +                mkfontscale $fontdir
> +        done
> +}
> +
> -- 
> 2.7.3
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20160318/a655baeb/attachment-0002.sig>