[oe] [meta-networking][PATCH v2] networkd-dispatcher: new package

[Khem Raj]

http://errors.yoctoproject.org/Errors/Details/192034/
On Fri, Sep 7, 2018 at 3:55 AM Bartosz Golaszewski <brgl at bgdev.pl> wrote:
>
> From: Bartosz Golaszewski <bgolaszewski at baylibre.com>
>
> This adds a recipe for networkd-dispatcher.
>
> It's a simple package containing a python script that needs to be
> installed together with a systemd service and an example config
> file. There's nothing to build.
>
> Signed-off-by: Bartosz Golaszewski <bgolaszewski at baylibre.com>
> ---
> NOTE: resending with a proper tag
>
> v1 -> v2:
> - skip the package if systemd is not in DISTRO_FEATURES
> - use -D in install for new directories
> - use deltask instead of an empty do_compile() function
> - define PV in the recipe as <version>+git${SRCPV}
>
>  .../networkd-dispatcher.bb                    | 33 +++++++++++++++++++
>  1 file changed, 33 insertions(+)
>  create mode 100644 meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher.bb
>
> diff --git a/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher.bb b/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher.bb
> new file mode 100644
> index 000000000..7bb2347a8
> --- /dev/null
> +++ b/meta-networking/recipes-daemons/networkd-dispatcher/networkd-dispatcher.bb
> @@ -0,0 +1,33 @@
> +python __anonymous() {
> +    features = d.getVar('DISTRO_FEATURES')
> +    if not features or 'systemd' not in features:
> +        raise bb.parse.SkipPackage('networkd-dispatcher needs systemd in DISTRO_FEATURES')
> +}
> +
> +SUMMARY = "Dispatcher service for systemd-networkd connection status changes"
> +DESCRIPTION = "This daemon is similar to NetworkManager-dispatcher, but is much \
> +more limited in the types of events it supports due to the limited nature of \
> +systemd-networkd(8)."
> +AUTHOR = "Clayton Craft and others"
> +
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=84dcc94da3adb52b53ae4fa38fe49e5d"
> +
> +RDEPENDS_${PN} = "systemd python3 python3-pygobject python3-dbus"
> +
> +SRC_URI = "git://gitlab.com/craftyguy/networkd-dispatcher.git;protocol=https"
> +SRCREV = "c7e25623a161b64618ea778541c064d2a1df086b"
> +PV = "1.7+git${SRCPV}"
> +
> +S = "${WORKDIR}/git"
> +
> +# Nothing to build, just a python script to install
> +deltask do_compile
> +
> +do_install() {
> +    install -D -m 0755 ${S}/networkd-dispatcher ${D}${sbindir}/networkd-dispatcher
> +    install -D -m 0644 ${S}/networkd-dispatcher.service ${D}/${systemd_system_unitdir}/networkd-dispatcher.service
> +    install -D -m 0644 ${S}/networkd-dispatcher.conf ${D}/${sysconfdir}/conf.d/networkd-dispatcher.conf
> +}
> +
> +FILES_${PN} += "${systemd_system_unitdir}/networkd-dispatcher.service"
> --
> 2.18.0
>