[oe] [meta-networking][PATCH v2] bird: initial import

[Joe MacDonald]

[Re: [oe] [meta-networking][PATCH v2] bird: initial import] On 18.08.16 (Thu 17:02) Khem Raj wrote:

> 
> 
> On 8/16/18 8:29 AM, Joe MacDonald wrote:
> > Initial integration of the two stable BIRD releases, 1.6.4 and 2.0.2.
> > 
> > Signed-off-by: Joe MacDonald <joe_macdonald at mentor.com>
> > ---
> > 
> > v2:
> >    - adding upstream-status and link to upstream commit accomplishing the same
> >      goal.
> > 
> >  .../recipes-protocols/bird/bird.inc           |   32 +
> >  .../recipes-protocols/bird/bird_1.6.4.bb      |    9 +
> >  .../recipes-protocols/bird/bird_2.0.2.bb      |    9 +
> >  ...-extend-config.sub-to-recognize-musl.patch | 4430 +++++++++++++++++
> >  .../recipes-protocols/bird/files/bird.init    |    2 +
> >  5 files changed, 4482 insertions(+)
> >  create mode 100644 meta-networking/recipes-protocols/bird/bird.inc
> >  create mode 100644 meta-networking/recipes-protocols/bird/bird_1.6.4.bb
> >  create mode 100644 meta-networking/recipes-protocols/bird/bird_2.0.2.bb
> >  create mode 100644 meta-networking/recipes-protocols/bird/files/0001-musl-extend-config.sub-to-recognize-musl.patch
> >  create mode 100755 meta-networking/recipes-protocols/bird/files/bird.init
> > 
> > diff --git a/meta-networking/recipes-protocols/bird/bird.inc b/meta-networking/recipes-protocols/bird/bird.inc
> > new file mode 100644
> > index 000000000..33d17dcb7
> > --- /dev/null
> > +++ b/meta-networking/recipes-protocols/bird/bird.inc
> > @@ -0,0 +1,32 @@
> > +SUMMARY = "BIRD Internet Routing Daemon"
> > +DESCRIPTION = "\
> > +BIRD is dynamic routing daemon supporting IPv4 and IPv6 versions of routing \
> > +protocols BGP, RIP and OSPF."
> > +HOMEPAGE = "http://bird.network.cz"
> > +SECTION = "console/network"
> > +LICENSE = "GPLv2"
> > +LIC_FILES_CHKSUM = "file://README;beginline=87;endline=103;md5=0efecc23f039022580d0bac9a52f6117"
> > +DEPENDS = "flex bison ncurses readline"
> > +
> 
> does it need flex and bison on target ? or just native versions

Confirmed in my rework tree now that we only need the native versions.

> > +inherit autotools
> > +
> > +EXTRA_OECONF  += "\
> > +--enable-pthreads \
> > +"
> > +
> > +do_configure() {
> > +    oe_runconf ${EXTRA_OECONF}
> > +}
> > +
> > +do_install_append() {
> > +    install -m 0755 -d ${D}${sysconfdir}/init.d
> > +    install -m 0755 ${WORKDIR}/bird.init ${D}${sysconfdir}/init.d/bird
> 
> may be use a single line
> 
> install -D -m 0755 ${WORKDIR}/bird.init ${D}${sysconfdir}/init.d/bird

I actually prefer this split over two steps since it makes things
cleaner when we inevitably need to change what gets included in our
do_install*().  In my reworked version I've removed the mode set on the
first line, though, to better align with the other examples elsewhere in
the meta-openembedded tree.

> > +    rm -rf ${D}/run ${D}/var/run 
> > +}
> > +
> > +PACKAGES += " bird-client"
> > +
> > +FILES_${PN} += "/run /var/run"
> 
> I think we don't need this

Yeah, we don't need this.

> > +FILES_${PN}-client = "/usr/sbin/birdc*"
> > +
> 
> may be use ${sbindir} here

I've fixed this too.

> > +RUNIT_SERVICES = "bird"
> > diff --git a/meta-networking/recipes-protocols/bird/bird_1.6.4.bb b/meta-networking/recipes-protocols/bird/bird_1.6.4.bb
> > new file mode 100644
> > index 000000000..27c62aeee
> > --- /dev/null
> > +++ b/meta-networking/recipes-protocols/bird/bird_1.6.4.bb
> > @@ -0,0 +1,9 @@
> > +require bird.inc
> > +
> > +SRC_URI = "\
> > +    ftp://bird.network.cz/pub/${PN}/${PN}-${PV}.tar.gz \
> > +    file://bird.init \
> > +    file://0001-musl-extend-config.sub-to-recognize-musl.patch \
> > +    "
> > +SRC_URI[md5sum] = "d62ec2547338e8d3dfb934b4c7b2faa4"
> > +SRC_URI[sha256sum] = "c26b8caae988dba81a9dbbee93502463d4326d1b749d728d62aa5529c605afc0"
> > diff --git a/meta-networking/recipes-protocols/bird/bird_2.0.2.bb b/meta-networking/recipes-protocols/bird/bird_2.0.2.bb
> > new file mode 100644
> > index 000000000..92d858869
> > --- /dev/null
> > +++ b/meta-networking/recipes-protocols/bird/bird_2.0.2.bb
> > @@ -0,0 +1,9 @@
> > +require bird.inc
> > +
> > +SRC_URI = "\
> > +    ftp://bird.network.cz/pub/${PN}/${PN}-${PV}.tar.gz \
> > +    file://bird.init \
> > +    file://0001-musl-extend-config.sub-to-recognize-musl.patch \
> > +    "
> > +SRC_URI[md5sum] = "de17645b045fa13912409aea59420132"
> > +SRC_URI[sha256sum] = "035f91d6f568f8ed438a0814235ac4c5c79147cd2acf201322c307732883480f"
> 
> do we need to maintain both 1.6 and 2.x versions ?
> I guess they must be incompatible with each other and 1.6 still
> deployed. but I would prefer to just maintain latest version

That's a much bigger question, ongoing in the v1 thread.

-J.

-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 488 bytes
Desc: not available
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20180817/55687d37/attachment-0002.sig>