[oe] [PATCH 23/41] tracker: initial add 2.2.2
Andreas Müller
schnitzeltony at gmail.com
Thu May 23 06:48:41 UTC 2019
This is a dependenccy for upcoming nautilus 3.32
Signed-off-by: Andreas Müller <schnitzeltony at gmail.com>
---
.../recipes-gnome/tracker/tracker_2.2.2.bb | 51 +++++++++++++++++++
1 file changed, 51 insertions(+)
create mode 100644 meta-gnome/recipes-gnome/tracker/tracker_2.2.2.bb
diff --git a/meta-gnome/recipes-gnome/tracker/tracker_2.2.2.bb b/meta-gnome/recipes-gnome/tracker/tracker_2.2.2.bb
new file mode 100644
index 000000000..4c9083fd5
--- /dev/null
+++ b/meta-gnome/recipes-gnome/tracker/tracker_2.2.2.bb
@@ -0,0 +1,51 @@
+SUMMARY = "Tracker is a file search engine"
+LICENSE = "GPLv2 & LGPLv2.1"
+LIC_FILES_CHKSUM = " \
+ file://COPYING.GPL;md5=ee31012bf90e7b8c108c69f197f3e3a4 \
+ file://COPYING.LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
+"
+
+DEPENDS = " \
+ libxml2-native \
+ glib-2.0 \
+ sqlite3 \
+ libarchive \
+ dbus \
+ icu \
+ json-glib \
+ libsoup-2.4 \
+ libstemmer \
+"
+
+GNOMEBASEBUILDCLASS = "meson"
+
+inherit gnomebase gobject-introspection vala gtk-doc manpages bash-completion distro_features_check
+
+SRC_URI[archive.md5sum] = "2ec18c6f9e877abdfe1f50bac0e9eade"
+SRC_URI[archive.sha256sum] = "c6a73462f9aa9c32efa139003d2abd2ac5f70f8af6ce744729954975a661e2e6"
+
+# gobject-introspection is mandatory and cannot be configured
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+UNKNOWN_CONFIGURE_WHITELIST_append = " introspection"
+
+CFLAGS += "-lstemmer"
+
+PACKAGECONFIG ??= "fts"
+PACKAGECONFIG[networkmanager] = "-Dnetwork_manager=enabled,-Dnetwork_manager=disabled,networkmanger"
+# full text search requires sqlite3 build with PACKAGECONFIG[fts5] set
+PACKAGECONFIG[fts] = "-Dfts=true,-Dfts=false"
+
+# set required cross property sqlite3_has_fts5
+do_write_config[vardeps] += "PACKAGECONFIG"
+do_write_config_append() {
+ echo "[properties]" > ${WORKDIR}/meson-tracker.cross
+ echo "sqlite3_has_fts5 = '${@bb.utils.contains('PACKAGECONFIG', 'fts', 'true', 'false', d)}'" >> ${WORKDIR}/meson-tracker.cross
+}
+
+EXTRA_OEMESON = "--cross-file ${WORKDIR}/meson-tracker.cross"
+
+FILES_${PN} += " \
+ ${datadir}/dbus-1 \
+ ${libdir}/tracker-2.0 \
+ ${systemd_user_unitdir} \
+"
--
2.20.1
More information about the Openembedded-devel
mailing list