[oe] [meta-oe][PATCH 3/8] funyahoo-plusplus, icyque, pidgin-sipe, purple-skypeweb: add couple plugins for pidgin

[Khem Raj]

Hi Martin

I noticed this error on qemux86-64

https://errors.yoctoproject.org/Errors/Details/248480/

It seems we need to bring in recipe for gmime for this to work. This
is already in master
so can you work on fixing this?

On Thu, May 23, 2019 at 4:55 AM Martin Jansa <martin.jansa at gmail.com> wrote:
>
> * import from luneos to make pidgin here in meta-oe a bit more useful
>
> Signed-off-by: Martin Jansa <Martin.Jansa at gmail.com>
> ---
>  .../pidgin/funyahoo-plusplus_git.bb           | 25 ++++++++++++++
>  meta-oe/recipes-support/pidgin/icyque_git.bb  | 27 +++++++++++++++
>  .../pidgin/pidgin-sipe_1.24.0.bb              | 34 +++++++++++++++++++
>  .../pidgin/purple-skypeweb_git.bb             | 26 ++++++++++++++
>  4 files changed, 112 insertions(+)
>  create mode 100644 meta-oe/recipes-support/pidgin/funyahoo-plusplus_git.bb
>  create mode 100644 meta-oe/recipes-support/pidgin/icyque_git.bb
>  create mode 100644 meta-oe/recipes-support/pidgin/pidgin-sipe_1.24.0.bb
>  create mode 100644 meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb
>
> diff --git a/meta-oe/recipes-support/pidgin/funyahoo-plusplus_git.bb b/meta-oe/recipes-support/pidgin/funyahoo-plusplus_git.bb
> new file mode 100644
> index 0000000000..3a437659e7
> --- /dev/null
> +++ b/meta-oe/recipes-support/pidgin/funyahoo-plusplus_git.bb
> @@ -0,0 +1,25 @@
> +SUMMARY = "Protocol plugin for New Yahoo (2016) for Adium, Pidgin, Miranda and Telepathy IM Framework"
> +SECTION = "webos/services"
> +LICENSE = "GPLv3.0"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=84dcc94da3adb52b53ae4fa38fe49e5d"
> +
> +DEPENDS = "pidgin json-glib glib-2.0"
> +
> +inherit pkgconfig
> +
> +SRC_URI = "git://github.com/EionRobb/funyahoo-plusplus;branch=master;protocol=git"
> +SRCREV = "fbbd9c591100aa00a0487738ec7b6acd3d924b3f"
> +
> +S = "${WORKDIR}/git"
> +
> +do_compile() {
> +    oe_runmake CC="${CC}" CXX="${CXX}" EXTRA_INCLUDES="${TARGET_CFLAGS}" AR="${AR}";
> +}
> +
> +do_install() {
> +    oe_runmake DESTDIR="${D}" install;
> +}
> +
> +FILES_${PN} += " \
> +    ${libdir} \
> +"
> diff --git a/meta-oe/recipes-support/pidgin/icyque_git.bb b/meta-oe/recipes-support/pidgin/icyque_git.bb
> new file mode 100644
> index 0000000000..0f32dc3a39
> --- /dev/null
> +++ b/meta-oe/recipes-support/pidgin/icyque_git.bb
> @@ -0,0 +1,27 @@
> +SUMMARY = "WIM Protocol plugin for ICQ for Adium, Pidgin, Miranda and Telepathy IM Framework"
> +SECTION = "webos/services"
> +LICENSE = "GPLv3.0"
> +LIC_FILES_CHKSUM = "file://LICENSE;md5=1ebbd3e34237af26da5dc08a4e440464"
> +
> +DEPENDS = "pidgin json-glib"
> +
> +PV = "0.1+gitr${SRCPV}"
> +
> +inherit pkgconfig
> +
> +SRC_URI = "git://github.com/EionRobb/icyque"
> +SRCREV = "513fc162d5d1a201c2b044e2b42941436d1069d5"
> +
> +S = "${WORKDIR}/git"
> +
> +do_compile() {
> +    oe_runmake;
> +}
> +
> +do_install() {
> +    oe_runmake DESTDIR="${D}" install;
> +}
> +
> +FILES_${PN} += " \
> +    ${libdir} \
> +"
> diff --git a/meta-oe/recipes-support/pidgin/pidgin-sipe_1.24.0.bb b/meta-oe/recipes-support/pidgin/pidgin-sipe_1.24.0.bb
> new file mode 100644
> index 0000000000..beae281a30
> --- /dev/null
> +++ b/meta-oe/recipes-support/pidgin/pidgin-sipe_1.24.0.bb
> @@ -0,0 +1,34 @@
> +SUMMARY = "Protocol plugin for Office 365/Lync/OCS for Adium, Pidgin, Miranda and Telepathy IM Framework"
> +SECTION = "webos/services"
> +LICENSE = "GPLv2.0"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
> +
> +DEPENDS = "pidgin intltool-native glib-2.0-native"
> +
> +inherit pkgconfig
> +inherit autotools
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/sipe/pidgin-sipe-${PV}.tar.xz \
> +"
> +
> +SRC_URI[md5sum] = "b91106d28c235b347a63dcb676f7b66a"
> +SRC_URI[sha256sum] = "958803722b23d869131f76bd90df9da19116d4ca5a873e5253371479b7390f43"
> +
> +PACKAGECONFIG ??= "nss krb5"
> +PACKAGECONFIG[nss] = "--enable-nss=yes,--enable-nss=no,nss"
> +PACKAGECONFIG[openssl] = "--enable-openssl=yes,--enable-openssl=no,openssl"
> +PACKAGECONFIG[krb5] = "--with-krb5=yes,--with-krb5=no,krb5"
> +#PACKAGECONFIG[voice_and_video] = "--with-vv=yes,--with-vv=no,libnice gstreamer"
> +PACKAGECONFIG[telepathy] = "--enable-telepathy=yes,--enable-telepathy=no,telepathy-glib gmime"
> +#PACKAGECONFIG[gssapi_only] = "--enable-gssapi-only=yes,--enable-gssapi-only=no,krb5"
> +PACKAGECONFIG[debug] = "--enable-debug=yes,--enable-debug=no,valgrind"
> +
> +FILES_${PN}-dev += " \
> +    ${libdir}/purple-2/*.la \
> +"
> +
> +FILES_${PN} += " \
> +    ${libdir}/purple-2/libsipe.so \
> +    ${datadir}/appdata \
> +    ${datadir}/metainfo \
> +"
> diff --git a/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb b/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb
> new file mode 100644
> index 0000000000..092e6059b8
> --- /dev/null
> +++ b/meta-oe/recipes-support/pidgin/purple-skypeweb_git.bb
> @@ -0,0 +1,26 @@
> +SUMMARY = "Skype protocol plug-in for libpurple"
> +SECTION = "webos/services"
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = "file://skypeweb/gpl3.txt;md5=d90260d32cef39f3c8d6c0f05d3adb8e"
> +
> +DEPENDS = "pidgin json-glib glib-2.0 zlib"
> +
> +inherit pkgconfig
> +
> +SRC_URI = "git://github.com/EionRobb/skype4pidgin;branch=master;protocol=git"
> +SRCREV = "14f1b69b6292bbdc98cca484b050ec8359394c4e"
> +
> +S = "${WORKDIR}/git"
> +PV = "1.5+git${SRCPV}"
> +
> +do_compile() {
> +    oe_runmake -C skypeweb;
> +}
> +
> +do_install() {
> +    oe_runmake -C skypeweb DESTDIR="${D}" install;
> +}
> +
> +FILES_${PN} += " \
> +    ${libdir} \
> +"
> --
> 2.17.1
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel