[oe] [meta-networking][PATCH V3 3/4] dante: Add recipe for 1.4.1

[Martin Jansa]

On Fri, Nov 25, 2016 at 10:24:34PM -0800, Khem Raj wrote:
> * Add packageconfig for krb5
> * Require pam in distro
> 
> Signed-off-by: Khem Raj <raj.khem at gmail.com>
> ---
>  .../recipes-protocols/dante/dante_1.4.1.bb         | 49 ++++++++++++++++++++++
>  1 file changed, 49 insertions(+)
>  create mode 100644 meta-networking/recipes-protocols/dante/dante_1.4.1.bb
> 
> diff --git a/meta-networking/recipes-protocols/dante/dante_1.4.1.bb b/meta-networking/recipes-protocols/dante/dante_1.4.1.bb
> new file mode 100644
> index 0000000..0fb0f67
> --- /dev/null
> +++ b/meta-networking/recipes-protocols/dante/dante_1.4.1.bb
> @@ -0,0 +1,49 @@
> +SECTION = "console/utils"
> +SUMMARY = "A free SOCKS server"
> +DESCRIPTION = "Dante consists of a SOCKS server and a SOCKS client,\
> +implementing RFC 1928 and related standards. It is a flexible product\
> +that can be used to provide convenient and secure network\
> +connectivity. Once installed, Dante can in most cases be made\
> +transparent to clients, providing functionality somewhat similar to\
> +what could be described as a non-transparent Layer 4 router."
> +HOMEPAGE = "http://www.inet.no/dante/"
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=221118dda731fe93a85d0ed973467249"
> +
> +SRC_URI = "https://www.inet.no/dante/files/dante-${PV}.tar.gz \
> +          "
> +SRC_URI[md5sum] = "68c2ce12119e12cea11a90c7a80efa8f"
> +SRC_URI[sha256sum] = "b6d232bd6fefc87d14bf97e447e4fcdeef4b28b16b048d804b50b48f261c4f53"
> +
> +# without --without-gssapi, config.log will contain reference to /usr/lib
> +# as a consequence of GSSAPI path being set to /usr by default.
> +# --with-gssapi-path=PATH specify gssapi path
> +# --without-gssapi        disable gssapi support
> +# --enable-release        build prerelease as full release
> +EXTRA_OECONF += "--without-gssapi --sbindir=${bindir}"
> +
> +DEPENDS += "flex-native bison-native libpam"
> +
> +inherit autotools-brokensep
> +
> +REQUIRED_DISTRO_FEATURES = "pam"

Did you forget to add distro_features_check to inherit?

I've added this when cherry-picking to master-next, but not sure if Joe
will pick it from there.

> +
> +EXTRA_AUTORECONF = "-I ${S}"
> +
> +PACKAGECONFIG[libwrap] = ",--disable-libwrap,tcp-wrappers,libwrap"
> +PACKAGECONFIG[krb5] = ",--disable-krb5,krb5"
> +
> +PACKAGECONFIG ??= ""
> +
> +do_install_append() {
> +    install -d ${D}${sysconfdir}
> +    cp ${S}/example/sock[sd].conf ${D}${sysconfdir}
> +}
> +
> +PACKAGES =+ "${PN}-sockd ${PN}-libdsocks "
> +
> +FILES_${PN}-libdsocks = "${libdir}/libdsocks.so"
> +FILES_${PN}-sockd = "${bindir}/sockd ${sysconfdir}/sockd.conf"
> +
> +INSANE_SKIP_${PN}-libdsocks = "dev-elf"
> -- 
> 2.10.2
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 195 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20161129/72ea9e71/attachment-0002.sig>