[oe] [meta-networking] [PATCH] libreswan: this patch adds libreswan to meta-networking

[Khem Raj]

On Wed, Apr 5, 2017 at 6:41 AM, Oliver Graute <oliver.graute at gmail.com> wrote:
> Libreswan is an IPsec implementation for Linux
>
> Signed-off-by: Oliver Graute <oliver.graute at neuhaus.de>
> ---
>  .../recipes-support/libreswan/libreswan_3.20.bb    | 48 ++++++++++++++++++++++
>  1 file changed, 48 insertions(+)
>  create mode 100644 meta-networking/recipes-support/libreswan/libreswan_3.20.bb
>
> diff --git a/meta-networking/recipes-support/libreswan/libreswan_3.20.bb b/meta-networking/recipes-support/libreswan/libreswan_3.20.bb
> new file mode 100644
> index 0000000..e291211
> --- /dev/null
> +++ b/meta-networking/recipes-support/libreswan/libreswan_3.20.bb
> @@ -0,0 +1,48 @@
> +SUMMERY = "Libreswan is an IPsec implementation for Linux."
> +DESCRIPTION = "IPsec implementation with IKEv1 and IKEv2 keying protocols"
> +HOMEPAGE = "http://www.libreswan.org"
> +SECTION = "net"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
> +DEPENDS = "gmp nss libcap-ng libevent iproute2 iptables unbound flex-native"
> +RRECOMMENDS_${PN} = "kernel-module-ipsec"
> +RDEPENDS_${PN} = "python curl libpam"
> +RDEPENDS_${PN}_nylon = "perl"

call it ${PN}-nylon for naming consistency

> +PR = "r0"

Drop this, its default

> +
> +SRC_URI = "http://download.libreswan.org/libreswan-${PV}.tar.gz"
> +SRC_URI[md5sum] = "72aecdf8314c0c47546d5ae2cf918191"
> +SRC_URI[sha256sum] = "2f0931c11ea0b9303ce1e4ee76ffe9db6f3bd70ceead51fe4ec11e2f40a9ae2e"
> +
> +S = "${WORKDIR}/libreswan-${PV}"
> +
> +EXTRA_OEMAKE = "DESTDIR=${D} \
> +                FINALCONFDIR=${sysconfdir}/ipsec \
> +                INC_RCDEFAULT=${sysconfdir}/init.d \
> +                INC_USRLOCAL=${prefix} \
> +                INC_MANDIR=/share/man \
> +                FINALSBINDIR=${bindir} \
> +                FINALLIBEXECDIR=${libexecdir}/ipsec \
> +                USE_XAUTH=true \
> +                USE_LIBCAP_NG=true \
> +                USE_LEAK_DETECTIVE=false \
> +                WERROR='' \
> +                "
> +
> +do_compile () {
> +    export ARCH=${TARGET_ARCH}
> +    ${S}/CROSSCOMPILE.sh
> +    make \

can we call oe_runmake here

> +    #programs
> +    oe_runmake programs
> +}
> +
> +do_install () {
> +        oe_runmake install
> +        install -d ${D}${datadir}/doc
> +}
> +
> +FILES_${PN} = "${sysconfdir} ${libdir}/ipsec/* ${sbindir}/* ${bindir}/* ${localstatedir}/* ${libexecdir}/ipsec/* /run"

/run is a generated file. You should not package it instead just
delete it if empty. If not empty find a way to generate the files in
/run at runtime.

> +FILES_${PN}-dbg += "${libdir}/ipsec/.debug ${libexecdir}/ipsec/.debug"
> +FILES_${PN}-doc += "${datadir}/libreswan/* ${mandir}/*"
> +CONFFILES_${PN} = "${sysconfdir}/ipsec/ipsec.conf"
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel