[oe] [meta-networking][rocko][PATCH] civetweb: Add new recipe for v1.10 version

[Khem Raj]

On 4/17/18 5:15 AM, Krzysztof Kozlowski wrote:
> Add recipe for CivetWeb: easy to use, powerful, C/C++ embeddable web
> server with optional CGI, SSL and Lua support, under MIT license.
> 
> CivetWeb provides C and C++ libraries and a standalone server binary.
> 
> Signed-off-by: Krzysztof Kozlowski <krzk at kernel.org>
> ---
>   .../recipes-connectivity/civetweb/civetweb_1.10.bb | 34 ++++++++++++++++++++++
>   1 file changed, 34 insertions(+)
>   create mode 100644 meta-networking/recipes-connectivity/civetweb/civetweb_1.10.bb
> 
> diff --git a/meta-networking/recipes-connectivity/civetweb/civetweb_1.10.bb b/meta-networking/recipes-connectivity/civetweb/civetweb_1.10.bb
> new file mode 100644
> index 000000000000..35af45680818
> --- /dev/null
> +++ b/meta-networking/recipes-connectivity/civetweb/civetweb_1.10.bb
> @@ -0,0 +1,34 @@
> +SUMMARY = "Civetweb embedded web server"
> +HOMEPAGE = "https://github.com/civetweb/civetweb"
> +
> +LICENSE = "MIT"
> +LIC_FILES_CHKSUM = "file://LICENSE.md;md5=da079d81be91ff1d1ca56dcd751f897f"
> +
> +SRC_URI = " \
> +    git://github.com/civetweb/civetweb.git;tag=v${PV} \

its better to use SHA version corresponding to this tag, tags result in 
fetcher n/w access and builds might fail when n/w access is disabled, 
secondly tags are floating types and can be moved.

> +"
> +S = "${WORKDIR}/git"
> +
> +# civetweb supports building with make or cmake (although cmake lacks few features)
> +inherit cmake
> +
> +# Disable Lua and Duktape because they do not compile from CMake (as of v1.8, v1.9 and v1.10)
> +EXTRA_OECMAKE = " \
> +    -DBUILD_SHARED_LIBS=ON \
> +    -DCIVETWEB_ENABLE_DUKTAPE=OFF \
> +    -DCIVETWEB_ENABLE_LUA=OFF \
> +"
> +
> +PACKAGECONFIG ??= "asan caching cgi cpp debug ipv6 server websockets"
> +PACKAGECONFIG[asan] = "-DCIVETWEB_ENABLE_ASAN=ON,-DCIVETWEB_ENABLE_ASAN=OFF,gcc-sanitizers"
> +PACKAGECONFIG[caching] = "-DCIVETWEB_DISABLE_CACHING=OFF,-DCIVETWEB_DISABLE_CACHING=ON,"
> +PACKAGECONFIG[cgi] = "-DCIVETWEB_DISABLE_CGI=OFF,-DCIVETWEB_DISABLE_CGI=ON,"
> +PACKAGECONFIG[cpp] = "-DCIVETWEB_ENABLE_CXX=ON,-DCIVETWEB_ENABLE_CXX=OFF,"
> +PACKAGECONFIG[debug] = "-DCIVETWEB_ENABLE_MEMORY_DEBUGGING=ON,-DCIVETWEB_ENABLE_MEMORY_DEBUGGING=OFF,"
> +PACKAGECONFIG[ipv6] = "-DCIVETWEB_ENABLE_IPV6=ON,-DCIVETWEB_ENABLE_IPV6=OFF,"
> +PACKAGECONFIG[server] = "-DCIVETWEB_INSTALL_EXECUTABLE=ON,-DCIVETWEB_INSTALL_EXECUTABLE=OFF,"
> +# As of v1.10, SSL does not work. Bring it back with v1.11:
> +# PACKAGECONFIG[ssl] = "-DCIVETWEB_ENABLE_SSL=ON -DCIVETWEB_SSL_OPENSSL_API_1_1=ON -DCIVETWEB_ENABLE_SSL_DYNAMIC_LOADING=OFF,-DCIVETWEB_ENABLE_SSL=OFF,openssl"
> +PACKAGECONFIG[websockets] = "-DCIVETWEB_ENABLE_WEBSOCKETS=ON,-DCIVETWEB_ENABLE_WEBSOCKETS=OFF,"
> +
> +BBCLASSEXTEND = "native nativesdk"
>