[oe] [meta-oe][PATCH] libjpeg-turbo: update 1.3.0 -> 1.3.1

Sun May 4 15:12:35 UTC 2014

On Sat, May 03, 2014 at 12:23:01AM -0700, Andre McCurdy wrote:
> This commit also modifies SRC_URI to fetch a release tarfile instead
> of checking out from SourceForge SVN and makes some minor updates to
> the jpeg-tools DESCRIPTION text.
> 
> Signed-off-by: Andre McCurdy <armccurdy at gmail.com>
> ---
>  .../recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb    | 39 ++++++++++++++++++++++
>  meta-oe/recipes-core/jpeg/libjpeg-turbo_svn.bb     | 36 --------------------
>  2 files changed, 39 insertions(+), 36 deletions(-)
>  create mode 100644 meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb
>  delete mode 100644 meta-oe/recipes-core/jpeg/libjpeg-turbo_svn.bb
> 
> diff --git a/meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb b/meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb
> new file mode 100644
> index 0000000..d30811e
> --- /dev/null
> +++ b/meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb
> @@ -0,0 +1,39 @@
> +DESCRIPTION = "libjpeg-turbo is a derivative of libjpeg that uses SIMD instructions (MMX, SSE2, NEON) to accelerate baseline JPEG compression and decompression"
> +HOMEPAGE = "http://libjpeg-turbo.org/"
> +
> +LICENSE = "BSD-3-Clause"
> +LIC_FILES_CHKSUM = "file://cdjpeg.h;endline=12;md5=78fa8dbac547bb5b2a0e6457a6cfe21d \
> +                    file://jpeglib.h;endline=14;md5=a08bb0a80f782a9f8da313cc4015ed6f \
> +                    file://djpeg.c;endline=9;md5=7629c51aed78174711c20a40194a8f1b \
> +"
> +
> +BASEPV = "${@d.getVar('PV',1).split('+')[1]}"

,1 -> ,True

> +SRC_URI = "${SOURCEFORGE_MIRROR}/${PN}/${PN}-${BASEPV}.tar.gz"

PN -> BPN

> +SRC_URI[md5sum] = "2c3a68129dac443a72815ff5bb374b05"
> +SRC_URI[sha256sum] = "c132907417ddc40ed552fe53d6b91d5fecbb14a356a60ddc7ea50d6be9666fb9"
> +
> +S = "${WORKDIR}/${PN}-${BASEPV}"

PN -> BPN

I did above changes in master-next, because otherwise
libjpeg-turbo-native fails to fetch:

NOTE: Running task 1098 of 25448 (ID: 24931, virtual:native:/home/jenkins/oe/shr-core-branches/shr-core/meta-openembedded/meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb, do_fetch)
NOTE: recipe libjpeg-turbo-native-8d+1.3.1-r0: task do_fetch: Started
WARNING: Failed to fetch URL http://downloads.sourceforge.net/libjpeg-turbo-native/libjpeg-turbo-native-1.3.1.tar.gz, attempting MIRRORS if available
ERROR: Fetcher failure: Fetch command failed with exit code 8, output:
http://downloads.sourceforge.net/libjpeg-turbo-native/libjpeg-turbo-native-1.3.1.tar.gz:
2014-05-03 19:52:48 ERROR 404: Not Found.

ERROR: Function failed: Fetcher failure for URL: 'http://downloads.sourceforge.net/libjpeg-turbo-native/libjpeg-turbo-native-1.3.1.tar.gz'. Unable to fetch URL from any source.
ERROR: Logfile of failure stored in: /home/jenkins/oe/shr-core-branches/shr-core/tmp-eglibc/work/x86_64-linux/libjpeg-turbo-native/8d+1.3.1-r0/temp/log.do_fetch.5294
NOTE: recipe libjpeg-turbo-native-8d+1.3.1-r0: task do_fetch: Failed
ERROR: Task 24931 (virtual:native:/home/jenkins/oe/shr-core-branches/shr-core/meta-openembedded/meta-oe/recipes-core/jpeg/libjpeg-turbo_8d+1.3.1.bb, do_fetch) failed with exit code '1'

> +
> +# Drop-in replacement for jpeg
> +PROVIDES = "jpeg"
> +RPROVIDES_${PN} += "jpeg"
> +RREPLACES_${PN} += "jpeg"
> +RCONFLICTS_${PN} += "jpeg"
> +
> +inherit autotools pkgconfig
> +
> +EXTRA_OECONF = "--with-jpeg8 "
> +
> +PACKAGES =+ "jpeg-tools libturbojpeg"
> +
> +DESCRIPTION_jpeg-tools = "The jpeg-tools package includes client programs to access libjpeg functionality.  These tools allow for the compression, decompression, transformation and display of JPEG files and benchmarking of the libjpeg library."
> +FILES_jpeg-tools = "${bindir}/*"
> +
> +FILES_libturbojpeg = "${libdir}/libturbojpeg.so"
> +INSANE_SKIP_libturbojpeg = "dev-so"
> +
> +BBCLASSEXTEND = "native"
> +DEPENDS = "nasm-native"
> +
> +LEAD_SONAME = "libjpeg.so.8"
> diff --git a/meta-oe/recipes-core/jpeg/libjpeg-turbo_svn.bb b/meta-oe/recipes-core/jpeg/libjpeg-turbo_svn.bb
> deleted file mode 100644
> index fa4acfd..0000000
> --- a/meta-oe/recipes-core/jpeg/libjpeg-turbo_svn.bb
> +++ /dev/null
> @@ -1,36 +0,0 @@
> -DESCRIPTION = "libjpeg-turbo is a derivative of libjpeg that uses SIMD instructions (MMX, SSE2, NEON) to accelerate baseline JPEG compression and decompression"
> -HOMEPAGE = "http://libjpeg-turbo.org/"
> -
> -LICENSE = "BSD-3-Clause"
> -LIC_FILES_CHKSUM = "file://cdjpeg.h;endline=12;md5=78fa8dbac547bb5b2a0e6457a6cfe21d \
> -                    file://jpeglib.h;endline=14;md5=a08bb0a80f782a9f8da313cc4015ed6f \
> -                    file://djpeg.c;endline=13;md5=03db065044529233c296324be85530ab \
> -"
> -PV = "8d+1.3.0"
> -SRCREV = "988"
> -SRC_URI = "svn://svn.code.sf.net/p/libjpeg-turbo/code;protocol=svn;module=trunk"
> -
> -S = "${WORKDIR}/trunk"
> -
> -# Drop-in replacement for jpeg
> -PROVIDES = "jpeg"
> -RPROVIDES_${PN} += "jpeg"
> -RREPLACES_${PN} += "jpeg"
> -RCONFLICTS_${PN} += "jpeg"
> -
> -inherit autotools pkgconfig
> -
> -EXTRA_OECONF = "--with-jpeg8 "
> -
> -PACKAGES =+ "jpeg-tools libturbojpeg"
> -
> -DESCRIPTION_jpeg-tools = "The jpeg-tools package includes the client programs for access libjpeg functionality.  These tools allow for the compression, decompression, transformation and display of JPEG files."
> -FILES_jpeg-tools = "${bindir}/*"
> -
> -FILES_libturbojpeg = "${libdir}/libturbojpeg.so"
> -INSANE_SKIP_libturbojpeg = "dev-so"
> -
> -BBCLASSEXTEND = "native"
> -DEPENDS = "nasm-native"
> -
> -LEAD_SONAME = "libjpeg.so.8"
> -- 
> 1.8.1.2
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 198 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20140504/0f97743b/attachment-0002.sig>