[oe] [meta-networking][PATCH] unbound: create recipe for version 1.9.1

[Beniamin Sandu]

Signed-off-by: Beniamin Sandu <beniamin.sandu at gmail.com>
---
 .../recipes-support/unbound/unbound_1.9.1.bb  | 36 +++++++++++++++++++
 1 file changed, 36 insertions(+)
 create mode 100644 meta-networking/recipes-support/unbound/unbound_1.9.1.bb

diff --git a/meta-networking/recipes-support/unbound/unbound_1.9.1.bb b/meta-networking/recipes-support/unbound/unbound_1.9.1.bb
new file mode 100644
index 000000000..84bbe6581
--- /dev/null
+++ b/meta-networking/recipes-support/unbound/unbound_1.9.1.bb
@@ -0,0 +1,36 @@
+SUMMARY = "Unbound is a validating, recursive, and caching DNS resolver"
+DESCRIPTION = "Unbound's design is a set of modular components which incorporate \
+	features including enhanced security (DNSSEC) validation, Internet Protocol \
+	Version 6 (IPv6), and a client resolver library API as an integral part of the \
+	architecture"
+
+HOMEPAGE = "https://www.unbound.net/"
+SECTION = "net"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5308494bc0590c0cb036afd781d78f06"
+
+SRC_URI = "git://github.com/NLnetLabs/unbound.git;protocol=http;branch=master"
+SRCREV="16cc196bf28aec604ed2dae2b5af2ed82c8a58d6"
+
+inherit autotools pkgconfig systemd
+
+DEPENDS = "openssl libevent libtool-native bison-native expat"
+RDEPENDS_${PN} = "bash openssl-bin"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OECONF = "libtool=${TARGET_PREFIX}libtool \
+		--with-ssl=${STAGING_EXECPREFIXDIR}"
+
+PACKAGECONFIG = "${@bb.utils.contains('DISTRO_FEATURES','systemd','systemd','',d)}"
+PACKAGECONFIG[systemd] = "--enable-systemd,,systemd"
+
+do_install_append() {
+	# systemd support
+	if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+		install -d ${D}${systemd_unitdir}/system/
+		install -m 0644 ${B}/contrib/${BPN}.service ${D}${systemd_unitdir}/system/${BPN}.service
+	fi
+}
+
+SYSTEMD_SERVICE_${PN} = "${BPN}.service"
-- 
2.17.1