[oe] [meta-oe][PATCH 2/2] debsums: New recipe

[Khem Raj]

On Sun, Jun 11, 2017 at 8:06 AM, Tom Rini <trini at konsulko.com> wrote:
> A tool for verification of installed package files against MD5 checksums
> debsums can verify the integrity of installed package files against MD5
> checksums installed by the package, or generated from a .deb archive.
>

order of directives seems a bit displaced, may be running
meta-openembedded/contrib/oe-stylize.py
will be good.

> Signed-off-by: Tom Rini <trini at konsulko.com>
> ---
>  meta-oe/recipes-support/debsums/debsums_2.2.2.bb | 53 ++++++++++++++++++++++++
>  1 file changed, 53 insertions(+)
>  create mode 100644 meta-oe/recipes-support/debsums/debsums_2.2.2.bb
>
> diff --git a/meta-oe/recipes-support/debsums/debsums_2.2.2.bb b/meta-oe/recipes-support/debsums/debsums_2.2.2.bb
> new file mode 100644
> index 000000000000..9713ae22784e
> --- /dev/null
> +++ b/meta-oe/recipes-support/debsums/debsums_2.2.2.bb
> @@ -0,0 +1,53 @@
> +SUMMARY = "Miscellaneous utilities specific to Debian"
> +DESCRIPTION = "A tool for verification of installed package files against \
> +MD5 checksums debsums can verify the integrity of installed package files \
> +against MD5 checksums installed by the package, or generated from a .deb \
> +archive."
> +
> +SECTION = "base"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://debian/copyright;md5=770d751553e6559e9eaefd2e11ccf7e9"
> +
> +SUMMARY_${PN}-cron = "Cron scripts to control automatic prelinking"
> +DESCRIPTION_${PN}-cron = "Cron scripts to control automatic checking."
> +FILES_${PN}-cron = "${sysconfdir}/cron.*"
> +
> +PACKAGES =+ "${PN}-cron"
> +
> +SRC_URI = "http://snapshot.debian.org/archive/debian/20170530T212108Z/pool/main/d/debsums/debsums_2.2.2.tar.xz"
> +# the package is taken from snapshots.debian.org; that source is static and goes stale
> +# so we check the latest upstream from a directory that does get updated
> +UPSTREAM_CHECK_URI = "${DEBIAN_MIRROR}/main/d/${BPN}/"
> +
> +SRC_URI[md5sum] = "82b0710855a7e5212d4358163a269e79"
> +SRC_URI[sha256sum] = "aa61896f93a6bbfe0161c21dcd67529ae8e1ec8c3ccf244523c52c4ad8253d97"
> +
> +RDEPENDS_${PN} = "dpkg dpkg-perl libfile-fnmatch-perl perl \
> +                  perl-module-constant perl-module-digest-md5 \
> +                  perl-module-errno perl-module-fcntl \
> +                  perl-module-file-basename perl-module-file-copy \
> +                  perl-module-file-find perl-module-file-glob \
> +                  perl-module-file-path perl-module-file-spec \
> +                  perl-module-file-temp perl-module-getopt-long \
> +                  perl-module-posix"
> +
> +do_install() {
> +       install -d ${D}/${sysconfdir}/cron.daily ${D}/${sysconfdir}/cron.weekly
> +       install -d ${D}/${sysconfdir}/cron.monthly ${D}${sbindir} ${D}${bindir}
> +       install -d ${D}${mandir}/man1 ${D}${mandir}/man8
> +       install -m 0755 debsums ${D}${bindir}/
> +       install -m 0755 rdebsums ${D}${bindir}/
> +       install -m 0755 debsums_init ${D}${sbindir}
> +       install -m 0644 man/debsums.1 ${D}${mandir}/man1/
> +       install -m 0644 man/rdebsums.1 ${D}${mandir}/man1/
> +       install -m 0644 man/debsums_init.8 ${D}${mandir}/man8/
> +       install -m 0644 debian/cron.daily \
> +               ${D}/${sysconfdir}/cron.daily/debsums
> +       install -m 0644 debian/cron.weekly \
> +               ${D}/${sysconfdir}/cron.weekly/debsums
> +       install -m 0644 debian/cron.monthly \
> +               ${D}/${sysconfdir}/cron.monthly/debsums
> +
> +       # Must exist, defaults to empty.
> +       touch ${D}/${sysconfdir}/debsums-ignore
> +}
> --
> 1.9.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel