[oe] [meta-oe][PATCH] rocksdb: add version 5.8

[Khem Raj]

On Fri, Oct 6, 2017 at 4:31 AM, Pascal Bach <pascal.bach at siemens.com> wrote:
> Version 5.8 does no longer includes the facebook patent grant and is
> licensed under the Apache-2.0 license.
>

I see leveldb as well as GPL-2.0 licence file in repo. Are they not used

> Signed-off-by: Pascal Bach <pascal.bach at siemens.com>
> ---
>  meta-oe/recipes-extended/rocksdb/rocksdb_git.bb | 26 +++++++++++++++++++++++++
>  1 file changed, 26 insertions(+)
>  create mode 100644 meta-oe/recipes-extended/rocksdb/rocksdb_git.bb
>
> diff --git a/meta-oe/recipes-extended/rocksdb/rocksdb_git.bb b/meta-oe/recipes-extended/rocksdb/rocksdb_git.bb
> new file mode 100644
> index 0000000..a4fbf34
> --- /dev/null
> +++ b/meta-oe/recipes-extended/rocksdb/rocksdb_git.bb
> @@ -0,0 +1,26 @@
> +SUMMARY = "RocksDB an embeddable, persistent key-value store"
> +DESCRIPTION = "RocksDB is library that provides an embeddable, persistent key-value store for fast storage."
> +HOMEPAGE = "http://rocksdb.org/"
> +LICENSE = "Apache-2.0"
> +LIC_FILES_CHKSUM = "file://LICENSE.Apache;md5=3b83ef96387f14655fc854ddc3c6bd57"
> +
> +SRCREV = "266ac245affd69555643b735d19d3715c4eff91a"
> +PV = "5.8+git${SRCPV}"
> +
> +SRC_URI = "git://github.com/facebook/${BPN}.git"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit cmake
> +
> +PACKAGECONFIG ??= "bzip2 zlib lz4"
> +PACKAGECONFIG[bzip2] = "-DWITH_BZ2=ON,-DWITH_BZ2=OFF,bzip2"
> +PACKAGECONFIG[lz4] = "-DWITH_LZ4=ON,-DWITH_LZ4=OFF,lz4"
> +PACKAGECONFIG[zlib] = "-DWITH_ZLIB=ON,-DWITH_ZLIB=OFF,zlib"
> +PACKAGECONFIG[lite] = "-DROCKSDB_LITE=ON,-DROCKSDB_LITE=OFF"
> +
> +EXTRA_OECMAKE = "\
> +    -DPORTABLE=ON \
> +"
> +
> +FILES_${PN}-dev += "${libdir}/cmake"
> --
> 2.1.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel