[oe-commits] [meta-openembedded] 02/03: tmon: add recipes
git at git.openembedded.org
git at git.openembedded.org
Tue Mar 29 11:49:21 UTC 2016
martin_jansa pushed a commit to branch master-next
in repository meta-openembedded.
commit 7ed85b6742743dbd68f845be3b1153aaf68dfb70
Author: Roy Li <rongqing.li at windriver.com>
AuthorDate: Tue Mar 29 15:49:44 2016 +0800
tmon: add recipes
tmon is a monitoring and testing tool for Linux kernel thermal subsystem
Signed-off-by: Roy Li <rongqing.li at windriver.com>
Signed-off-by: Martin Jansa <Martin.Jansa at gmail.com>
---
meta-oe/recipes-kernel/tmon/tmon.bb | 34 ++++++++++++++++++++++++++++++++++
1 file changed, 34 insertions(+)
diff --git a/meta-oe/recipes-kernel/tmon/tmon.bb b/meta-oe/recipes-kernel/tmon/tmon.bb
new file mode 100644
index 0000000..3bf2b3d
--- /dev/null
+++ b/meta-oe/recipes-kernel/tmon/tmon.bb
@@ -0,0 +1,34 @@
+SUMMARY = "A monitoring and testing tool for Linux kernel thermal subsystem"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+DEPENDS = "ncurses"
+
+inherit kernelsrc kernel-arch
+
+do_configure[depends] += "virtual/kernel:do_shared_workdir"
+do_populate_lic[depends] += "virtual/kernel:do_patch"
+
+B = "${WORKDIR}/${BPN}-${PV}"
+
+EXTRA_OEMAKE = '\
+ -C ${S}/tools/thermal/tmon \
+ CROSS_COMPILE=${TARGET_PREFIX} \
+ ARCH=${ARCH} \
+ CC="${CC}" \
+ AR="${AR}" \
+'
+do_compile() {
+ unset CFLAGS
+ oe_runmake tmon
+}
+
+do_install() {
+ unset CFLAGS
+ oe_runmake INSTALL_ROOT=${D} install
+}
+
+python do_package_prepend() {
+ d.setVar('PKGV', d.getVar("KERNEL_VERSION", True).split("-")[0])
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
--
To stop receiving notification emails like this one, please contact
the administrator of this repository.
More information about the Openembedded-commits
mailing list