[oe] [meta-oe][patch v5] dnf-plugin-tui: new recipe

[Khem Raj]

Thanks for resending. I have some comments below.

On 8/8/19 4:24 AM, Zheng Ruoqin wrote:
> This dnf plugin aims to supply a tui interface for user to manage
> packages. It has features as following:
>   1. Add new command dnf tui --init to make dnf work on host.
>   2. Text-based user interface for dnf.
>   3. Manage SPDX files.
>   4. Manage SRPM files.
>   5. Add installation samples for dnf.
> 
> More details please refer to https://github.com/ubinux/dnf-plugin-tui.
> 
> Signed-off-by: Zheng Ruoqin <zhengrq.fnst at cn.fujitsu.com>
> ---
>  .../dnf-plugin-tui/dnf-plugin-tui_git.bb      | 38 +++++++++++++++++++
>  .../files/oe-remote.repo.sample               |  5 +++
>  2 files changed, 43 insertions(+)
>  create mode 100644 meta-oe/recipes-devtools/dnf-plugin-tui/dnf-plugin-tui_git.bb
>  create mode 100644 meta-oe/recipes-devtools/dnf-plugin-tui/files/oe-remote.repo.sample
> 
> diff --git a/meta-oe/recipes-devtools/dnf-plugin-tui/dnf-plugin-tui_git.bb b/meta-oe/recipes-devtools/dnf-plugin-tui/dnf-plugin-tui_git.bb
> new file mode 100644
> index 000000000..e891868cd
> --- /dev/null
> +++ b/meta-oe/recipes-devtools/dnf-plugin-tui/dnf-plugin-tui_git.bb
> @@ -0,0 +1,38 @@
> +SUMMARY = "A text-based user interface plugin of dnf for user to manage packages. "
> +LICENSE = "GPLv2"
> +
> +LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
> +
> +SRC_URI = "git://github.com/ubinux/dnf-plugin-tui.git;branch=master "

master is default so lets drop setting branch here

> +SRCREV = "31d6866d5eda02be9a6bfb1fca9e9095b12eecd1"
> +PV = "1.0"

Drop PV

> +
> +SRC_URI_append_class-target = "file://oe-remote.repo.sample"
                                  ^^
missing space

> +
> +inherit distutils3-base
> +
> +S = "${WORKDIR}/git"
> +
> +do_install_append() {
> +        install -d ${D}${datadir}/dnf
> +        install -m 0755 ${S}/samples/* ${D}${datadir}/dnf
> +        install -d ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
> +        install -m 0755 ${S}/dnf-plugins/mkimg/* ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
> +        for file in $(ls ${S}/dnf-plugins/ | grep -v mkimg); do
> +            install -m 0755 ${S}/dnf-plugins/$file ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins
> +        done
> +}
> +
> +do_install_append_class-target() {
> +        install -d ${D}${sysconfdir}/yum.repos.d
> +        install -m 0644 ${WORKDIR}/oe-remote.repo.sample ${D}${sysconfdir}/yum.repos.d
> +}
> +
> +FILES_${PN} += "${datadir}/dnf"
> +
> +RDEPENDS_${PN} += " \
> +  dnf \
> +  libnewt-python \
> +  "
> +
> +BBCLASSEXTEND = "nativesdk"
> diff --git a/meta-oe/recipes-devtools/dnf-plugin-tui/files/oe-remote.repo.sample b/meta-oe/recipes-devtools/dnf-plugin-tui/files/oe-remote.repo.sample
> new file mode 100644
> index 000000000..6c4502e17
> --- /dev/null
> +++ b/meta-oe/recipes-devtools/dnf-plugin-tui/files/oe-remote.repo.sample
> @@ -0,0 +1,5 @@
> +[base]
> +name=myrepo
> +baseurl=http://127.0.0.1/oe_repo/
> +enabled=1
> +gpgcheck=0
> 
-------------- next part --------------
A non-text attachment was scrubbed...
Name: pEpkey.asc
Type: application/pgp-keys
Size: 2334 bytes
Desc: not available
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20190807/8391d17d/attachment-0001.bin>