[oe] [meta-filesystems][PATCH 1/2] xfsdump: 3.1.4 -> 3.1.6

[Chen Qi]

From: Robert Yang <liezhi.yang at windriver.com>

The 3.1.4 doesn't work with xfsprogs 4.7:
| inv_files.o: In function `inv_dirpath':
|xfsdump-3.1.4/invutil/inv_files.c:53: undefined reference to `ASSERT'
| inv_files.o: In function `inv_fstab':
|xfsdump-3.1.4/invutil/inv_files.c:60: undefined reference to `ASSERT'
| inv_files.o: In function `inv_lockfile':
|xfsdump-3.1.4/invutil/inv_files.c:67: undefined reference to `ASSERT'
| inv_files.o: In function `inv_basepath':
|xfsdump-3.1.4/invutil/inv_files.c:74: undefined reference to `ASSERT'
| collect2: error: ld returned 1 exit status
| make[2]: *** [../include/buildrules:33: xfsinvutil] Error 1

Signed-off-by: Robert Yang <liezhi.yang at windriver.com>
---
 .../recipes-utils/xfsdump/xfsdump_3.1.6.bb         | 38 ++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 meta-filesystems/recipes-utils/xfsdump/xfsdump_3.1.6.bb

diff --git a/meta-filesystems/recipes-utils/xfsdump/xfsdump_3.1.6.bb b/meta-filesystems/recipes-utils/xfsdump/xfsdump_3.1.6.bb
new file mode 100644
index 000000000..8f942ba7c
--- /dev/null
+++ b/meta-filesystems/recipes-utils/xfsdump/xfsdump_3.1.6.bb
@@ -0,0 +1,38 @@
+SUMMARY = "XFS Filesystem Dump Utility"
+DESCRIPTION = "The xfsdump package contains xfsdump, xfsrestore and a \
+               number of other utilities for administering XFS filesystems.\
+               xfsdump examines files in a filesystem, determines which \
+               need to be backed up, and copies those files to a \
+               specified disk, tape or other storage medium."
+HOMEPAGE = "http://oss.sgi.com/projects/xfs"
+SECTION = "base"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://doc/COPYING;md5=15c832894d10ddd00dfcf57bee490ecc"
+DEPENDS = "xfsprogs attr"
+
+SRC_URI = "ftp://oss.sgi.com/projects/xfs/cmd_tars/${BPN}-${PV}.tar.gz \
+    file://remove-install-as-user.patch \
+"
+SRC_URI[md5sum] = "50353cd4f4b435685955363e6044f4d1"
+SRC_URI[sha256sum] = "7f78c11ca527477d90e5e62b0778f3ad96f2b71c19173044e9aca9515fff42d0"
+
+inherit autotools-brokensep
+
+PARALLEL_MAKE = ""
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[gettext] = "--enable-gettext=yes,--enable-gettext=no,gettext"
+
+EXTRA_OEMAKE += "'LIBTOOL=${HOST_SYS}-libtool' V=1"
+
+do_configure () {
+    export DEBUG="-DNDEBUG"
+    oe_runconf
+}
+
+do_install () {
+    export DIST_ROOT=${D}
+    oe_runmake install
+    oe_runmake install-dev
+}
+
+PNBLACKLIST[xfsdump] ?= "Depends on broken xfsprogs - the recipe will be removed on 2017-09-01 unless the issue is fixed"
-- 
2.11.0