[OE-core] [PATCH v3] buildinfo.bblass: Added buildinfo class
Alejandro Hernandez
alejandro.hernandez at linux.intel.com
Thu Oct 30 19:19:19 UTC 2014
Writes build information to target filesystem to help developers
[YOCTO #6770]
Signed-off-by: Alejandro Hernandez <alejandro.hernandez at linux.intel.com>
---
meta/classes/buildinfo.bbclass | 90 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 90 insertions(+)
create mode 100644 meta/classes/buildinfo.bbclass
diff --git a/meta/classes/buildinfo.bbclass b/meta/classes/buildinfo.bbclass
new file mode 100644
index 0000000..f00b073
--- /dev/null
+++ b/meta/classes/buildinfo.bbclass
@@ -0,0 +1,90 @@
+#
+# Writes build information to target filesystem
+#
+# Usage: add INHERIT += "buildinfo" to your conf file
+#
+# Based in part on buildhistory.bbclass
+#
+# Copyright (C) 2014 Intel Corporation
+# Author: Alejandro Enedino Hernandez Samaniego <alejandro.hernandez at intel.com>
+#
+# Licensed under the MIT license, see COPYING.MIT for details
+#
+
+# From buildhistory.bbclass
+def squashspaces(string):
+ import re
+ return re.sub("\s+", " ", string).strip()
+
+# From buildhistory.bbclass
+def outputvars(vars, listvars, d):
+ vars = vars.split()
+ listvars = listvars.split()
+ ret = ""
+ for var in vars:
+ value = d.getVar(var, True) or ""
+ if var in listvars:
+ value = squashspaces(value)
+ ret += "%s = %s\n" % (var, value)
+ return ret.rstrip('\n')
+
+# From buildhistory.bbclass
+def base_get_metadata_git_branch(path, d):
+ branch = os.popen('cd %s; git branch 2>&1 | grep "^* " | tr -d "* "' % path).read()
+ if len(branch) != 0:
+ return branch
+ return "<unknown>"
+
+# From buildhistory.bbclass
+def base_get_metadata_git_revision(path, d):
+ f = os.popen("cd %s; git log -n 1 --pretty=oneline -- 2>&1" % path)
+ data = f.read()
+ if f.close() is None:
+ rev = data.split(" ")[0]
+ if len(rev) != 0:
+ return rev
+ return "<unknown>"
+
+# Gets git branch's status (clean or dirty)
+def get_layer_git_status(path):
+ f = os.popen("cd %s; git diff --stat 2>&1 | tail -n 1" % path)
+ data = f.read()
+ if f.close() is None:
+ if len(data) != 0:
+ return "-- modified"
+ return ""
+
+# Returns layer revisions along with their respective status
+def get_layer_revs(d):
+ layers = (d.getVar("BBLAYERS", True) or "").split()
+ medadata_revs = ["%-17s = %s:%s %s" % (os.path.basename(i), \
+ base_get_metadata_git_branch(i, None).strip(), \
+ base_get_metadata_git_revision(i, None), \
+ get_layer_git_status(i)) \
+ for i in layers]
+ return '\n'.join(medadata_revs)
+
+def buildinfo_target(d):
+ # Get context
+ if d.getVar('BB_WORKERCONTEXT', True) != '1':
+ return ""
+ # Single and list variables to be read
+ vars = "DISTRO DISTRO_VERSION BB_VERSION BUILD_SYS TARGET_SYS MACHINE USER_CLASSES IMAGE_CLASSES IMAGE_FEATURES IMAGE_LINGUAS IMAGE_INSTALL PACKAGE_EXCLUDE"
+ listvars = "USER_CLASSES IMAGE_CLASSES IMAGE_FEATURES IMAGE_LINGUAS IMAGE_INSTALL PACKAGE_EXCLUDE"
+ return outputvars(vars, listvars, d)
+
+# Write build information to target filesystem
+buildinfo () {
+cat > ${IMAGE_ROOTFS}${sysconfdir}/build <<END
+-----------------------
+Build Configuration: |
+-----------------------
+${@buildinfo_target(d)}
+-----------------------
+Layer Revisions: |
+-----------------------
+${@get_layer_revs(d)}
+END
+}
+
+IMAGE_PREPROCESS_COMMAND += "buildinfo;"
--
1.9.1
More information about the Openembedded-core
mailing list