[oe] [meta-multimedia][PATCH] gerbera: Add recipe

[Khem Raj]

On Fri, Sep 8, 2017 at 6:34 AM, Fabien Lahoudere
<fabien.lahoudere at collabora.co.uk> wrote:
> Gerbera is a UPnP media server which allows you to stream your digital media
> through your home network and consume it on a variety of UPnP compatible devices.
>
> Gerbera is based on MediaTomb 12.1 which is dead upstream, so this is an attempt
> to kick it back into life.
>
> Signed-off-by: Fabien Lahoudere <fabien.lahoudere at collabora.co.uk>
> ---
>  .../gerbera/files/gerbera.service                  | 13 +++++++++
>  .../recipes-multimedia/gerbera/gerbera_git.bb      | 34 ++++++++++++++++++++++
>  2 files changed, 47 insertions(+)
>  create mode 100644 meta-multimedia/recipes-multimedia/gerbera/files/gerbera.service
>  create mode 100644 meta-multimedia/recipes-multimedia/gerbera/gerbera_git.bb
>
> diff --git a/meta-multimedia/recipes-multimedia/gerbera/files/gerbera.service b/meta-multimedia/recipes-multimedia/gerbera/files/gerbera.service
> new file mode 100644
> index 000000000..1b5a3ad3e
> --- /dev/null
> +++ b/meta-multimedia/recipes-multimedia/gerbera/files/gerbera.service
> @@ -0,0 +1,13 @@
> +[Unit]
> +Description=Start Gerbera, an UPnP media server
> +After=multi-user.target network-online.target
> +Wants=network-online.target
> +
> +[Service]
> +ExecStart=/usr/bin/gerbera
> +Environment='HOME=/root'
> +Type=simple
> +RemainAfterExit=yes
> +
> +[Install]
> +WantedBy=multi-user.target
> \ No newline at end of file
> diff --git a/meta-multimedia/recipes-multimedia/gerbera/gerbera_git.bb b/meta-multimedia/recipes-multimedia/gerbera/gerbera_git.bb
> new file mode 100644
> index 000000000..2bbedc0d1
> --- /dev/null
> +++ b/meta-multimedia/recipes-multimedia/gerbera/gerbera_git.bb
> @@ -0,0 +1,34 @@
> +Description = "Gerbera - An UPnP media server"
> +
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://LICENSE.md;md5=25cdec9afe3f1f26212ead6bd2f7fac8"
> +
> +SRC_URI = "git://github.com/v00d00/gerbera.git;protocol=https \
> +          file://gerbera.service "
> +
> +
> +# Modify these as desired
> +PV = "1.0+git${SRCPV}"
> +SRCREV = "4435b165d121195aefd67d0287f7f9349e181d45"
> +
> +S = "${WORKDIR}/git"
> +
> +DEPENDS = "expat zlib curl libupnp e2fsprogs sqlite3 taglib "
> +RDEPENDS_${PN} = "expat zlib curl libupnp e2fsprogs taglib "

we we need all of these explicitly specified for rdeps ?

> +
> +SYSTEMD_SERVICE_${PN} = "gerbera.service"
> +SYSTEMD_AUTO_ENABLE = "enable"
> +

this is default you can delete it.

> +inherit cmake systemd
> +
> +EXTRA_OECMAKE = "-DWITH_JS=FALSE -DWITH_TAGLIB=FALSE -DWITH_MAGIC=FALSE -DWITH_EXIF=FALSE -DLIBUUID_INCLUDE_DIRS=${WORKDIR}/recipe-sysroot/usr/include -DLIBUUID_LIBRARIES=-luuid"

Here taglib is  disabled but its added in DEPENDS, it would be better
to create packageconfig for this
use -DLIBUUID_INCLUDE_DIRS=${STAGING_INCDIR}
> +
> +do_install_append() {
> +       install -d ${D}/root/.config/

this assumes the rootfs is rw, I think it will cause issues with ro images.

> +       install -d ${D}${systemd_system_unitdir}
> +        install -m 0644 ${WORKDIR}/gerbera.service ${D}${systemd_system_unitdir}/
> +}
> +
> +FILES_${PN} += " /root/.config/ \
> +                ${systemd_system_unitdir}/* \
> +"
> \ No newline at end of file
> --
> 2.11.0
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel