[oe] [meta-multimedia][PATCH] Add a working tvheadend recipe

[Peter Bašista]

The original one was previously removed
by commit ec9e5ed06256ad92c818474cdb490dc0d3a0d0a3
as part of a clean-up of blacklisted recipes.

Signed-off-by: Peter Bašista <pbasista at gmail.com>
---
 .../recipes-dvb/tvheadend/tvheadend_git.bb    | 37 +++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 meta-multimedia/recipes-dvb/tvheadend/tvheadend_git.bb

diff --git a/meta-multimedia/recipes-dvb/tvheadend/tvheadend_git.bb b/meta-multimedia/recipes-dvb/tvheadend/tvheadend_git.bb
new file mode 100644
index 000000000..2a76d5d34
--- /dev/null
+++ b/meta-multimedia/recipes-dvb/tvheadend/tvheadend_git.bb
@@ -0,0 +1,37 @@
+SUMMARY = "Tvheadend: TV streaming server and recorder"
+HOMEPAGE = "https://tvheadend.org/"
+
+DEPENDS = "avahi cmake-native gettext-native libpcre2 libdvbcsa openssl zlib python-native"
+
+LICENSE = "GPLv3+"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=9cae5acac2e9ee2fc3aec01ac88ce5db"
+
+SRC_URI = "git://github.com/tvheadend/tvheadend.git"
+
+inherit gitpkgv
+SRCREV = "${AUTOREV}"
+PV = "4.3+git${SRCPV}"
+PKGV = "4.3+git${GITPKGV}"
+
+S = "${WORKDIR}/git"
+
+PACKAGECONFIG ?= ""
+PACKAGECONFIG[uriparser] = "--enable-uriparser,--disable-uriparser,uriparser"
+
+do_configure() {
+    ./configure ${PACKAGECONFIG_CONFARGS} \
+                --prefix=${prefix} \
+                --libdir=${libdir} \
+                --bindir=${bindir} \
+                --datadir=${datadir} \
+                --arch=${TARGET_ARCH} \
+                --disable-libav \
+                --disable-ffmpeg_static \
+                --disable-hdhomerun_static
+}
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}
+
+FILES_${PN} += "${datadir}/${BPN}"
-- 
2.19.1