[oe] [PATCH] vim: update to 8.1.0155
Khem Raj
raj.khem at gmail.com
Fri Jul 6 21:21:53 UTC 2018
On Fri, Jul 6, 2018 at 2:14 AM Leon Anavi <leon.anavi at konsulko.com> wrote:
>
> Update vim to the latest version 8.1.0155.
>
> Signed-off-by: Leon Anavi <leon.anavi at konsulko.com>
> ---
> meta-oe/recipes-support/vim/vim-tiny_8.1.0.116.bb | 13 ---
> meta-oe/recipes-support/vim/vim-tiny_8.1.0155.bb | 13 +++
> meta-oe/recipes-support/vim/vim_8.1.0.116.bb | 113 ----------------------
> meta-oe/recipes-support/vim/vim_8.1.0155.bb | 113 ++++++++++++++++++++++
> 4 files changed, 126 insertions(+), 126 deletions(-)
> delete mode 100644 meta-oe/recipes-support/vim/vim-tiny_8.1.0.116.bb
> create mode 100644 meta-oe/recipes-support/vim/vim-tiny_8.1.0155.bb
> delete mode 100644 meta-oe/recipes-support/vim/vim_8.1.0.116.bb
> create mode 100644 meta-oe/recipes-support/vim/vim_8.1.0155.bb
>
this patch is ok however I would suggest that you add
[diff]
renames = copies
to your ~/.gitconfig this will help git detect renames and make
patches easier to review.
> diff --git a/meta-oe/recipes-support/vim/vim-tiny_8.1.0.116.bb b/meta-oe/recipes-support/vim/vim-tiny_8.1.0.116.bb
> deleted file mode 100644
> index bb8f2b7..0000000
> --- a/meta-oe/recipes-support/vim/vim-tiny_8.1.0.116.bb
> +++ /dev/null
> @@ -1,13 +0,0 @@
> -require vim_${PV}.bb
> -
> -SUMMARY += " (with tiny features)"
> -
> -PACKAGECONFIG += "tiny"
> -
> -do_install() {
> - install -d ${D}/${bindir}
> - install -m 0755 ${S}/vim ${D}/${bindir}/vim.tiny
> -}
> -
> -ALTERNATIVE_PRIORITY = "90"
> -ALTERNATIVE_TARGET = "${bindir}/vim.tiny"
> diff --git a/meta-oe/recipes-support/vim/vim-tiny_8.1.0155.bb b/meta-oe/recipes-support/vim/vim-tiny_8.1.0155.bb
> new file mode 100644
> index 0000000..bb8f2b7
> --- /dev/null
> +++ b/meta-oe/recipes-support/vim/vim-tiny_8.1.0155.bb
> @@ -0,0 +1,13 @@
> +require vim_${PV}.bb
> +
> +SUMMARY += " (with tiny features)"
> +
> +PACKAGECONFIG += "tiny"
> +
> +do_install() {
> + install -d ${D}/${bindir}
> + install -m 0755 ${S}/vim ${D}/${bindir}/vim.tiny
> +}
This could just be made a single liner with
install -D -m 0755 ${S}/vim ${D}/${bindir}/vim.tiny
> +
> +ALTERNATIVE_PRIORITY = "90"
> +ALTERNATIVE_TARGET = "${bindir}/vim.tiny"
> diff --git a/meta-oe/recipes-support/vim/vim_8.1.0.116.bb b/meta-oe/recipes-support/vim/vim_8.1.0.116.bb
> deleted file mode 100644
> index f669dfe..0000000
> --- a/meta-oe/recipes-support/vim/vim_8.1.0.116.bb
> +++ /dev/null
> @@ -1,113 +0,0 @@
> -SUMMARY = "Vi IMproved - enhanced vi editor"
> -SECTION = "console/utils"
> -DEPENDS = "ncurses gettext-native"
> -# vimdiff doesn't like busybox diff
> -RSUGGESTS_${PN} = "diffutils"
> -LICENSE = "vim"
> -LIC_FILES_CHKSUM = "file://../runtime/doc/uganda.txt;md5=b6eb9d541de3933cc8f48125ae0335fe"
> -
> -SRC_URI = "git://github.com/vim/vim.git \
> - file://disable_acl_header_check.patch;patchdir=.. \
> - file://vim-add-knob-whether-elf.h-are-checked.patch;patchdir=.. \
> -"
> -SRCREV = "a87b72cc316e065d66dcbcf7ec1cde330adef3a3"
> -
> -S = "${WORKDIR}/git/src"
> -
> -VIMDIR = "vim${@d.getVar('PV').split('.')[0]}${@d.getVar('PV').split('.')[1]}"
> -
> -inherit autotools-brokensep update-alternatives
> -
> -CLEANBROKEN = "1"
> -
> -# vim configure.in contains functions which got 'dropped' by autotools.bbclass
> -do_configure () {
> - rm -f auto/*
> - touch auto/config.mk
> - aclocal
> - autoconf
> - oe_runconf
> - touch auto/configure
> - touch auto/config.mk auto/config.h
> -}
> -
> -#Available PACKAGECONFIG options are gtkgui, acl, x11, tiny
> -PACKAGECONFIG ??= ""
> -PACKAGECONFIG += "${@bb.utils.filter('DISTRO_FEATURES', 'acl selinux', d)}"
> -
> -PACKAGECONFIG[gtkgui] = "--enable-gtk2-test --enable-gui=gtk2,--enable-gui=no,gtk+,"
> -PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
> -PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
> -PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
> -PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
> -PACKAGECONFIG[elfutils] = "--enable-elf-check,,elfutils,"
> -
> -EXTRA_OECONF = " \
> - --disable-gpm \
> - --disable-gtktest \
> - --disable-xim \
> - --disable-netbeans \
> - --with-tlib=ncurses \
> - ac_cv_small_wchar_t=no \
> - vim_cv_getcwd_broken=no \
> - vim_cv_memmove_handles_overlap=yes \
> - vim_cv_stat_ignores_slash=no \
> - vim_cv_terminfo=yes \
> - vim_cv_tgetent=non-zero \
> - vim_cv_toupper_broken=no \
> - vim_cv_tty_group=world \
> - STRIP=/bin/true \
> -"
> -
> -do_install() {
> - autotools_do_install
> -
> - # Work around file-rdeps picking up csh, awk, perl or python as a dep
> - chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/vim132
> - chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/mve.awk
> - chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.pl
> - chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.py
> -
> - # Install example vimrc from runtime files
> - install -m 0644 ../runtime/vimrc_example.vim ${D}/${datadir}/${BPN}/vimrc
> -
> - # we use --with-features=big as default
> - mv ${D}${bindir}/${BPN} ${D}${bindir}/${BPN}.${BPN}
> -}
> -
> -PARALLEL_MAKEINST = ""
> -
> -PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-tools"
> -FILES_${PN}-syntax = "${datadir}/${BPN}/${VIMDIR}/syntax"
> -FILES_${PN}-help = "${datadir}/${BPN}/${VIMDIR}/doc"
> -FILES_${PN}-tutor = "${datadir}/${BPN}/${VIMDIR}/tutor ${bindir}/${BPN}tutor"
> -FILES_${PN}-vimrc = "${datadir}/${BPN}/vimrc"
> -FILES_${PN}-data = "${datadir}/${BPN}"
> -FILES_${PN}-tools = "${datadir}/${BPN}/${VIMDIR}/tools"
> -FILES_${PN}-common = " \
> - ${datadir}/${BPN}/${VIMDIR}/*.vim \
> - ${datadir}/${BPN}/${VIMDIR}/autoload \
> - ${datadir}/${BPN}/${VIMDIR}/colors \
> - ${datadir}/${BPN}/${VIMDIR}/compiler \
> - ${datadir}/${BPN}/${VIMDIR}/ftplugin \
> - ${datadir}/${BPN}/${VIMDIR}/indent \
> - ${datadir}/${BPN}/${VIMDIR}/keymap \
> - ${datadir}/${BPN}/${VIMDIR}/lang \
> - ${datadir}/${BPN}/${VIMDIR}/macros \
> - ${datadir}/${BPN}/${VIMDIR}/plugin \
> - ${datadir}/${BPN}/${VIMDIR}/print \
> - ${datadir}/${BPN}/${VIMDIR}/spell \
> - ${datadir}/icons \
> -"
> -
> -RDEPENDS_${BPN} = "ncurses-terminfo-base"
> -# Recommend that runtime data is installed along with vim
> -RRECOMMENDS_${BPN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-common"
> -
> -ALTERNATIVE_${PN} = "vi vim"
> -ALTERNATIVE_TARGET = "${bindir}/${BPN}.${BPN}"
> -ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
> -ALTERNATIVE_LINK_NAME[vim] = "${bindir}/vim"
> -ALTERNATIVE_PRIORITY = "100"
> -
> -BBCLASSEXTEND = "native"
> diff --git a/meta-oe/recipes-support/vim/vim_8.1.0155.bb b/meta-oe/recipes-support/vim/vim_8.1.0155.bb
> new file mode 100644
> index 0000000..532b50c
> --- /dev/null
> +++ b/meta-oe/recipes-support/vim/vim_8.1.0155.bb
> @@ -0,0 +1,113 @@
> +SUMMARY = "Vi IMproved - enhanced vi editor"
> +SECTION = "console/utils"
> +DEPENDS = "ncurses gettext-native"
> +# vimdiff doesn't like busybox diff
> +RSUGGESTS_${PN} = "diffutils"
> +LICENSE = "vim"
> +LIC_FILES_CHKSUM = "file://../runtime/doc/uganda.txt;md5=b6eb9d541de3933cc8f48125ae0335fe"
> +
> +SRC_URI = "git://github.com/vim/vim.git \
> + file://disable_acl_header_check.patch;patchdir=.. \
> + file://vim-add-knob-whether-elf.h-are-checked.patch;patchdir=.. \
> +"
> +SRCREV = "ae728edc93fe5a2f8c39fa75b1ae9ed71526858c"
> +
> +S = "${WORKDIR}/git/src"
> +
> +VIMDIR = "vim${@d.getVar('PV').split('.')[0]}${@d.getVar('PV').split('.')[1]}"
> +
> +inherit autotools-brokensep update-alternatives
> +
> +CLEANBROKEN = "1"
> +
> +# vim configure.in contains functions which got 'dropped' by autotools.bbclass
> +do_configure () {
> + rm -f auto/*
> + touch auto/config.mk
> + aclocal
> + autoconf
> + oe_runconf
> + touch auto/configure
> + touch auto/config.mk auto/config.h
> +}
> +
> +#Available PACKAGECONFIG options are gtkgui, acl, x11, tiny
> +PACKAGECONFIG ??= ""
> +PACKAGECONFIG += "${@bb.utils.filter('DISTRO_FEATURES', 'acl selinux', d)}"
> +
> +PACKAGECONFIG[gtkgui] = "--enable-gtk2-test --enable-gui=gtk2,--enable-gui=no,gtk+,"
> +PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
> +PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
> +PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
> +PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
> +PACKAGECONFIG[elfutils] = "--enable-elf-check,,elfutils,"
> +
> +EXTRA_OECONF = " \
> + --disable-gpm \
> + --disable-gtktest \
> + --disable-xim \
> + --disable-netbeans \
> + --with-tlib=ncurses \
> + ac_cv_small_wchar_t=no \
> + vim_cv_getcwd_broken=no \
> + vim_cv_memmove_handles_overlap=yes \
> + vim_cv_stat_ignores_slash=no \
> + vim_cv_terminfo=yes \
> + vim_cv_tgetent=non-zero \
> + vim_cv_toupper_broken=no \
> + vim_cv_tty_group=world \
> + STRIP=/bin/true \
> +"
> +
> +do_install() {
> + autotools_do_install
> +
> + # Work around file-rdeps picking up csh, awk, perl or python as a dep
> + chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/vim132
> + chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/mve.awk
> + chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.pl
> + chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.py
> +
> + # Install example vimrc from runtime files
> + install -m 0644 ../runtime/vimrc_example.vim ${D}/${datadir}/${BPN}/vimrc
> +
> + # we use --with-features=big as default
> + mv ${D}${bindir}/${BPN} ${D}${bindir}/${BPN}.${BPN}
> +}
> +
> +PARALLEL_MAKEINST = ""
> +
> +PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-tools"
> +FILES_${PN}-syntax = "${datadir}/${BPN}/${VIMDIR}/syntax"
> +FILES_${PN}-help = "${datadir}/${BPN}/${VIMDIR}/doc"
> +FILES_${PN}-tutor = "${datadir}/${BPN}/${VIMDIR}/tutor ${bindir}/${BPN}tutor"
> +FILES_${PN}-vimrc = "${datadir}/${BPN}/vimrc"
> +FILES_${PN}-data = "${datadir}/${BPN}"
> +FILES_${PN}-tools = "${datadir}/${BPN}/${VIMDIR}/tools"
> +FILES_${PN}-common = " \
> + ${datadir}/${BPN}/${VIMDIR}/*.vim \
> + ${datadir}/${BPN}/${VIMDIR}/autoload \
> + ${datadir}/${BPN}/${VIMDIR}/colors \
> + ${datadir}/${BPN}/${VIMDIR}/compiler \
> + ${datadir}/${BPN}/${VIMDIR}/ftplugin \
> + ${datadir}/${BPN}/${VIMDIR}/indent \
> + ${datadir}/${BPN}/${VIMDIR}/keymap \
> + ${datadir}/${BPN}/${VIMDIR}/lang \
> + ${datadir}/${BPN}/${VIMDIR}/macros \
> + ${datadir}/${BPN}/${VIMDIR}/plugin \
> + ${datadir}/${BPN}/${VIMDIR}/print \
> + ${datadir}/${BPN}/${VIMDIR}/spell \
> + ${datadir}/icons \
> +"
> +
> +RDEPENDS_${BPN} = "ncurses-terminfo-base"
> +# Recommend that runtime data is installed along with vim
> +RRECOMMENDS_${BPN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-common"
> +
> +ALTERNATIVE_${PN} = "vi vim"
> +ALTERNATIVE_TARGET = "${bindir}/${BPN}.${BPN}"
> +ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
> +ALTERNATIVE_LINK_NAME[vim] = "${bindir}/vim"
> +ALTERNATIVE_PRIORITY = "100"
> +
> +BBCLASSEXTEND = "native"
> --
> 2.7.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel
More information about the Openembedded-devel
mailing list