[oe-commits] [meta-openembedded] 01/03: cpupower: add recipes

[git at git.openembedded.org]

martin_jansa pushed a commit to branch master-next
in repository meta-openembedded.

commit 18af446cfc4fbc3f1084155f9f19f034ed6a03bc
Author: Roy Li <rongqing.li at windriver.com>
AuthorDate: Tue Mar 29 15:28:56 2016 +0800

    cpupower: add recipes
    
    cpupower is tools to shows and sets processor power related values
    
    Signed-off-by: Roy Li <rongqing.li at windriver.com>
    Signed-off-by: Martin Jansa <Martin.Jansa at gmail.com>
---
 meta-oe/recipes-kernel/cpupower/cpupower.bb | 41 +++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/meta-oe/recipes-kernel/cpupower/cpupower.bb b/meta-oe/recipes-kernel/cpupower/cpupower.bb
new file mode 100644
index 0000000..d53deac
--- /dev/null
+++ b/meta-oe/recipes-kernel/cpupower/cpupower.bb
@@ -0,0 +1,41 @@
+SUMMARY = "Shows and sets processor power related values"
+DESCRIPTION = "cpupower is a collection of tools to examine and tune power \
+saving related features of your processor."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+DEPENDS = "pciutils"
+
+inherit kernelsrc kernel-arch
+
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+do_populate_lic[depends] += "virtual/kernel:do_patch"
+
+PROVIDES = "virtual/cpupower"
+
+B = "${WORKDIR}/${BPN}-${PV}"
+
+EXTRA_OEMAKE = '\
+    -C ${S}/tools/power/cpupower \
+    O=${B} \
+    CROSS=${TARGET_PREFIX} \
+    ARCH=${ARCH} \
+    CC="${CC}" \
+    AR="${AR}" \
+'
+do_compile() {
+	unset CFLAGS
+	oe_runmake all
+}
+
+do_install() {
+	unset CFLAGS
+	oe_runmake DESTDIR=${D} install
+	chown root:root ${D}/${libdir}/*
+}
+
+python do_package_prepend() {
+    d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+RDEPENDS_${PN} = "bash"

-- 
To stop receiving notification emails like this one, please contact
the administrator of this repository.