[oe] [meta-networking][PATCH] networkd-dispatcher: new package

[Khem Raj]

On Thu, Sep 6, 2018 at 5:38 AM Bartosz Golaszewski <brgl at bgdev.pl> wrote:
>
> From: Bartosz Golaszewski <bgolaszewski at baylibre.com>
>
> This adds a recipe for networkd-dispatcher.
>
> It's a simple package containing a python script that needs to be
> installed together with a systemd service and an example config
> file. There's nothing to build.
>
> Signed-off-by: Bartosz Golaszewski <bgolaszewski at baylibre.com>
> ---
>  .../networkd-dispatcher_1.7.bb                | 30 +++++++++++++++++++
>  1 file changed, 30 insertions(+)
>  create mode 100644 meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher_1.7.bb
>
> diff --git a/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher_1.7.bb b/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher_1.7.bb
> new file mode 100644
> index 000000000..1887c4c7a
> --- /dev/null
> +++ b/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher_1.7.bb
> @@ -0,0 +1,30 @@
> +SUMMARY = "Dispatcher service for systemd-networkd connection status changes"
> +DESCRIPTION = "This daemon is similar to NetworkManager-dispatcher, but is much \
> +more limited in the types of events it supports due to the limited nature of \
> +systemd-networkd(8)."
> +AUTHOR = "Clayton Craft and others"
> +
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=84dcc94da3adb52b53ae4fa38fe49e5d"
> +
> +RDEPENDS_${PN} = "systemd python3 python3-pygobject python3-dbus"
> +
> +SRC_URI = "git://gitlab.com/craftyguy/networkd-dispatcher.git;protocol=https"
> +SRCREV = "c7e25623a161b64618ea778541c064d2a1df086b"

perhaps define PV in terms of SRCPV

> +
> +S = "${WORKDIR}/git"
> +
> +# Nothing to build, just a python script to install.
> +do_compile() {
> +}

use deltask

> +
> +do_install() {
> +    mkdir -p ${D}/${sbindir}
> +    install -m 0755 ${S}/networkd-dispatcher ${D}${sbindir}/networkd-dispatcher

condense both into install -D -m 0755 ....

> +    mkdir -p ${D}/${systemd_unitdir}/system
> +    install -m 0644 ${S}/networkd-dispatcher.service ${D}/${systemd_unitdir}/system/networkd-dispatcher.service
> +    mkdir -p ${D}/${sysconfdir}/conf.d
> +    install -m 0644 ${S}/networkd-dispatcher.conf ${D}/${sysconfdir}/conf.d/networkd-dispatcher.conf

this whole section should check for systemd being in DISTRO_FEATURES

> +}
> +
> +FILES_${PN} += "${systemd_unitdir}/system/networkd-dispatcher.service"

use systemd_system_unitdir

> --
> 2.18.0
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel