[oe] [PATCH] bpftool: add new recipe

[Khem Raj]

On Tue, Jun 26, 2018 at 8:09 PM Daniel Díaz <daniel.diaz at linaro.org> wrote:
>
> The bpftool allows for inspection and simple manipulation of
> eBPF programs and maps, so common in the kernel selftests.
>
> Signed-off-by: Daniel Díaz <daniel.diaz at linaro.org>
> ---
>  meta-oe/recipes-kernel/bpftool/bpftool.bb | 32 +++++++++++++++++++++++++++++++
>  1 file changed, 32 insertions(+)
>  create mode 100644 meta-oe/recipes-kernel/bpftool/bpftool.bb
>
> diff --git a/meta-oe/recipes-kernel/bpftool/bpftool.bb b/meta-oe/recipes-kernel/bpftool/bpftool.bb
> new file mode 100644
> index 0000000..887f079
> --- /dev/null
> +++ b/meta-oe/recipes-kernel/bpftool/bpftool.bb
> @@ -0,0 +1,32 @@
> +SUMMARY = "Inspect and manipulate eBPF programs and maps"
> +DESCRIPTION = "bpftool is a kernel tool for inspection and simple manipulation \
> +of eBPF programs and maps."
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
> +DEPENDS = "binutils elfutils"
> +PROVIDES = "virtual/bpftool"
> +
> +inherit bash-completion kernelsrc kernel-arch
> +
> +do_populate_lic[depends] += "virtual/kernel:do_patch"
> +
> +EXTRA_OEMAKE = "-C ${S}/tools/bpf/bpftool O=${B} CROSS=${TARGET_PREFIX} CC="${CC}" LD="${LD}" AR=${AR} ARCH=${ARCH}"
> +
> +do_configure[depends] += "virtual/kernel:do_shared_workdir"
> +
> +do_compile() {
> +    oe_runmake
> +}
> +
> +do_install() {
> +    oe_runmake DESTDIR=${D} install
> +    chown -R root:root ${D}

this chown does not seem right

> +}
> +
> +PACKAGE_ARCH = "${MACHINE_ARCH}"
> +
> +python do_package_prepend() {
> +    d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
> +}
> +
> +B = "${WORKDIR}/${BPN}-${PV}"
> --
> 2.7.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel