[oe] [PATCH][meta-networking] blueman: update to 2.1.1

[Khem Raj]

HI Oleksandr

Can you rebase this on top of master-next and resend ?

On 7/21/19 4:38 PM, Oleksandr Kravchuk wrote:
> Removed patch was upstreamed.
>
> Signed-off-by: Oleksandr Kravchuk <open.source at oleksandr-kravchuk.com>
> ---
>   .../blueman/blueman_2.1.1.bb                  | 58 +++++++++++++++++++
>   .../blueman/blueman_git.bb                    | 42 --------------
>   2 files changed, 58 insertions(+), 42 deletions(-)
>   create mode 100644 meta-networking/recipes-connectivity/blueman/blueman_2.1.1.bb
>   delete mode 100644 meta-networking/recipes-connectivity/blueman/blueman_git.bb
>
> diff --git a/meta-networking/recipes-connectivity/blueman/blueman_2.1.1.bb b/meta-networking/recipes-connectivity/blueman/blueman_2.1.1.bb
> new file mode 100644
> index 000000000..36de2af1d
> --- /dev/null
> +++ b/meta-networking/recipes-connectivity/blueman/blueman_2.1.1.bb
> @@ -0,0 +1,58 @@
> +DESCRIPTION = "Blueman is a GTK+ Bluetooth Manager"
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
> +
> +DEPENDS = "bluez5 python3-pygobject python3-cython-native python3-setuptools-native intltool-native"
> +
> +inherit autotools systemd gsettings python3native gtk-icon-cache
> +
> +SRC_URI = " \
> +    https://github.com/blueman-project/blueman/releases/download/${PV}/blueman-${PV}.tar.xz \
> +    file://0001-Search-for-cython3.patch \
> +"
> +SRC_URI[md5sum] = "9de89abb31be45bdbf11f7884764a2dc"
> +SRC_URI[sha256sum] = "f1eab2334e5a1587defa80900901048d14c2e8ffa8c0cff7240bc9937a61dbc3"
> +
> +EXTRA_OECONF = " \
> +    --disable-runtime-deps-check \
> +    --disable-schemas-compile \
> +"
> +
> +SYSTEMD_SERVICE_${PN} = "${BPN}-mechanism.service"
> +SYSTEMD_AUTO_ENABLE_${PN} = "disable"
> +
> +RRECOMENDS_${PN} += "adwaita-icon-theme"
> +RDEPENDS_${PN} += " \
> +    python3-core \
> +    python3-dbus \
> +    packagegroup-tools-bluetooth \
> +"
> +
> +PACKAGECONFIG ??= "thunar"
> +PACKAGECONFIG[thunar] = "--enable-thunar-sendto,--disable-thunar-sendto"
> +
> +FILES_${PN} += " \
> +    ${datadir}/dbus-1 \
> +    ${datadir}/Thunar \
> +    ${systemd_user_unitdir} \
> +    ${exec_prefix}${systemd_system_unitdir} \
> +    ${PYTHON_SITEPACKAGES_DIR} \
> +"
> +
> +FILES_${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/_blueman.a"
> +
> +# In code, path to python is a variable that is replaced with path to native version of it
> +# during the configure stage, e.g ../recipe-sysroot-native/usr/bin/python3-native/python3.
> +# Replace it with #!/usr/bin/env python3
> +do_install_append() {
> +    sed -i "1s/.*/#!\/usr\/bin\/env python3/" ${D}${prefix}/libexec/blueman-rfcomm-watcher \
> +                                              ${D}${prefix}/libexec/blueman-mechanism \
> +                                              ${D}${bindir}/blueman-tray \
> +                                              ${D}${bindir}/blueman-services \
> +                                              ${D}${bindir}/blueman-sendto \
> +                                              ${D}${bindir}/blueman-report \
> +                                              ${D}${bindir}/blueman-manager \
> +                                              ${D}${bindir}/blueman-assistant \
> +                                              ${D}${bindir}/blueman-applet \
> +                                              ${D}${bindir}/blueman-adapters
> +}
> diff --git a/meta-networking/recipes-connectivity/blueman/blueman_git.bb b/meta-networking/recipes-connectivity/blueman/blueman_git.bb
> deleted file mode 100644
> index 91b64a36b..000000000
> --- a/meta-networking/recipes-connectivity/blueman/blueman_git.bb
> +++ /dev/null
> @@ -1,42 +0,0 @@
> -DESCRIPTION = "Blueman is a GTK+ Bluetooth Manager"
> -LICENSE = "GPLv3"
> -LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
> -
> -DEPENDS = "bluez5 python3-pygobject python3-cython-native python3-setuptools-native intltool-native"
> -
> -inherit autotools systemd gsettings python3native gtk-icon-cache
> -
> -SRC_URI = " \
> -    git://github.com/blueman-project/blueman.git \
> -    file://0001-Search-for-cython3.patch \
> -"
> -SRCREV = "c4a03417e81e21543d4568e8e7f7de307582eb50"
> -PV = "2.0.5+git${SRCPV}"
> -S = "${WORKDIR}/git"
> -
> -EXTRA_OECONF = " \
> -    --disable-runtime-deps-check \
> -    --disable-schemas-compile \
> -"
> -
> -SYSTEMD_SERVICE_${PN} = "${BPN}-mechanism.service"
> -SYSTEMD_AUTO_ENABLE_${PN} = "disable"
> -
> -RRECOMENDS_${PN} += "adwaita-icon-theme"
> -RDEPENDS_${PN} += " \
> -    python3-dbus \
> -    packagegroup-tools-bluetooth \
> -"
> -
> -PACKAGECONFIG ??= "thunar"
> -PACKAGECONFIG[thunar] = "--enable-thunar-sendto,--disable-thunar-sendto"
> -
> -FILES_${PN} += " \
> -    ${datadir}/dbus-1 \
> -    ${datadir}/Thunar \
> -    ${systemd_user_unitdir} \
> -    ${exec_prefix}${systemd_system_unitdir} \
> -    ${PYTHON_SITEPACKAGES_DIR} \
> -"
> -
> -FILES_${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/_blueman.a"