[oe] [meta-openembedded][PATCH] mksh: add version 56

[Andrea Adami]

I had not yet time to review and test-build the recipe but I pointed
it to the author, tg, the fellow helping with klibc.
Here his observations:

<ant_home> LICENSE = "MirOS & ISC"
<mira> ISC only if your libc doesn't have strlcpy
<mira> all but glibc have it
<mira> +    chmod +x ${S}/Build.sh
<mira> why?
<mira> just run sh ${S}/Build.sh instead
<mira> oh and add -r
<mira> saves time (-r disables automatic compilation of the manpage to
a catmanpage, BSD style)
<mira> inherit autotools   ← I doubt that ;)
<mira> you’ll also want to install an /etc/skel/.mkshrc or similar; in
FreeWRT, OpenWrt and OpenADK where root is the only user we install it
as /root/.mkshrc

Cheers
Andrea
On Wed, Dec 5, 2018 at 12:00 AM Khem Raj <raj.khem at gmail.com> wrote:
>
> Fails to build with musl - http://errors.yoctoproject.org/Errors/Details/203419/
> On Tue, Dec 4, 2018 at 6:16 AM Eduardas Meile <eduardas.m at fods.com> wrote:
> >
> > The MirBSD Korn Shell is a permissively licensed shell currently used
> > by Android.
> >
> > Signed-off-by: Eduardas Meile <eduardas.m at fods.com>
> > ---
> >  meta-oe/recipes-shells/mksh/mksh_56.bb | 34 ++++++++++++++++++++++++++
> >  1 file changed, 34 insertions(+)
> >  create mode 100644 meta-oe/recipes-shells/mksh/mksh_56.bb
> >
> > diff --git a/meta-oe/recipes-shells/mksh/mksh_56.bb b/meta-oe/recipes-shells/mksh/mksh_56.bb
> > new file mode 100644
> > index 000000000..2ddcc6607
> > --- /dev/null
> > +++ b/meta-oe/recipes-shells/mksh/mksh_56.bb
> > @@ -0,0 +1,34 @@
> > +DESCRIPTION = "The MirBSD Korn Shell - an enhanced version of the public domain ksh"
> > +HOMEPAGE = "http://www.mirbsd.org/mksh.htm"
> > +SECTION = "base/shell"
> > +
> > +LICENSE = "MirOS & ISC"
> > +LIC_FILES_CHKSUM = "file://main.c;beginline=6;endline=25;md5=7204fec4d12912f2a13fe8745bc356f9 \
> > +                    file://strlcpy.c;beginline=1;endline=17;md5=d953f28f0c43ee29e238ec9bc15df2a0 \
> > +                   "
> > +
> > +SRC_URI = "http://www.mirbsd.org/MirOS/dist/mir/mksh/mksh-R56c.tgz"
> > +
> > +SRC_URI[md5sum] = "4799a9ac6d55871d79ba66713d928663"
> > +SRC_URI[sha256sum] = "dd86ebc421215a7b44095dc13b056921ba81e61b9f6f4cdab08ca135d02afb77"
> > +
> > +inherit autotools update-alternatives
> > +
> > +S = "${WORKDIR}/${PN}"
> > +
> > +ALTERNATIVE_${PN} = "sh"
> > +ALTERNATIVE_LINK_NAME[sh] = "${base_bindir}/sh"
> > +ALTERNATIVE_TARGET[sh] = "${base_bindir}/${BPN}"
> > +ALTERNATIVE_PRIORITY = "100"
> > +
> > +do_compile() {
> > +    chmod +x ${S}/Build.sh
> > +    ${S}/Build.sh
> > +}
> > +
> > +do_install() {
> > +    install -d ${D}${base_bindir}
> > +    install -m 0755 ${S}/mksh ${D}${base_bindir}/mksh
> > +}
> > +
> > +RPROVIDES_${PN} += "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '/bin/sh', '', d)}"
> > --
> > 2.17.1
> >
> > --
> > _______________________________________________
> > Openembedded-devel mailing list
> > Openembedded-devel at lists.openembedded.org
> > http://lists.openembedded.org/mailman/listinfo/openembedded-devel
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel