[oe] [meta-oe][PATCH] libseccomp: import from meta-security

[Bruce Ashfield]

On Thu, Jul 25, 2019 at 3:06 AM <mingli.yu at windriver.com> wrote:
>
> From: Mingli Yu <Mingli.Yu at windriver.com>

Can you share some details as to why this should be pulled from
meta-security into a different repo ?

It seems to fit the mandate of meta-security quite nicely ;)

Is there some sort of dependency issue, or other technical problem
that is causing a problem ?

Bruce

>
> Signed-off-by: Mingli Yu <Mingli.Yu at windriver.com>
> ---
>  .../recipes-security/libseccomp/files/run-ptest    |  4 +++
>  .../libseccomp/libseccomp_2.4.1.bb                 | 41 ++++++++++++++++++++++
>  2 files changed, 45 insertions(+)
>  create mode 100644 meta-oe/recipes-security/libseccomp/files/run-ptest
>  create mode 100644 meta-oe/recipes-security/libseccomp/libseccomp_2.4.1.bb
>
> diff --git a/meta-oe/recipes-security/libseccomp/files/run-ptest b/meta-oe/recipes-security/libseccomp/files/run-ptest
> new file mode 100644
> index 0000000..54b4a63
> --- /dev/null
> +++ b/meta-oe/recipes-security/libseccomp/files/run-ptest
> @@ -0,0 +1,4 @@
> +#!/bin/sh
> +
> +cd tests
> +./regression -a
> diff --git a/meta-oe/recipes-security/libseccomp/libseccomp_2.4.1.bb b/meta-oe/recipes-security/libseccomp/libseccomp_2.4.1.bb
> new file mode 100644
> index 0000000..dba1be5
> --- /dev/null
> +++ b/meta-oe/recipes-security/libseccomp/libseccomp_2.4.1.bb
> @@ -0,0 +1,41 @@
> +SUMMARY = "interface to seccomp filtering mechanism"
> +DESCRIPTION = "The libseccomp library provides and easy to use, platform independent,interface to the Linux Kernel's syscall filtering mechanism: seccomp."
> +SECTION = "security"
> +LICENSE = "LGPL-2.1"
> +LIC_FILES_CHKSUM = "file://LICENSE;beginline=0;endline=1;md5=8eac08d22113880357ceb8e7c37f989f"
> +
> +SRCREV = "fb43972ea1aab24f2a70193fb7445c2674f594e3"
> +
> +SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=release-2.4 \
> +           file://run-ptest \
> +"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit autotools-brokensep pkgconfig ptest
> +
> +PACKAGECONFIG ??= ""
> +PACKAGECONFIG[python] = "--enable-python, --disable-python, python"
> +
> +do_compile_ptest() {
> +    oe_runmake -C tests check-build
> +}
> +
> +do_install_ptest() {
> +    install -d ${D}${PTEST_PATH}/tests
> +    install -d ${D}${PTEST_PATH}/tools
> +    for file in $(find tests/* -executable -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
> +    done
> +    for file in $(find tests/*.tests -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
> +    done
> +    for file in $(find tools/* -executable -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
> +    done
> +}
> +
> +FILES_${PN} = "${bindir} ${libdir}/${BPN}.so*"
> +FILES_${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
> +
> +RDEPENDS_${PN}-ptest = "bash"
> --
> 2.7.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel



-- 
- Thou shalt not follow the NULL pointer, for chaos and madness await
thee at its end
- "Use the force Harry" - Gandalf, Star Trek II