[oe] [meta-oe][PATCH] openocd: Add recipe for openocd
Moritz Fischer
moritz.fischer at ettus.com
Thu May 4 22:50:37 UTC 2017
Adds a recipe for openocd. Based on recipe found in meta-zephyr.
Signed-off-by: Moritz Fischer <moritz.fischer at ettus.com>
---
meta-oe/recipes-devtools/openocd/openocd_git.bb | 44 +++++++++++++++++++++++++
1 file changed, 44 insertions(+)
create mode 100644 meta-oe/recipes-devtools/openocd/openocd_git.bb
diff --git a/meta-oe/recipes-devtools/openocd/openocd_git.bb b/meta-oe/recipes-devtools/openocd/openocd_git.bb
new file mode 100644
index 0000000..783a6c7
--- /dev/null
+++ b/meta-oe/recipes-devtools/openocd/openocd_git.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Free and Open On-Chip Debugging, In-System Programming and Boundary-Scan Testing"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+DEPENDS = "libusb-compat libftdi"
+RDEPENDS_${PN} = "libusb1"
+
+SRC_URI = "git://repo.or.cz/openocd.git \
+ "
+SRCREV = "cb317eabf2d162365467aeb89b564828e5e6d6f3"
+
+PV = "0.10+gitr${SRCPV}"
+S = "${WORKDIR}/git"
+
+inherit pkgconfig autotools-brokensep gettext
+
+BBCLASSEXTEND += "nativesdk"
+
+EXTRA_OECONF = "--enable-ftdi --disable-doxygen-html "
+
+do_configure() {
+ ./bootstrap
+ oe_runconf ${EXTRA_OECONF}
+}
+
+do_install() {
+ oe_runmake DESTDIR=${D} install
+ if [ -e "${D}${infodir}" ]; then
+ rm -Rf ${D}${infodir}
+ fi
+ if [ -e "${D}${mandir}" ]; then
+ rm -Rf ${D}${mandir}
+ fi
+ if [ -e "${D}${bindir}/.debug" ]; then
+ rm -Rf ${D}${bindir}/.debug
+ fi
+}
+
+FILES_${PN} = " \
+ ${datadir}/openocd/* \
+ ${bindir}/openocd \
+ "
+
+PACKAGECONFIG[sysfsgpio] = "--enable-sysfsgpio,--disable-sysfsgpio"
+PACKAGECONFIG ??= "sysfsgpio"
--
2.7.4
More information about the Openembedded-devel
mailing list