[oe] [PATCH 11/16] tracker: initial add 2.3.1

Andreas Müller schnitzeltony at gmail.com
Thu Nov 14 19:49:25 UTC 2019


This is a dependenccy for upcoming nautilus 3.34

Signed-off-by: Andreas Müller <schnitzeltony at gmail.com>
---
 .../recipes-gnome/tracker/tracker_2.3.1.bb    | 50 +++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 meta-gnome/recipes-gnome/tracker/tracker_2.3.1.bb

diff --git a/meta-gnome/recipes-gnome/tracker/tracker_2.3.1.bb b/meta-gnome/recipes-gnome/tracker/tracker_2.3.1.bb
new file mode 100644
index 000000000..ad65630c1
--- /dev/null
+++ b/meta-gnome/recipes-gnome/tracker/tracker_2.3.1.bb
@@ -0,0 +1,50 @@
+SUMMARY = "Tracker is a file search engine"
+LICENSE = "GPLv2 & LGPLv2.1"
+LIC_FILES_CHKSUM = " \
+    file://COPYING.GPL;md5=ee31012bf90e7b8c108c69f197f3e3a4 \
+    file://COPYING.LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
+"
+
+DEPENDS = " \
+    libxml2-native \
+    dbus-native \
+    glib-2.0 \
+    sqlite3 \
+    libarchive \
+    dbus \
+    icu \
+    json-glib \
+    libsoup-2.4 \
+    libstemmer \
+"
+
+GNOMEBASEBUILDCLASS = "meson"
+
+inherit gnomebase gobject-introspection vala gtk-doc manpages bash-completion distro_features_check
+
+SRC_URI[archive.md5sum] = "5e75b611b190c4cebf53e3de15266429"
+SRC_URI[archive.sha256sum] = "b6748726e465ad2f4d991560634b1fd0df8841f3d981b3b837c4162abedf08a1"
+
+# gobject-introspection is mandatory and cannot be configured
+REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
+UNKNOWN_CONFIGURE_WHITELIST_append = " introspection"
+
+PACKAGECONFIG ??= "fts"
+PACKAGECONFIG[networkmanager] = "-Dnetwork_manager=enabled,-Dnetwork_manager=disabled,networkmanger"
+# full text search requires sqlite3 build with PACKAGECONFIG[fts5] set
+PACKAGECONFIG[fts] = "-Dfts=true,-Dfts=false"
+
+# set required cross property sqlite3_has_fts5
+do_write_config[vardeps] += "PACKAGECONFIG"
+do_write_config_append() {
+    echo "[properties]" > ${WORKDIR}/meson-tracker.cross
+    echo "sqlite3_has_fts5 = '${@bb.utils.contains('PACKAGECONFIG', 'fts', 'true', 'false', d)}'" >> ${WORKDIR}/meson-tracker.cross
+}
+
+EXTRA_OEMESON = "--cross-file ${WORKDIR}/meson-tracker.cross"
+
+FILES_${PN} += " \
+    ${datadir}/dbus-1 \
+    ${libdir}/tracker-2.0 \
+    ${systemd_user_unitdir} \
+"
-- 
2.21.0



More information about the Openembedded-devel mailing list