[oe] [PATCH 1/4] soci: Add recipe

[Martin Jansa]

On Sun, Mar 01, 2015 at 10:25:05PM +0000, Khem Raj wrote:
> Define PACKAGECONFIG to enable a given backend of choice
> by default its 'empty'
> 
> Change-Id: Ie1123af658ca94d2fe22a3ca1a32dfb47d58979e
> Signed-off-by: Khem Raj <raj.khem at gmail.com>
> ---
>  meta-oe/recipes-support/soci/soci_3.2.2.bb | 46 ++++++++++++++++++++++++++++++
>  1 file changed, 46 insertions(+)
>  create mode 100644 meta-oe/recipes-support/soci/soci_3.2.2.bb

Is this v2 to fix following QA?

soci-3.2.2: soci: Files/directories were installed but not shipped
  /usr/lib64
  /usr/lib64/libsoci_core.so.3.2.2
  /usr/lib64/libsoci_empty.so.3.2.2
  /usr/lib64/libsoci_core.so.3.2
  /usr/lib64/libsoci_core.so
  /usr/lib64/libsoci_core.a
  /usr/lib64/libsoci_empty.so.3.2
  /usr/lib64/libsoci_empty.so
  /usr/lib64/libsoci_empty.a
  /usr/lib64/.debug
  /usr/lib64/.debug/libsoci_core.so.3.2.2
  /usr/lib64/.debug/libsoci_empty.so.3.2.2 [installed-vs-shipped]

> 
> diff --git a/meta-oe/recipes-support/soci/soci_3.2.2.bb b/meta-oe/recipes-support/soci/soci_3.2.2.bb
> new file mode 100644
> index 0000000..1c333cb
> --- /dev/null
> +++ b/meta-oe/recipes-support/soci/soci_3.2.2.bb
> @@ -0,0 +1,46 @@
> +# Copyright (C) 2015 Khem Raj <raj.khem at gmail.com>
> +# Released under the MIT license (see COPYING.MIT for the terms)
> +
> +DESCRIPTION = "The C++ Database Access Library"
> +HOMEPAGE = "http://soci.sourceforge.net"
> +LICENSE = "BSL-1.0"
> +SECTION = "libs"
> +DEPENDS = "boost"
> +
> +LIC_FILES_CHKSUM = "file://LICENSE_1_0.txt;md5=e4224ccaecb14d942c71d31bef20d78c"
> +
> +SRC_URI = "${SOURCEFORGE_MIRROR}/project/${BPN}/${BPN}/${P}/${P}.tar.gz"
> +SRC_URI[md5sum] = "bc3c35f6cd3f80a1be19fe30b3c111bf"
> +SRC_URI[sha256sum] = "30ea2f4d26639ef5b5cdc24fb300b3896746243dbb77b743582de2ff443ccb1c"
> +
> +TESTCONFIG = '-DSOCI_TEST_EMPTY_CONNSTR="dummy" -DSOCI_TEST_SQLITE3_CONNSTR="test.db" \
> +              -DSOCI_TEST_POSTGRESQL_CONNSTR:STRING="dbname=soci_test" \
> +              -DSOCI_TEST_MYSQL_CONNSTR:STRING="db=soci_test user=oe password=oe"'
> +
> +OBASEDIR ?= "/opt/oracle"
> +OINCDIR = "rdbms/public"
> +OLIBDIR = "lib"
> +
> +PACKAGECONFIG[sqlite3] = "-DSOCI_SQLITE3=ON,-DSOCI_SQLITE3=OFF,sqlite3,"
> +PACKAGECONFIG[mysql] = "-DSOCI_MYSQL=ON,-DSOCI_MYSQL=OFF,mariadb,"
> +PACKAGECONFIG[postgresql] = "-DSOCI_POSTGRESQL=ON,-DSOCI_POSTGRESQL=OFF,postgresql,"
> +PACKAGECONFIG[odbc] = "-DSOCI_ODBC=ON,-DSOCI_ODBC=OFF,,"
> +PACKAGECONFIG[empty] = "-DSOCI_EMPTY=ON,-DSOCI_EMPTY=OFF,,"
> +PACKAGECONFIG[oracle] = "-DWITH_ORACLE=ON --with-oracle-include=${OINCDIR} --with-oracle-lib=${OLIBDIR},-DWITH_ORACLE=OFF,,"
> +PACKAGECONFIG[ptest] = "${TESTCONFIG},,,"
> +
> +# enable your backend by default we enable 'empty'
> +PACKAGECONFIG ??= "empty"
> +
> +# Take the flags added by PACKAGECONFIG and pass them to cmake.
> +EXTRA_OECMAKE = "${EXTRA_OECONF}"
> +
> +inherit cmake
> +
> +PACKAGES += "${PN}-sqlite3 ${PN}-mysql ${PN}-postgresql ${PN}-odbc ${PN}-oracle"
> +
> +FILES_${PN}-sqlite3 = "${libdir}/lib${BPN}_sqlite3.so.*"
> +FILES_${PN}-mysql = "${libdir}/lib${BPN}_mysql.so.*"
> +FILES_${PN}-postgresql = "${libdir}/lib${BPN}_postgresql.so.*"
> +FILES_${PN}-odbc = "${libdir}/lib${BPN}_odbc.so.*"
> +FILES_${PN}-oracle = "${libdir}/lib${BPN}_oracle.so.*"
> -- 
> 2.1.4
> 
> -- 
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel at lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

-- 
Martin 'JaMa' Jansa     jabber: Martin.Jansa at gmail.com
-------------- next part --------------
A non-text attachment was scrubbed...
Name: signature.asc
Type: application/pgp-signature
Size: 181 bytes
Desc: Digital signature
URL: <http://lists.openembedded.org/pipermail/openembedded-devel/attachments/20150302/0145459e/attachment-0002.sig>