[oe] [meta-gnome][PATCH 2/3] gnome-keyring: Update to version 3.28.2

[Piotr Tworek]

This is the latest stable upstream release.

For the most part this is a simple version bump. There are however
some small additional changes this patch makes.
1. Inherit gettext bbclass since the build system used by this pacakge
   does use it.
2. Inherit upstream-version-is-even bbclass. GNOME components like this
   do follow versioning scheme checked by this bbclass.
3. Use PACKAGECONFIG to handle pam feature.
4. Add optional, disabled by default feature for ssh-agent integration
   this new version of gnome-keyring has. This does not introduce any
   additional build time dependencies. For the feature to work ssh-add
   and ssh-agent tools need to be provided in the rootfs. Both are shipped
   in openssh-misc package. For the configure script to work reliably in
   all setups we also need to tell it said tools are available in
   bindir. This is done by specifying ac_cv_path_SSH_ADD and
   ac_cv_path_SSH_AGENT. Without those configure can fail if the host
   system does not have both tools instsalled in /usr/bin.

Signed-off-by: Piotr Tworek <tworaz at tworaz.net>
---
 ...keyring_3.20.0.bb => gnome-keyring_3.28.2.bb} | 16 +++++++++-------
 1 file changed, 9 insertions(+), 7 deletions(-)
 rename meta-gnome/recipes-gnome/gnome-keyring/{gnome-keyring_3.20.0.bb => gnome-keyring_3.28.2.bb} (55%)

diff --git a/meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.20.0.bb b/meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.28.2.bb
similarity index 55%
rename from meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.20.0.bb
rename to meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.28.2.bb
index 55640625d..8dc11c85d 100644
--- a/meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.20.0.bb
+++ b/meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.28.2.bb
@@ -9,7 +9,7 @@ LIC_FILES_CHKSUM = " \
     file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
 "
 
-inherit distro_features_check gnomebase remove-libtool
+inherit distro_features_check gnomebase remove-libtool gettext upstream-version-is-even
 
 DEPENDS = " \
     intltool-native \
@@ -20,19 +20,21 @@ DEPENDS = " \
     ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)} \
 "
 
-SRC_URI[archive.md5sum] = "e09efe8021944dae404736b5a2adb98e"
-SRC_URI[archive.sha256sum] = "bc17cecd748a0e46e302171d11c3ae3d76bba5258c441fabec3786f418e7ec99"
+SRC_URI[archive.md5sum] = "284580f954f762caf62aed2ae7358177"
+SRC_URI[archive.sha256sum] = "81171b7d07211b216b4c9bb79bf2deb3deca18fe8d56d46dda1c4549b4a2646a"
 SRC_URI += "file://musl.patch"
 
 REQUIRED_DISTRO_FEATURES = "x11"
 
 RDEPENDS_${PN} = "libgnome-keyring glib-2.0-utils"
 
-EXTRA_OECONF = " \
-    --disable-doc \
-    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam --with-pam-dir=${base_libdir}/security', '--disable-pam', d)} \
-"
+EXTRA_OECONF = "--disable-doc \
+                ac_cv_path_SSH_AGENT=${bindir}/ssh-agent \
+                ac_cv_path_SSH_ADD=${bindir}/ssh-add"
 
+PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
+PACKAGECONFIG[pam] = "--enable-pam --with-pam-dir=${base_libdir}/security, --disable-pam"
+PACKAGECONFIG[ssh-agent] = "--enable-ssh-agent,--disable-ssh-agent,,openssh-misc"
 
 FILES_${PN} += " \
     ${datadir}/dbus-1/services \
-- 
2.21.0