[oe] [meta-networking][PATCH] tinyproxy: Add recipe

[Martin Jansa]

On Wed, Apr 05, 2017 at 02:53:26PM +0200, Benjamin Gaignard wrote:
> Signed-off-by: Benjamin Gaignard <benjamin.gaignard at linaro.org>
> ---
>  .../tinyproxy/tinyproxy/tinyproxy.service          | 14 ++++++++++
>  .../recipes-support/tinyproxy/tinyproxy_1.8.4.bb   | 32 ++++++++++++++++++++++
>  2 files changed, 46 insertions(+)
>  create mode 100644 meta-networking/recipes-support/tinyproxy/tinyproxy/tinyproxy.service
>  create mode 100644 meta-networking/recipes-support/tinyproxy/tinyproxy_1.8.4.bb
> 
> diff --git a/meta-networking/recipes-support/tinyproxy/tinyproxy/tinyproxy.service b/meta-networking/recipes-support/tinyproxy/tinyproxy/tinyproxy.service
> new file mode 100644
> index 0000000..800d2ad
> --- /dev/null
> +++ b/meta-networking/recipes-support/tinyproxy/tinyproxy/tinyproxy.service
> @@ -0,0 +1,14 @@
> +[Unit]
> +Description=Tinyproxy, Lightweight http(s) proxy daemon
> +RequiresMountsFor=/var
> +
> +[Service]
> +User=root
> +ExecStartPre=/bin/mkdir -p /var/log/tinyproxy
> +ExecStartPre=/bin/chown -R nobody.adm /var/log/tinyproxy
> +ExecStartPre=/bin/mkdir -p /var/run/tinyproxy
> +ExecStartPre=/bin/chown -R nobody.adm /var/run/tinyproxy
> +ExecStart=/usr/sbin/tinyproxy -d
> +
> +[Install]
> +WantedBy=multi-user.target
> diff --git a/meta-networking/recipes-support/tinyproxy/tinyproxy_1.8.4.bb b/meta-networking/recipes-support/tinyproxy/tinyproxy_1.8.4.bb
> new file mode 100644
> index 0000000..76cec63
> --- /dev/null
> +++ b/meta-networking/recipes-support/tinyproxy/tinyproxy_1.8.4.bb
> @@ -0,0 +1,32 @@
> +SUMMARY = "Lightweight http(s) proxy daemon"
> +HOMEPAGE = "https://tinyproxy.github.io/"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
> +
> +SRC_URI = "https://github.com/tinyproxy/tinyproxy/releases/download/1.8.4/tinyproxy-${PV}.tar.gz"

Use ${PV} for 2nd 1.8.4 as well.

You can also replace "tinyproxy-${PV}" with just "${BP}" and tinyproxy
with ${BPN}"

> +SRC_URI += "file://tinyproxy.service"
> +
> +SRC_URI[md5sum] = "3b60f7d08e0821ed1a3e2cf1e5778cac"
> +SRC_URI[sha256sum] = "8234c879a129feee61efa98bac14a1a3e46e5cf08f01696a216940872aa70faf"
> +
> +EXTRA_OECONF += " \
> +	--enable-filter \
> +	--enable-transparent \
> +	--disable-regexcheck \
> +	--enable-reverse \
> +	--enable-upstream \
> +	--enable-xtinyproxy \
> +	"
> +
> +inherit autotools systemd
> +
> +SYSTEMD_PACKAGES += "${PN}"
> +SYSTEMD_SERVICE_${PN} = "tinyproxy.service"
> +SYSTEMD_AUTO_ENABLE_${PN} = "enable"
> +
> +do_install_append() {
> +	install -d ${D}${systemd_system_unitdir}
> +	install -m 0644 ${WORKDIR}/tinyproxy.service ${D}${systemd_system_unitdir}

IIRC this should respect systemd in DISTRO_FEATURES.

> +}
> +
> +FILES_${PN} =+ "${systemd_system_unitdir}/tinyproxy.service"
> -- 
> 1.9.1
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 195 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20170405/a08e142c/attachment-0002.sig>